Build on macOS?

[lf-]

Hi! I got bored and was writing a Nix packaging for Glean and thoughtlessly was doing it on macOS. However, glean depends on hinotify, which is Linux-only.

I assume this is somewhat intentional (or at least .. macOS is not deliberately supported, whether it works by accident is another question). However, I've not looked at the actual file watching code and whether it could be disabled with a flag. Maybe that should be an option? Everything else ... mostly seems to build, modulo some curious Google packaging decisions about glog causing breakage.

This builds up to hsPkgs.glean when placed in a checkout of nixpkgs:

let
  pkgs = import ./. {
    overlays = [
      overlay
    ];
  };
  inherit (pkgs) lib;
  overlay =
    final: prev:
    let
      overlayHS = hfinal: hprev: {
        glean =
          (hlib.overrideCabal (old: {
            libraryHaskellDepends = old.libraryHaskellDepends ++ [ hfinal.hinotify ];
            jailbreak = true;
          }) hprev.glean).overrideAttrs
            (oldAttrs: {
              # its busted and pointless
              postPatch = ''
                ${oldAttrs.postPatch or ""}
                rm Setup.hs
              '';
            });
        fb-util =
          (hlib.dontCheck (hlib.unmarkBroken (hlib.doJailbreak hprev.fb-util))).overrideAttrs
            (oldAttrs: {
              # why doesn't this work? who knows! it should be doing pkgconfig into the clang command line and it simply does not.
              # env = (oldAttrs.env or {}) // {
              #   NIX_DEBUG = 2;
              # };
              # # jank, should be libraryPkgconfigDepends in overrideCabal but I don't feel like it
              # buildInputs = (oldAttrs.buildInputs or []) ++ [
              #   final.folly
              # ];

              # jank jank jank! works around missing pkg-config in nixpkgs for glog.
              env = (prev.env or { }) // {
                NIX_CFLAGS_COMPILE = "${
                  oldAttrs.env.NIX_CFLAGS_COMPILE or ""
                } -DGFLAGS_IS_A_DLL=0 -DGLOG_USE_GLOG_EXPORT -DGLOG_USE_GFLAGS -lglog";
              };
              postPatch = ''
                ${oldAttrs.postPatch or ""}
                substituteInPlace ./fb-util.cabal --replace-fail "libglog," "" --replace-fail "g++" "c++"
                substituteInPlace ./Util/AsanAlloc.cpp --replace-fail "#include <malloc.h>" "#include <stdlib.h>"
              '';
            });
        thrift-compiler = hlib.doJailbreak hprev.thrift-compiler;
        thrift-lib = hlib.dontCheck (hlib.doJailbreak hprev.thrift-lib);
        thrift-http = hlib.dontCheck (hlib.doJailbreak hprev.thrift-http);
        thrift-haxl = hlib.dontCheck (hlib.doJailbreak hprev.thrift-haxl);
        fb-stubs = hlib.unmarkBroken (hlib.doJailbreak hprev.fb-stubs);
        # this really shouldn't be this goofy right??
        folly-clib = hprev.callCabal2nixWithOptions "folly-clib" (pkgs.fetchzip {
          url = "mirror://hackage/folly-clib-20250713.1537/folly-clib-20250713.1537.tar.gz";
          sha256 = "sha256-pmiJ9TDn/TGs/DZwdkk0hl9rCyBjIeQfNDg6mTEMH40=";
        }) "-f-bundled-folly" { libfolly = final.folly; };
        haxl = (hlib.unmarkBroken hprev.haxl).overrideAttrs (oldAttrs: {
          # its busted and pointless
          postPatch = "rm Setup.hs";
        });
        haskell-names = hlib.unmarkBroken (hlib.dontCheck (hlib.doJailbreak hprev.haskell-names));
        mangle = hlib.doJailbreak hprev.mangle;
      };
    in
    {
      haskell = prev.haskell // {
        packages = prev.haskell.packages // {
          ghc9103 = prev.haskell.packages.ghc9103.override (old: {
            overrides = lib.fold lib.composeExtensions (old.overrides or (_: _: { })) [ overlayHS ];
          });
        };
      };
    };
  hlib = pkgs.haskell.lib.compose;
in
{
  hsPkgs = pkgs.haskellPackages;
}

[bradymadden97]

Did you end up getting this working? I've been trying to use this to get a somewhat operable binary for mac built but haven't been successful.

[lf-]

i’m not convinced there’s significant problems other than needing to patch out the file watcher but i’ve not tried doing so yet. since filing this i’ve written a more comprehensive packaging that provides a working dev shell. i might post it during the week once i get out my work computer.

[bradymadden97]

Think I got this shell running, but then getting tripped up on what I think is the next step

(nix:nix-shell-env) bmadden660-mac:Glean bmadden$ make glean
cabal --jobs --ghc-options='' -vnormal+nowrap --project-file=/Users/bmadden/projects/glean-mac/Glean/cabal.project   build glean glean-server glean-hyperlink
Warning: Specifying an absolute path to the project file is deprecated. Use --project-dir to set the project's directory.
Resolving dependencies...
Error: [Cabal-7107]
Could not resolve dependencies:
[__0] next goal: glean (user goal)
[__0] rejecting: glean-0.1.0.0 (conflict: pkg-config package libxxhash-any, not found in the pkg-config database)
[__0] fail (backjumping, conflict set: glean)
After searching the rest of the dependency tree exhaustively, these were the goals I've had most trouble fulfilling: glean

make: *** [Makefile:144: glean] Error 1

Anyways, if you have the working dev shell available that would be awesome

[lf-]

Apologies for my laziness in not packaging it up in a runnable form, but here is the current work code with a usable overlay:

It's using a heavily patched GHC 9.10.1 that is basically 9.10.3.

The referenced horrible build system hacks are: https://github.com/MercuryTechnologies/Glean/commits/jade/push-ysqumxlzqmur/ "jades horrible hacks".

  overlay-glean =
    hfinal: hprev:
    let
      # due to unfortunate choices, folly contains some checks for x86 architecture
      # version in headers, which require that -march is set to the same thing
      # on folly itself as in its users. this shouldn't be forced everywhere
      # because that's not nixpkgs support policy, so we have to build a
      # special folly for just glean.
      folly-avx =
        if self.stdenv.hostPlatform.isx86_64 then
          self.folly.overrideAttrs (oldAttrs: {
            env = (oldAttrs.env or { }) // {
              NIX_CFLAGS_COMPILE = "${oldAttrs.env.NIX_CFLAGS_COMPILE or ""} -march=haswell";
            };
          })
        else
          self.folly;
    in
    {
      glean =
        (overrideCabal
          (old: {
            jailbreak = true;
            # seemingly this does pass but keeps running out of disk because lolz
            doCheck = false;

            patches = (old.patches or [ ]) ++ [
              # fix the build
              (self.fetchpatch {
                url = "https://github.com/facebookincubator/Glean/pull/590/commits/d2aebf681eb08bf126ca0c7a4fa468d7f73e02ad.patch";
                sha256 = "sha256-SRR+hUKsfX6qu/UUWlJleeV/eJ6flEF2tOBKhwr++yY=";
              })
              # fix the haskell indexer for ghc 9.10
              (self.fetchpatch {
                url = "https://github.com/facebookincubator/Glean/pull/591/commits/72c926eafea769d12e28065c2f393cb98508c7f3.patch";
                sha256 = "sha256-Tpp+dcVK/HelJPa8M9jf67jrTeN6sOLAJ7tHZLrVb58=";
              })
            ];
            libraryToolDepends = (old.libraryToolDepends or [ ]) ++ [
              # bork template haskell https://github.com/facebookincubator/Glean/issues/589
              self.git
            ];
          })
          (
            hfinal.callHackage "glean" "0.1.0.0" {
              atomic = null;
              libfolly = folly-avx;
              libglog = self.glog;
              libxxhash = self.xxHash;
              gtest_main = null;
            }
          )
        ).overrideAttrs
          (oldAttrs: {
            # FIXME(nixpkgs-update): move to overrideCabal https://github.com/NixOS/nixpkgs/pull/424368
            # jank jank jank! works around missing pkg-config in nixpkgs for glog.
            # i dont have any idea why libfolly cflags aren't heeded here since they explicitly fix this
            NIX_CFLAGS_COMPILE = "${
              oldAttrs.NIX_CFLAGS_COMPILE or ""
            } -DGFLAGS_IS_A_DLL=0 -DGLOG_USE_GLOG_EXPORT -DGLOG_USE_GFLAGS -lglog -Wno-stringop-overflow";

            disallowedRequisites =
              (oldAttrs.disallowedRequisites or [ ])
              ++ lib.optionals self.stdenv.hostPlatform.isx86_64 [
                self.folly
              ];
            # its busted and pointless
            postPatch = ''
              ${oldAttrs.postPatch or ""}
              substituteInPlace ./glean.cabal --replace-fail "libglog," ""
              rm Setup.hs
            '';

            # dev shell so that you can work on the glean repo with
            # nix-supplied haskell.
            # some pretty bad patches to the build system are required to
            # actually work on it in practice though.
            #
            # Use with:
            # nix develop -f myShell.nix haskell.packages.ghc910.glean.passthru.shell
            passthru = (oldAttrs.passthru or { }) // {
              shell = hfinal.shellFor {
                packages = ps: [ ps.glean ];
                nativeBuildInputs = [
                  self.cabal-install
                  self.m4
                  self.gnumake
                  self.happy
                  self.alex
                  hfinal.thrift-compiler
                  self.haskell-language-server
                  self.watchman
                  self.python3Packages.pywatchman
                ];

                NIX_CFLAGS_COMPILE = "-DGFLAGS_IS_A_DLL=0 -DGLOG_USE_GLOG_EXPORT -DGLOG_USE_GFLAGS -lglog -Wno-stringop-overflow";
              };
            };
          });
      fb-util =
        (overrideCabal
          (old: {
            librarySystemDepends = (old.librarySystemDepends or [ ]) ++ [
              folly-avx
              self.glog
            ];
            jailbreak = true;
            doCheck = true;
            broken = false;
          })
          (
            hprev.callCabal2nixWithOptions "fb-util" (self.fetchzip {
              url = "mirror://hackage/fb-util-0.2.0.0/fb-util-0.2.0.0.tar.gz";
              sha256 = "sha256-4NFiV73AZ8YIwjqP03+n8HelIdM6McQXMzFNCyrLvJc=";
            }) "-ffolly" { libglog = self.glog; }
          )
        ).overrideAttrs
          (oldAttrs: {
            # FIXME(nixpkgs-update): move to overrideCabal https://github.com/NixOS/nixpkgs/pull/424368
            # jank jank jank! works around missing pkg-config in nixpkgs for
            # glog. why does the folly pkg-config not fix this?!
            NIX_CFLAGS_COMPILE = "${
              oldAttrs.NIX_CFLAGS_COMPILE or ""
            } -DGFLAGS_IS_A_DLL=0 -DGLOG_USE_GLOG_EXPORT -DGLOG_USE_GFLAGS -lglog";

            # Fixes build on macOS
            postPatch = ''
              ${oldAttrs.postPatch or ""}
              substituteInPlace ./fb-util.cabal --replace-fail "libglog," "libfolly," --replace-fail "g++" "c++"
              substituteInPlace ./Util/AsanAlloc.cpp --replace-fail "#include <malloc.h>" "#include <stdlib.h>"
            '';
          });
      thrift-compiler = doJailbreak hprev.thrift-compiler;
      thrift-lib = dontCheck (doJailbreak hprev.thrift-lib);
      thrift-http = dontCheck (doJailbreak hprev.thrift-http);
      thrift-haxl = dontCheck (doJailbreak hprev.thrift-haxl);
      fb-stubs = unmarkBroken (doJailbreak hprev.fb-stubs);
      # this really shouldn't be this goofy right??
      folly-clib = hprev.callCabal2nixWithOptions "folly-clib" (self.fetchzip {
        url = "mirror://hackage/folly-clib-20250713.1537/folly-clib-20250713.1537.tar.gz";
        sha256 = "sha256-pmiJ9TDn/TGs/DZwdkk0hl9rCyBjIeQfNDg6mTEMH40=";
      }) "-f-bundled-folly" { libfolly = folly-avx; };
      haxl = (unmarkBroken hprev.haxl).overrideAttrs (oldAttrs: {
        # its busted and pointless
        postPatch = "rm Setup.hs";
      });
      haskell-names = unmarkBroken (dontCheck (doJailbreak hprev.haskell-names));
      mangle = doJailbreak hprev.mangle;
    };

I believe most of this builds on macOS, but not glean itself.