[cmake][common] Adding optional support for --zcl argument in chip_zapgen() cmake function (project-chip#40537)

* [cmake] Add optional support for --zcl argument in chip_zapgen CMake function

Signed-off-by: Dina Benamar <[email protected]>

* [NXP][cmake][common] Set "CHIP_ENABLE_ZCL_ARG" to ON for all NXP examples to allow default ZCL path to be passed as --zcl argument with chip_zapgen

Signed-off-by: Dina Benamar <[email protected]>

* [cmake] Simplify logic for handling ZCL_PATH

Signed-off-by: Dina Benamar <[email protected]>

* [cmake] Updating documentation to explain the usage of ZCL_PATH in chip_zapgen() and chip_configure_data_model()

Signed-off-by: Dina Benamar <[email protected]>

* [NXP][cmake] Updating all-clusters-app example to use custom ZCL_PATH argument with chip_configure_data_model

Signed-off-by: Dina Benamar <[email protected]>

* [cmake][common] Updating documentation of chip_zapgen and chip_configure_data_model to explain the purpose of using ZCL_PATH argument

Signed-off-by: Dina Benamar <[email protected]>

---------

Signed-off-by: Dina Benamar <[email protected]>

Author: dinabenamar

build/chip/chip_codegen.cmake

@@ -123,6 +123,7 @@ endfunction()
 #            "zap-generated/IMClusterCommandHandler.cpp"
 #     OUTPUT_PATH  DIR_NAME_VAR
 #     OUTPUT_FILES  FILE_NAMES_VAR
+#     ZCL_PATH     "path/to/custom/zcl.json" # Optional: override default ZCL path
 #   )
 #
 # Arguments:
@@ -135,11 +136,20 @@ endfunction()
 #
 #   OUTPUT_FILES - [OUT] output variable will contain the path of generated files.
 #                  suitable to be added within a build target
+#   ZCL_PATH     - [OPTIONAL] Path to a custom ZCL JSON file.
+#                  This maps to the '--zcl' argument in the "scripts/tools/zap/generate.py" script.
+#                  By default, generate.py attempts to autodetect the ZCL path from the .zap 
+#                  file which is often a relative path. When the .zap file is relocated or symlinked,
+#                  these relative paths become invalid, causing the build to fail.
+#                  Passing ZCL_PATH explicitly via CMake ensures the build remains robust and portable.
+#                  If ZCL_PATH is not provided, the default behavior is preserved unless CHIP_ENABLE_ZCL_ARG
+#                  is enabled, in which case the default path "src/app/zap-templates/zcl/zcl.json" is
+#                  automatically injected to simplify usage.
 #
 function(chip_zapgen TARGET_NAME)
     cmake_parse_arguments(ARG
          ""
-         "INPUT;GENERATOR;OUTPUT_PATH;OUTPUT_FILES"
+         "INPUT;GENERATOR;OUTPUT_PATH;OUTPUT_FILES;ZCL_PATH"
          "OUTPUTS"
          ${ARGN}
     )
@@ -180,6 +190,25 @@ function(chip_zapgen TARGET_NAME)
             message(SEND_ERROR "Unsupported zap generator: ${ARG_GENERATOR}")
         endif()
 
+        set(ZAPGEN_ARGS
+            "--no-prettify-output"
+            "--templates" "${TEMPLATE_PATH}"
+            "--output-dir" "${GEN_FOLDER}/${OUTPUT_SUBDIR}"
+            "--lock-file" "${CMAKE_BINARY_DIR}/zap_gen.lock"
+            "--parallel"
+            "${ARG_INPUT}"
+        )
+
+        # Optional ZCL path for zapgen:
+        # - If ZCL_PATH is passed, use it.
+        # - If CHIP_ENABLE_ZCL_ARG is ON, use default path.
+        # - Otherwise, skip --zcl to preserve default behavior.
+        if(ARG_ZCL_PATH)
+            list(APPEND ZAPGEN_ARGS "--zcl" "${ARG_ZCL_PATH}")
+        elseif(CHIP_ENABLE_ZCL_ARG)
+            list(APPEND ZAPGEN_ARGS "--zcl" "${CHIP_ROOT}/src/app/zap-templates/zcl/zcl.json")
+        endif()
+
         # Python is expected to be in the path
         # Forcing a call to find find_package here as ${Python3_EXECUTABLE} would be used
         find_package(Python3 REQUIRED)
@@ -191,13 +220,7 @@ function(chip_zapgen TARGET_NAME)
         add_custom_command(
             OUTPUT ${OUT_NAMES}
             COMMAND "${Python3_EXECUTABLE}" "${CHIP_ROOT}/scripts/tools/zap/generate.py"
-            ARGS
-                "--no-prettify-output"
-                "--templates" "${TEMPLATE_PATH}"
-                "--output-dir" "${GEN_FOLDER}/${OUTPUT_SUBDIR}"
-                "--lock-file" "${CMAKE_BINARY_DIR}/zap_gen.lock"
-                "--parallel"
-                "${ARG_INPUT}"
+            ARGS ${ZAPGEN_ARGS}
             DEPENDS
                 "${ARG_INPUT}"
                 ${EXTRA_DEPENDENCIES}

examples/all-clusters-app/nxp/CMakeLists.txt

@@ -105,5 +105,6 @@ else()
     chip_configure_data_model(app
         INCLUDE_SERVER
         ZAP_FILE ${NXP_EXAMPLE_ZAP_DIR}/all-clusters-app.zap
+        ZCL_PATH ${CHIP_ROOT}/src/app/zap-templates/zcl/zcl-with-test-extensions.json
     )
 endif()

examples/platform/nxp/common/app_common.cmake

@@ -26,6 +26,10 @@ if(NOT DEFINED EXAMPLE_NXP_PLATFORM_DIR)
     get_filename_component(EXAMPLE_NXP_PLATFORM_DIR ${CHIP_ROOT}/examples/platform/nxp/${CONFIG_CHIP_NXP_PLATFORM_FOLDER_NAME} REALPATH)
 endif()
 
+# Enable default ZCL path to be passed to the zapgen command for all examples.
+# This is only used if the ZCL_PATH argument is not provided in the chip_configure_data_model().
+set(CHIP_ENABLE_ZCL_ARG ON)
+
 if (CONFIG_CHIP_APP_COMMON)
     target_sources(app PRIVATE
         ${EXAMPLE_PLATFORM_NXP_COMMON_DIR}/app_task/source/AppTaskBase.cpp

src/app/chip_data_model.cmake

@@ -71,10 +71,26 @@ endfunction()
 # EXTERNAL_CLUSTERS Clusters with external implementations. The default implementations
 # will not be used nor required for these clusters.
 # Format: MY_CUSTOM_CLUSTER'.
+# ZCL_PATH          [OPTIONAL] Path to a custom ZCL JSON file.
+#                   This maps to the '--zcl' argument in the "scripts/tools/zap/generate.py" script.
+#                   By default, generate.py attempts to autodetect the ZCL path from the .zap 
+#                   file which is often a relative path. When the .zap file is relocated or symlinked,
+#                   these relative paths become invalid, causing the build to fail.
+#                   Passing ZCL_PATH explicitly via CMake ensures the build remains robust and portable.
+#                   If ZCL_PATH is not provided, the default behavior is preserved unless CHIP_ENABLE_ZCL_ARG
+#                   is enabled, in which case the default path "src/app/zap-templates/zcl/zcl.json" is 
+#                   automatically injected to simplify usage.
+#
+# Example usage:
+# chip_configure_data_model(
+#     APP_TARGET app
+#     ZAP_FILE "some_file.zap"
+#     ZCL_PATH "path/to/custom/zcl.json"  # Optional: override default ZCL path
+# )
 #
 function(chip_configure_data_model APP_TARGET)
     set(SCOPE PRIVATE)
-    cmake_parse_arguments(ARG "" "SCOPE;ZAP_FILE;IDL" "EXTERNAL_CLUSTERS" ${ARGN})
+    cmake_parse_arguments(ARG "" "SCOPE;ZAP_FILE;IDL;ZCL_PATH" "EXTERNAL_CLUSTERS" ${ARGN})
 
     if(ARG_SCOPE)
         set(SCOPE ${ARG_SCOPE})
@@ -134,6 +150,7 @@ function(chip_configure_data_model APP_TARGET)
         "zap-generated/IMClusterCommandHandler.cpp"
         OUTPUT_PATH APP_TEMPLATES_GEN_DIR
         OUTPUT_FILES APP_TEMPLATES_GEN_FILES
+        ZCL_PATH ${ARG_ZCL_PATH}
     )
     target_include_directories(${APP_TARGET} ${SCOPE} "${APP_TEMPLATES_GEN_DIR}")
     target_include_directories(${APP_TARGET} ${SCOPE} "${CHIP_APP_BASE_DIR}/zzz_generated")