custodian.clsp

;; Copyright 2026 Julia.Social, Inc.
;;
;; Licensed under the Apache License, Version 2.0 (the "License");
;; you may not use this file except in compliance with the License.
;; You may obtain a copy of the License at
;;
;;     http://www.apache.org/licenses/LICENSE-2.0
;;
;; Unless required by applicable law or agreed to in writing, software
;; distributed under the License is distributed on an "AS IS" BASIS,
;; WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
;; See the License for the specific language governing permissions and
;; limitations under the License.

(mod (curried-args solution)

  (include *standard-cl-26*)
  (defun print (l x) (i (all "$print$" l x) x x))

  (include "condition_codes.clib")
  (include "curry_and_treehash.clib")
  (include "sha256tree.clib")
  
  (include "did_puzzles.clib")

  ; Sends a JDIDC command message to a custodied DID (minion), directing it to perform
  ; a specific operation.  The custodian must be in the custodian list of the minion.

  ; message what we want the minion to do
  (defun-inline create-custodian-request (julia-DID-puzzlehash minion-DID minion-curried-args-hash child-solution-hash)
    (list SEND_MESSAGE 0x12 (concat "JDIDC" child-solution-hash)  ; J C = Julia Custodian, 0x12 = 010010b - sender puzzle, receiver puzzle
                            (julia-DID-coin-puzzlehash julia-DID-puzzlehash minion-DID minion-curried-args-hash))
  )

  ; assert the DID in our solution is actually our DID (fast-forward compatible)
  (defun-inline assert-my-DID (my-DID julia-DID-puzzlehash curried-args-hash)
    (list ASSERT_MY_PUZZLEHASH (julia-DID-coin-puzzlehash julia-DID-puzzlehash my-DID curried-args-hash))
  )

  ; prepend the conditions to invoke the minion
  (defun-inline prepend-conditions (my-DID curried-args julia-DID-puzzlehash
                                    minion-DID minion-curried-args-hash child-solution-hash)
    (list (create-custodian-request julia-DID-puzzlehash minion-DID minion-curried-args-hash child-solution-hash)
          (assert-my-DID my-DID julia-DID-puzzlehash (sha256tree curried-args)))
  )

  ; construct the list containing the new curried args (unchanged) and the output conditions
  (defun-inline create-output (my-DID curried-args julia-DID-puzzlehash
                               minion-DID minion-curried-args-hash child-solution-hash)
    (list curried-args
          (prepend-conditions my-DID curried-args julia-DID-puzzlehash
                              minion-DID minion-curried-args-hash child-solution-hash))
  )

  ;; tell the minion what to do
  (assign
      ( julia-DID-puzzlehash
        my-launcher-id
        recovery-timeout-block
        multisig-info
        valid-custodian-DIDs
        recovery-info
        DID-doc
      ) curried-args
      ( minion-DID
        minion-curried-args-hash
        child-solution-hash
      ) solution
    ; the identity asserted in ASSERT_MY_PUZZLEHASH comes from the committed curried
    ; args, not from the solution, so the assertion cannot be aimed at another DID
    (create-output my-launcher-id curried-args julia-DID-puzzlehash
                   minion-DID minion-curried-args-hash child-solution-hash)
  )
)