Permalink pour la validation IRVE (#5524)

Co-authored-by: Thibaut Barrère <thibaut.barrere@gmail.com>

Author: vdegove

apps/transport/lib/irve/validator/summary.ex

@@ -22,4 +22,20 @@ defmodule Transport.IRVE.Validator.Summary do
     :column_errors,
     :error_samples
   ]
+
+  @doc """
+  Rebuilds a `%Summary{}` from its persisted (JSONB, string-keyed) `result` map. `struct!/2`
+  makes an unexpected top-level key raise rather than silently render as `nil`; `error_samples` rows
+  are re-keyed to atoms too (fixed key set) so the template keeps plain dot access.
+  """
+  def from_result(result) when is_map(result) do
+    result
+    |> atomize_keys()
+    |> Map.update!(:error_samples, fn samples -> Enum.map(samples, &atomize_keys/1) end)
+    |> then(&struct!(__MODULE__, &1))
+  end
+
+  defp atomize_keys(map) do
+    Map.new(map, fn {key, value} -> {String.to_existing_atom(key), value} end)
+  end
 end

apps/transport/lib/transport_web/controllers/validation_controller.ex

@@ -60,9 +60,12 @@ defmodule TransportWeb.ValidationController do
     end
   end
 
-  # IRVE statique validation doesn’t use an Oban job and doesn’t store anything
-  # It’s just a display and forget validation, and it’s quick enough so that it can be done synchronously
-  # This clause intercepts the validation instead of sending to Validata like other TableSchema validations
+  # This clause intercepts IRVE statique validation instead of routing it to Validata like the other
+  # TableSchema validations, running it synchronously on the web server (which enables the permalink below)
+  # rather than on a worker. The catch: it takes an order of magnitude more RAM than the raw CSV (at time of
+  # writing), and the web node should stay isolated from that pressure to keep serving requests, so it would
+  # be a good idea not to reproduce this pattern:
+  # https://github.com/etalab/transport-site/pull/5524#pullrequestreview-4407262217
   def validate(%Plug.Conn{} = conn, %{
         "upload" => %{"file" => %{path: file_path, filename: filename}, "type" => "etalab/schema-irve-statique"}
       }) do
@@ -112,10 +115,18 @@ defmodule TransportWeb.ValidationController do
   defp validate_irve_statique(conn, file_path, filename, _size) do
     summary = Transport.IRVE.Validator.validate_and_summarize(file_path, irve_extension(filename))
 
-    conn
-    |> assign(:summary, summary)
-    |> assign(:filename, filename || "upload.csv")
-    |> render("show_irve_statique.html")
+    validation =
+      %MultiValidation{
+        validator: "on-demand-irve-statique",
+        validation_timestamp: DateTime.utc_now(),
+        # The #show route patterns match on secret_url_token
+        oban_args: %{"type" => "irve-statique", "state" => "completed", "secret_url_token" => Ecto.UUID.generate()},
+        result: Map.from_struct(summary),
+        validated_data_name: filename || "upload.csv"
+      }
+      |> Repo.insert!()
+
+    redirect_to_validation_show(conn, validation)
   end
 
   defp irve_extension(filename) when is_binary(filename) and filename != "" do
@@ -157,11 +168,7 @@ defmodule TransportWeb.ValidationController do
         validator = Transport.Validators.GTFSTransport
         current_issues = validator.get_issues(validation.result, params)
 
-        issue_type =
-          case params["issue_type"] do
-            nil -> validator.issue_type(current_issues)
-            issue_type -> issue_type
-          end
+        issue_type = params["issue_type"] || validator.issue_type(current_issues)
 
         conn
         |> assign_base_validation_details(params)
@@ -201,6 +208,12 @@ defmodule TransportWeb.ValidationController do
         |> assign(:xsd_errors, xsd_errors)
         |> render(template)
 
+      %MultiValidation{oban_args: %{"state" => "completed", "type" => "irve-statique"}} = validation ->
+        conn
+        |> assign(:summary, Transport.IRVE.Validator.Summary.from_result(validation.result))
+        |> assign(:filename, validation.validated_data_name)
+        |> render("show_irve_statique.html")
+
       # Handles waiting for validation to complete, errors and
       # validation for schemas
       _ ->

apps/transport/lib/transport_web/templates/validation/show_irve_statique.html.heex

@@ -2,9 +2,6 @@
   <div class="container">
     <div class="validation-title">
       <h2>{dgettext("validations", "IRVE Statique validation report")}</h2>
-      <p>
-        {dgettext("validations", "Validation file")}: <b>{@filename}</b>
-      </p>
       <p class="notification">
         {dgettext("validations", "This validation now uses our integrated IRVE Statique validator.")}
         {" "}
@@ -16,6 +13,16 @@
           )
         )}
       </p>
+      <p>
+        {dgettext("validations", "Validation file")}: <b>{@filename}</b>
+      </p>
+      <p>
+        {dgettext("validations", "This report can be shared with")}
+        {link(dgettext("validations", "this permanent link"), to: current_url(@conn))}
+        {dgettext("validations", "during %{retention_days} days",
+          retention_days: Transport.Jobs.CleanOnDemandValidationJob.retention_days()
+        )}.
+      </p>
     </div>
   </div>
 

apps/transport/test/transport_web/controllers/validation_controller_test.exs

@@ -253,11 +253,18 @@ defmodule TransportWeb.ValidationControllerTest do
             }
           })
 
-        response = html_response(conn, 200)
-        assert response =~ "icon--validation\">✅</span>"
-        assert response =~ "validata.fr/table-schema"
+        assert 1 == count_validations()
 
-        assert 0 == count_validations()
+        assert %{
+                 oban_args: %{"state" => "completed", "type" => "irve-statique", "secret_url_token" => token},
+                 result: %{"valid" => true},
+                 validator: "on-demand-irve-statique",
+                 validated_data_name: "irve.csv",
+                 id: validation_id
+               } = DB.MultiValidation.with_result() |> DB.Repo.one!()
+
+        assert [] == all_enqueued(worker: Transport.Jobs.OnDemandValidationJob, queue: :on_demand_validation)
+        assert redirected_to(conn, 302) == validation_path(conn, :show, validation_id, token: token)
 
         assert [
                  %DB.FeatureUsage{
@@ -284,11 +291,14 @@ defmodule TransportWeb.ValidationControllerTest do
             }
           })
 
-        response = html_response(conn, 200)
-        assert response =~ "icon--validation\">❌</span>"
-        assert response =~ "puissance_nominale"
+        assert 1 == count_validations()
 
-        assert 0 == count_validations()
+        assert %{
+                 oban_args: %{"state" => "completed", "type" => "irve-statique"},
+                 result: %{"valid" => false}
+               } = DB.MultiValidation.with_result() |> DB.Repo.one!()
+
+        assert redirected_to(conn, 302) =~ "/validation/"
       end)
     end
 
@@ -810,6 +820,34 @@ defmodule TransportWeb.ValidationControllerTest do
       assert render(view) =~ "Value is not allowed in enum."
     end
 
+    test "with a completed IRVE Statique validation", %{conn: conn} do
+      token = Ecto.UUID.generate()
+
+      mv =
+        insert(:multi_validation,
+          oban_args: %{
+            "state" => "completed",
+            "type" => "irve-statique",
+            "secret_url_token" => token
+          },
+          result: %{
+            "valid" => true,
+            "valid_row_count" => 1,
+            "invalid_row_count" => 0,
+            "total_row_count" => 1,
+            "file_level_errors" => [],
+            "column_errors" => %{},
+            "error_samples" => []
+          },
+          validated_data_name: "irve.csv"
+        )
+
+      response = conn |> get(validation_path(conn, :show, mv.id, token: token)) |> html_response(200)
+      assert response =~ "icon--validation\">✅</span>"
+      assert response =~ "validata.fr/table-schema"
+      assert response =~ "irve.csv"
+    end
+
     test "with a GTFS-RT validation", %{conn: conn} do
       gtfs_rt_url = "https://example.com/gtfs-rt"