content-provider/utils/build.gradle at 3608b8a2c53ab761225624a5469c2a805e73b4e7 · elimu-ai/content-provider · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
plugins {
    id 'com.android.library'
    id 'maven-publish'
}

apply from: "${rootProject.projectDir}/gradle/prepare_release.gradle"
apply from: "${rootProject.projectDir}/gradle/clean_release.gradle"
apply from: "${rootProject.projectDir}/gradle/perform_release.gradle"
apply from: "${rootProject.projectDir}/gradle/ensure_clean.gradle"

android {
    compileSdk 34
    namespace 'ai.elimu.content_provider.utils'

    defaultConfig {
        minSdkVersion 24
        targetSdkVersion 34
        versionCode 1002029
        versionName "1.2.29-SNAPSHOT"
        setProperty("archivesBaseName", "utils-${versionName}")
    }

    buildTypes {
        release {
            minifyEnabled false
        }
    }
    compileOptions {
        sourceCompatibility JavaVersion.VERSION_11
        targetCompatibility JavaVersion.VERSION_11
    }
}

dependencies {
    implementation 'com.github.elimu-ai:model:model-2.0.80' // See https://jitpack.io/#elimu-ai/model
    implementation 'com.github.elimu-ai:analytics:3.1.27@aar' // See https://jitpack.io/#elimu-ai/analytics
}

// See https://docs.gradle.org/current/dsl/org.gradle.api.publish.maven.MavenPublication.html
// Usage: ./gradlew clean build publish -PmavenUsername=***** -PmavenPassword=*****
publishing {
    publications {
        release(MavenPublication) {
            groupId 'ai.elimu.content_provider'
            artifactId 'utils'
            version '1.2.29-SNAPSHOT'
            artifact("${buildDir}/outputs/aar/utils-${version}-release.aar")
        }
    }
    repositories {
        maven {
            credentials(PasswordCredentials)
            url "https://maven.pkg.github.com/elimu-ai/content-provider"
        }
    }
}

tasks.named("publishReleasePublicationToMavenLocal") {
    mustRunAfter(":utils:bundleReleaseAar")
}

tasks.register('ensureCleanRepo') {
    doLast {
        ensureClean()
    }
}

tasks.register('releaseClean') {
    dependsOn ensureCleanRepo
    doLast {
        cleanRelease()
    }
}

// Task parameters:
//    bumpVersion -> if available will specify new versionName directly and ignores the `bumpType` parameter.
//    bumpType[major|minor|patch] -> will specify how the version bumping occurs.

tasks.register('releasePrepare') {
    dependsOn ensureCleanRepo
    doLast {
        prepareRelease()
    }
}

tasks.register('releasePerform') {
    dependsOn ensureCleanRepo
    doLast {
        performRelease()
    }
}