DIDdoc_announce.clsp

;; Copyright 2026 Julia.Social, Inc.
;;
;; Licensed under the Apache License, Version 2.0 (the "License");
;; you may not use this file except in compliance with the License.
;; You may obtain a copy of the License at
;;
;;     http://www.apache.org/licenses/LICENSE-2.0
;;
;; Unless required by applicable law or agreed to in writing, software
;; distributed under the License is distributed on an "AS IS" BASIS,
;; WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
;; See the License for the specific language governing permissions and
;; limitations under the License.

(mod (curried-args solution)

  (include *standard-cl-26*)
  (defun print (l x) (i (all "$print$" l x) x x))

  ; Announces the DID's associated DID Document location (a DataLayer singleton) via
  ; CREATE_PUZZLE_ANNOUNCEMENT with the JDIDD prefix.  Optionally delegates to a child puzzle.

  (include "condition_codes.clib")
  (include "sha256tree.clib")

  (embed-file pass-thru-puzzlehash bin "pass_thru.clsp.hash.bin")
  (embed-file present-claims-puzzlehash bin "present_claims.clsp.hash.bin")
  (embed-file present-delegated-puzzlehash bin "present_delegated.clsp.hash.bin")

  (assign
    ( julia-DID-puzzlehash
      my-launcher-id
      recovery-delay
      multisig-info
      valid-custodian-DIDs
      recovery-info
      DID-doc
    ) curried-args
    child-puzzle-output (if (l solution)
                            (assign
                                child-hash (sha256tree (f solution))
                              (if (if (= child-hash pass-thru-puzzlehash) 1
                                  (if (= child-hash present-claims-puzzlehash) 1
                                      (= child-hash present-delegated-puzzlehash)))
                                (a (f solution) (list curried-args (r solution)))
                                (x 110)
                              )
                            )
                            (list curried-args ())
                        )
    ( child-puzzle-new-curry-args
      child-puzzle-conditions
    ) child-puzzle-output
    (list child-puzzle-new-curry-args
          (c (list CREATE_PUZZLE_ANNOUNCEMENT (concat "JDIDD" DID-doc))
             child-puzzle-conditions))
  )
)