feat: add beadwork package (git-native work management tool for AI agents)

Author: sigma

packages/beadwork/data.json

@@ -0,0 +1,8 @@
+{
+  "_meta": { "default": "0.11.6", "releases": "https://github.com/jallum/beadwork/releases" },
+  "0.11.6": {
+    "sha256": "sha256-+WcNCXOjK8TuozVIbQME2U/cfwGPYgcOLONmmjqfqQ8=",
+    "vendorHash": "sha256-/tmJPuL9xHsh3oTtlaW1nUxroAxyX5rhsSB1pkuE9Fo=",
+    "go": "1.25.7"
+  }
+}

packages/beadwork/default.nix

@@ -0,0 +1,47 @@
+{ pkgs, lib, toolbox, toolboxLib }:
+
+let
+  inherit (toolboxLib.readData ./data.json) meta versions;
+
+  builders = {
+    default = version: versionData:
+      let
+        go = toolbox.go.versions.${versionData.go};
+      in
+      (pkgs.buildGoModule.override { inherit go; }) {
+        pname = "beadwork";
+        inherit version;
+        src = pkgs.fetchFromGitHub {
+          owner = "jallum";
+          repo = "beadwork";
+          rev = "v${version}";
+          hash = versionData.sha256;
+        };
+        vendorHash = versionData.vendorHash;
+        subPackages = [ "cmd/bw" ];
+        doCheck = false;
+
+        postPatch = ''
+          goVer="$(${go}/bin/go env GOVERSION | sed 's/^go//')"
+          sed -i "s/^go .*/go $goVer/" go.mod
+        '';
+        env.GOTOOLCHAIN = "auto";
+        nativeBuildInputs = [ pkgs.git ];
+
+        postInstall = ''
+          ln -s bw $out/bin/beadwork
+        '';
+
+        meta = with lib; {
+          description = "A git-native work management tool for AI coding agents";
+          homepage = "https://github.com/jallum/beadwork";
+          license = licenses.mit;
+          mainProgram = "bw";
+        };
+      };
+  };
+in
+{
+  versions = toolboxLib.buildVersions "beadwork" builders versions;
+  default = meta.default;
+}