mask-utils/build.gradle at master · eltonsandre/mask-utils · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
plugins {
    id 'java'
    id "java-library"

    id 'maven'
    id 'maven-publish'
    id 'signing'

    id 'idea'
}

repositories {
    mavenLocal()
    maven {
        url = uri('https://repo.maven.apache.org/maven2/')
    }
}

dependencies {
    ['annotationProcessor', 'compileOnly', 'testAnnotationProcessor', 'testCompileOnly'].each {
        config -> add(config, 'org.projectlombok:lombok:1.18.16')
    }

    implementation 'org.apache.commons:commons-lang3:3.9'
    testImplementation 'org.junit.jupiter:junit-jupiter-engine:5.6.2'
}

group = 'com.github.eltonsandre.utils'
version = '0.0.1-SNAPSHOT'
description = 'Util para ofuscar dados de objetos'

java.sourceCompatibility = JavaVersion.VERSION_1_8
java.targetCompatibility = JavaVersion.VERSION_1_8

tasks.withType(JavaCompile) {
    options.deprecation = true
    options.encoding = 'UTF-8'
    options.compilerArgs += ["-Xlint:unchecked", "-parameters"]
}

java {
    withJavadocJar()
    withSourcesJar()
}

allprojects {
    ext.'signing.keyId' = System.getenv('SIGNING_KEY_ID')
    ext.'signing.password' = System.getenv('SIGNING_PASSWORD')
    ext.'signing.secretKeyRingFile' = System.getenv('SIGNING_SECRET_KEY_RING_FILE')
}

publishing {
    publications {
        mavenJava(MavenPublication) {

            artifactId this.name
            version  this.version

            from components.java

            versionMapping {
                usage('java-api') {
                    fromResolutionOf('runtimeClasspath')
                }
                usage('java-runtime') {
                    fromResolutionResult()
                }
            }

            pom {
                name = project.name
                description = this.description
                url = 'https://github.com/eltonsandre/mask-utils'

                licenses {
                    license {
                        name = 'The Apache License, Version 2.0'
                        url = 'http://www.apache.org/licenses/LICENSE-2.0.txt'
                        distribution = 'repo'
                    }
                }

                developers {
                    developer {
                        id = 'eltonsandre'
                        name = 'Elton Sandré'
                        email = 'elton.santos.andre@gmail.com'
                        organization {
                            name ='eltonsandre'
                            url = 'https://github.com/eltonsandre'
                        }
                    }
                }

                scm {
                    connection = 'scm:git:git://github.com/eltonsandre/mask-util.git'
                    developerConnection = 'scm:git:ssh://github.com:eltonsandre/mask-util.git'
                    url = 'http://github.com/eltonsandre/mask-utils/tree/master'
                }
            }
        }
    }

    repositories {
        maven {
            def releasesRepoUrl = 'https://oss.sonatype.org/service/local/staging/deploy/maven2'
            def snapshotsRepoUrl = 'https://oss.sonatype.org/content/repositories/snapshots'

            url = version.toUpperCase().endsWith('SNAPSHOT') ? snapshotsRepoUrl : releasesRepoUrl

            credentials {
                username sonatypeUsername
                password sonatypePassword
            }
        }
    }

}

signing {
    sign publishing.publications.mavenJava
}

javadoc {
    if (JavaVersion.current().isJava9Compatible()) {
        options.addBooleanOption('html5', true)
    }
}