gwt-gradle-plugin/build.gradle at main · esoco/gwt-gradle-plugin · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
plugins {
    id "java-library"
    id "java-gradle-plugin"
    id "com.gradle.plugin-publish" version "2.1.1"
    id "pl.allegro.tech.build.axion-release" version "1.21.1"
    id "com.vanniktech.maven.publish" version "0.36.0"
}

scmVersion { tag { prefix.set("") } }

project.version = scmVersion.version
project.group = 'de.esoco.gwt'

repositories {
    mavenCentral()
}

dependencies {
    implementation gradleApi()
    implementation "com.google.guava:guava:33.6.0-jre"
    testImplementation 'org.spockframework:spock-core:2.4-groovy-5.0', gradleTestKit()
}

java {
    sourceCompatibility = JavaVersion.VERSION_17
    targetCompatibility = JavaVersion.VERSION_17
}


tasks.withType(JavaCompile).configureEach {
    options.compilerArgs += ['-Xlint:deprecation']
}

tasks.withType(Javadoc).configureEach {
    options.addStringOption('Xdoclint:none', '-quiet')
}

processResources {
    duplicatesStrategy = DuplicatesStrategy.EXCLUDE
}

publishing {
    publications {
        pluginPublication(MavenPublication) {
            from components.java
            groupId = project.group
            artifactId = project.name
            version = project.version
        }
    }
}

gradlePlugin {
    website = 'https://github.com/esoco/gwt-gradle-plugin'
    vcsUrl = 'https://github.com/esoco/gwt-gradle-plugin.git'
    plugins {
        create("gwtPlugin") {
            id = 'de.esoco.gwt'
            implementationClass = 'de.esoco.gwt.gradle.GwtPlugin'
            displayName = 'Gradle GWT plugin'
            description = 'GWT Application Gradle Plugin'
            tags.set(['gwt', 'java'])
        }
        create("gwtLibPlugin") {
            id = 'de.esoco.gwt-lib'
            implementationClass = 'de.esoco.gwt.gradle.GwtLibPlugin'
            displayName = 'Gradle GWT lib plugin'
            description = 'GWT Library Gradle Plugin'
            tags.set(['gwt', 'java'])
        }

    }
}

mavenPublishing {
    coordinates("$project.group", "$project.name", "$project.version")

    pom {
        name = "$project.name"
        description = "$project.description"
        url = "https://github.com/esoco/${project.name}"
        licenses {
            license {
                name = "LGPL-3.0 license"
                url = "https://www.gnu.org/licenses/lgpl-3.0.html.en#license-text"
                distribution = "https://www.gnu.org/licenses/lgpl-3.0.html.en"
            }
        }
        developers {
            developer {
                id = "esoco"
                name = "esoco GmbH"
                url = "https://esoco.de/"
            }
        }
        scm {
            url = "https://github.com/esoco/${project.name}/"
            connection = "scm:git:git://github.com/esoco/${project.name}.git"
            developerConnection = "scm:git:ssh://git@github.com/esoco/${project.name}.git"
        }
    }
}