Make RCTUnsafeExecuteOnMainQueueSync safer

Summary:
# Problem

React native's new list component is doing synchronous render. That means it makes synchronous dispatches from main thread to the js thread. (To capture the runtime so that it can execute js on the main thread).

But, the js thread already as a bunch of synchronous calls to the main thread. So, if any of those js -> ui sync calls happen concurrently with a synchronous render, the application will deadlock.

This diff is an attempt to mitigate all those deadlocks.

## Context
How js execution from the main thread works:

* Main thread puts a block on the js thread, to capture the js runtime.
* Main thread goes to sleep until that "runtime capture" block executes.
* Js thread executes "runtime capture block". The runtime is captured for the main thread. The js thread is put to sleep, until the runtime is released.
* Main thread wakes up, noticing that the runtime is captured. It executes its js code with the captured runtime. Then, it releases the runtime, and wakes up the js thread. Both the main and js thread move on to other tasks.

How synchronous js -> main thread calls work:
* Js thread puts a ui block on the main queue.
* Js thread goes to sleep until that ui block executes on the main thread.

## Deadlock #1
**Main thread**: execute js now:
  * Main thread puts a block on the js queue, to capture the runtime.
 * Main thread then then goes to sleep, waiting for runtime to be captured

**JS thread**: execute ui code synchronously:
* Js thread schedules a block on the ui thread
* Js thread then goes to sleep, waiting for that block to execute.

**Result:** The application deadlocks

| {F1978009555} |  {F1978009612} |

![image](https://github.com/user-attachments/assets/325a62f4-d5b7-492d-a114-efb738556239)

## Deadlock #2
**JS thread**: execute ui code synchronously:
* Js thread schedules a block on the ui thread
* Js thread then goes to sleep waiting for that block to execute.

**Main thread**: execute js now:
* Main thread puts a block on the js queue, to capture the runtime.
* Main thread then then goes to sleep, waiting for runtime to be captured

**Result:** The application deadlocks

|  {F1978009690}  | {F1978009701} |

![image](https://github.com/user-attachments/assets/13a6ea17-a55d-453d-9291-d1c8007ecffa)

# Changes
This diff attempts to fix those deadlocks. How:
* In "execute ui code synchronously" (js thread):
   * Before going to sleep, the js thread schedules the ui work on the main queue, **and** it  posts the ui work to "execute js now".
* In "execute js now" (main thread):
   * This diff makes "execute js now" stateful: it keeps a "pending ui block."
   * Before capturing the runtime, the "execute js now" executes "pending ui work", if it exists.
   * While sleeping waiting for runtime capture, "execute js now" can wake up, and execute "pending ui work." It goes back to sleep afterwards, waiting for runtime capture.

## Mitigation: Deadlock #1
**Main thread**: execute js now:
* Main thread puts a block on the js queue, to capture the runtime.
* Main thread then then goes to sleep, waiting for runtime capture

**JS Thread**: execute ui code synchronously:
* Js thread puts its ui block on the ui queue.
* ***New***: Js thread also posts that ui block to "execute js now". Main thread was sleeping waiting for runtime to be captured. It now wakes up.
* Js thread goes to sleep.

The main thread wakes up in "execute js now":
* Main thread sees that a "pending ui block" is posted. It executes the "pending ui block." The block, also scheduled on the main thread, noops henceforth.
* Main thread goes back to sleep, waiting for runtime capture.
* The js thread wakes up, moves on to the next task.

**Result:** The runtime is captured by the main thread.

| {F1978010383} | {F1978010363} |  {F1978010371} |  {F1978010379} |

![image](https://github.com/user-attachments/assets/f53cb10c-7801-46be-934a-96af7d5f5fab)

## Mitigation: Deadlock #2
**JS Thread**: execute ui code synchronously:
* Js thread puts its ui block on the ui queue.
* ***New***: Js thread also posts that ui block to "execute js now". Main thread was sleeping waiting for runtime to be captured. It now wakes up.
* Js thread goes to sleep.

**Main thread**: execute js now
* Main thread sees that a "pending ui block" is posted. It executes the "pending ui block" immediately. The block, also scheduled on the main thread, noops henceforth.
* Js thread wakes up and moves onto the next task.

**Result:** Main thread captures the runtime.

|  {F1978010525}  |  {F1978010533} |  {F1978010542} |

![image](https://github.com/user-attachments/assets/9e0ca5ef-fab6-4a26-bcca-d79d36624d5d)

Differential Revision: D74769326

Author: RSNara

packages/react-native/React/Base/RCTUtils.mm

@@ -19,6 +19,7 @@
 #import <CommonCrypto/CommonCrypto.h>
 
 #import <React/RCTUtilsUIOverride.h>
+#import <ReactCommon/RuntimeExecutorSyncUIThreadUtils.h>
 #import "RCTAssert.h"
 #import "RCTLog.h"
 
@@ -295,6 +296,11 @@ void RCTExecuteOnMainQueue(dispatch_block_t block)
   }
 }
 
+static BOOL RCTIsJSThread()
+{
+  return [[NSThread currentThread].name containsString:@"JavaScript"];
+}
+
 // Please do not use this method
 // unless you know what you are doing.
 void RCTUnsafeExecuteOnMainQueueSync(dispatch_block_t block)
@@ -311,7 +317,12 @@ void RCTUnsafeExecuteOnMainQueueSyncWithError(dispatch_block_t block, NSString *
     return;
   }
 
-  if (facebook::react::ReactNativeFeatureFlags::disableMainQueueSyncDispatchIOS()) {
+  if (facebook::react::ReactNativeFeatureFlags::enableSaferMainQueueSyncDispatchOnIOS()) {
+    if (RCTIsJSThread()) {
+      facebook::react::unsafeExecuteOnMainThreadSync(block);
+      return;
+    }
+  } else if (facebook::react::ReactNativeFeatureFlags::disableMainQueueSyncDispatchIOS()) {
     RCTLogError(
         @"RCTUnsafeExecuteOnMainQueueSync: %@",
         context ?: @"Sync dispatches to the main queue can deadlock React Native.");
@@ -340,7 +351,12 @@ static void RCTUnsafeExecuteOnMainQueueOnceSync(dispatch_once_t *onceToken, disp
     return;
   }
 
-  if (facebook::react::ReactNativeFeatureFlags::disableMainQueueSyncDispatchIOS()) {
+  if (facebook::react::ReactNativeFeatureFlags::enableSaferMainQueueSyncDispatchOnIOS()) {
+    if (RCTIsJSThread()) {
+      facebook::react::unsafeExecuteOnMainThreadSync(block);
+      return;
+    }
+  } else if (facebook::react::ReactNativeFeatureFlags::disableMainQueueSyncDispatchIOS()) {
     RCTLogError(@"RCTUnsafeExecuteOnMainQueueOnceSync: Sync dispatches to the main queue can deadlock React Native.");
   }
 

packages/react-native/ReactCommon/runtimeexecutor/platform/ios/ReactCommon/RuntimeExecutorSyncUIThreadUtils.h

@@ -36,4 +36,7 @@ inline static DataT executeSynchronouslyOnSameThread_CAN_DEADLOCK(
 
   return data;
 }
+
+void unsafeExecuteOnMainThreadSync(std::function<void()> runnable);
+
 } // namespace facebook::react

packages/react-native/ReactCommon/runtimeexecutor/platform/ios/ReactCommon/RuntimeExecutorSyncUIThreadUtils.mm

@@ -5,11 +5,119 @@
  * LICENSE file in the root directory of this source tree.
  */
 
+#import <Foundation/Foundation.h>
+
 #import <ReactCommon/RuntimeExecutorSyncUIThreadUtils.h>
-#include <mutex>
-#include <thread>
+#import <react/debug/react_native_assert.h>
+#import <react/featureflags/ReactNativeFeatureFlags.h>
+#import <react/utils/OnScopeExit.h>
+#import <functional>
+#import <future>
+#import <mutex>
+
+namespace {
+struct UITask {
+  std::promise<void> _isDone;
+  std::mutex _mutex;
+  std::function<void()> _uiWork;
+  bool _isRunning;
+  std::atomic_bool _wasStarted;
+
+ public:
+  UITask(std::function<void()> uiWork) : _uiWork(uiWork), _isRunning(false), _wasStarted(false) {}
+
+  void run()
+  {
+    bool expected = false;
+    if (!_wasStarted.compare_exchange_strong(expected, true)) {
+      return;
+    }
+    facebook::react::OnScopeExit onScopeExit(^{
+      _uiWork = nil;
+      _isRunning = false;
+      _isDone.set_value();
+    });
+    _isRunning = true;
+    _uiWork();
+  }
+
+  bool wasStarted()
+  {
+    return _wasStarted.load();
+  }
+
+  bool isRunning()
+  {
+    return _isRunning;
+  }
+
+  std::future<void> getFuture()
+  {
+    return _isDone.get_future();
+  }
+};
+} // namespace
+
+static std::mutex _mutex;
+static std::condition_variable _cv;
+
+// Global state
+static std::shared_ptr<UITask> _postedUITask;
 
 namespace facebook::react {
+namespace {
+
+void runPostedUITask()
+{
+  OnScopeExit onScopeExit([&]() { _postedUITask = nullptr; });
+  _postedUITask->run();
+}
+
+bool isJSThread()
+{
+  return [[NSThread currentThread].name containsString:@"JavaScript"];
+}
+
+void saferExecuteSynchronouslyOnSameThread_CAN_DEADLOCK(
+    const RuntimeExecutor &runtimeExecutor,
+    std::function<void(jsi::Runtime &runtime)> &&jsWork) noexcept
+{
+  react_native_assert([[NSThread currentThread] isMainThread] && (!_postedUITask || !_postedUITask->isRunning()));
+
+  jsi::Runtime *runtime = nullptr;
+  std::mutex jsWorkDone;
+
+  jsWorkDone.lock();
+  OnScopeExit onScopeExit([&]() { jsWorkDone.unlock(); });
+
+  {
+    std::unique_lock<std::mutex> lock(_mutex);
+    if (_postedUITask) {
+      runPostedUITask();
+    }
+
+    runtimeExecutor([&](jsi::Runtime &rt) {
+      runtime = &rt;
+      _cv.notify_one();
+
+      // Block the js thread until jsWork finishes on calling thread
+      jsWorkDone.lock();
+    });
+
+    while (true) {
+      _cv.wait(lock, [&] { return runtime != nullptr || _postedUITask != nullptr; });
+
+      if (_postedUITask != nullptr) {
+        runPostedUITask();
+      } else {
+        break;
+      }
+    }
+  }
+
+  jsWork(*runtime);
+}
+
 /**
  * Example order of events (when not a sync call in runtimeExecutor
  * jsWork):
@@ -26,7 +134,7 @@
  * - [JS thread] Signal runtime capture block is finished:
  *               runtimeCaptureBlockDone.unlock()
  */
-void executeSynchronouslyOnSameThread_CAN_DEADLOCK(
+void legacyExecuteSynchronouslyOnSameThread_CAN_DEADLOCK(
     const RuntimeExecutor &runtimeExecutor,
     std::function<void(jsi::Runtime &runtime)> &&jsWork) noexcept
 {
@@ -41,7 +149,7 @@ void executeSynchronouslyOnSameThread_CAN_DEADLOCK(
   jsWorkDone.lock();
   runtimeCaptureBlockDone.lock();
 
-  jsi::Runtime *runtimePtr;
+  jsi::Runtime *runtimePtr = nullptr;
 
   auto threadId = std::this_thread::get_id();
   auto runtimeCaptureBlock = [&](jsi::Runtime &runtime) {
@@ -67,4 +175,33 @@ void executeSynchronouslyOnSameThread_CAN_DEADLOCK(
   runtimeCaptureBlockDone.lock();
 }
 
+} // namespace
+
+void executeSynchronouslyOnSameThread_CAN_DEADLOCK(
+    const RuntimeExecutor &runtimeExecutor,
+    std::function<void(jsi::Runtime &runtime)> &&jsWork) noexcept
+{
+  if (ReactNativeFeatureFlags::enableSaferMainQueueSyncDispatchOnIOS()) {
+    saferExecuteSynchronouslyOnSameThread_CAN_DEADLOCK(runtimeExecutor, std::move(jsWork));
+  } else {
+    legacyExecuteSynchronouslyOnSameThread_CAN_DEADLOCK(runtimeExecutor, std::move(jsWork));
+  }
+}
+
+void unsafeExecuteOnMainThreadSync(std::function<void()> work)
+{
+  react_native_assert(isJSThread());
+  std::lock_guard<std::mutex> lock(_mutex);
+  react_native_assert(!_postedUITask || _postedUITask->wasStarted());
+
+  auto uiTask = std::make_shared<UITask>(work);
+  dispatch_async(dispatch_get_main_queue(), ^{
+    uiTask->run();
+  });
+
+  _postedUITask = uiTask;
+  _cv.notify_one();
+  uiTask->getFuture().wait();
+}
+
 } // namespace facebook::react