eventuate-tram-examples-customers-and-orders/build.gradle at master · eventuate-tram/eventuate-tram-examples-customers-and-orders · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
buildscript {
    repositories {
        mavenCentral()
        maven {
            url "https://snapshots.repositories.eventuate.io/repository"
        }
    }
    dependencies {
        classpath "org.springframework.boot:spring-boot-gradle-plugin:$springBootVersion"
        classpath "org.springframework.cloud:spring-cloud-contract-gradle-plugin:$springCloudContractDependenciesVersion"
        classpath "io.eventuate.tram.testingsupport.springcloudcontract:eventuate-tram-spring-testing-support-cloud-contract-plugins-gradle:$eventuateTramSpringTestingSupportCloudContractVersion"
    }
}

apply plugin: "io.eventuate.tram.spring.testing.cloudcontract.plugins.gradle.ConfigureContractRepoDirPlugin"

allprojects {
    group = "io.eventuate.examples.tram.ordersandcustomers"
}

subprojects {

    apply plugin: "java-library"

    java {
        toolchain {
            languageVersion = JavaLanguageVersion.of(17)
        }
    }

    repositories {
        mavenCentral()
        eventuateMavenRepoUrl.split(',').each { repoUrl -> maven { url repoUrl } }
    }

    dependencies {
        implementation(platform("io.eventuate.platform:eventuate-platform-dependencies:$eventuatePlatformVersion"))

        implementation(platform("org.springframework.cloud:spring-cloud-dependencies:${springCloudVersion}"))
        implementation(platform("org.springframework.boot:spring-boot-dependencies:$springBootVersion"))

        constraints {
                implementation("org.springdoc:springdoc-openapi-starter-webmvc-ui:$springDocOpenApiUiVersion")
        }
        testImplementation "org.springframework.boot:spring-boot-starter-test"
        testImplementation "org.junit.jupiter:junit-jupiter:$junitVersion"
        testRuntimeOnly 'org.junit.platform:junit-platform-launcher'

    }


    tasks.withType(JavaCompile) {
        options.compilerArgs << "-parameters"
    }

    tasks.withType(Test).configureEach {
          useJUnitPlatform()
    }

//    configurations.all {
//        resolutionStrategy.cacheChangingModulesFor 10, 'minutes'
//    }


}

task clean(type:Delete) {
    delete 'build/repos'
}


task compileAll(type: GradleBuild) {
    tasks = ["endToEndTestClasses", "componentTestClasses", "testClasses", "assemble"]
}

task endToEndTests(type: GradleBuild) {
    tasks = [":end-to-end-tests:endToEndTest"]
    dependsOn(":end-to-end-tests:clean")
}


task preCommitCheck {

}

task circleciConfigValidate(type: Exec) {
    commandLine 'circleci', 'config', 'validate'
}

preCommitCheck.finalizedBy(circleciConfigValidate)