julia_did_chialisp/issuer_key_control.clsp at main · fizpawiz/julia_did_chialisp · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
;; Copyright 2026 Julia.Social, Inc.
;;
;; Licensed under the Apache License, Version 2.0 (the "License");
;; you may not use this file except in compliance with the License.
;; You may obtain a copy of the License at
;;
;;     http://www.apache.org/licenses/LICENSE-2.0
;;
;; Unless required by applicable law or agreed to in writing, software
;; distributed under the License is distributed on an "AS IS" BASIS,
;; WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
;; See the License for the specific language governing permissions and
;; limitations under the License.

(mod (curried-args solution)

  (include *standard-cl-26*)
  (defun print (l x) (i (all "$print$" l x) x x))

  (include "condition_codes.clib")
  (include "curry_and_treehash.clib")
  (include "sha256tree.clib")

  (include "bitfield.clib")
  (include "did_puzzles.clib")

  (embed-file issuer-key-puzzlehash bin "issuer_key.clsp.hash.bin")

  ; Allows the owning DID to manage its issuer key singletons — updating the revocation
  ; bitfield (JDIDK message) or melting an entire issuer key (JDIDZ message).

  ; sends JDIDK message commanding an issuer key to update its revocation bitfield
  ; (the issuer_key_functions by-DID path, spend mode 3)
  (defun request-update-revocation-by-DID (mode-solution)
    (assign
        (
          issuer-key-launcher-id
          issuer-key-curried-args-hash
          issuer-key-parent-coin
          index
          new-leaf
        ) mode-solution
      (list
        (list SEND_MESSAGE 0x16
          (concat "JDIDK" (sha256tree (list index new-leaf)))
          issuer-key-parent-coin
          (issuer-key-coin-puzzlehash issuer-key-puzzlehash issuer-key-launcher-id issuer-key-curried-args-hash))
      )
    )
  )

  ; sends JDIDZ message to destroy an issuer key singleton
  (defun request-melt (mode-solution)
    (assign
        (
          issuer-key-launcher-id
          issuer-key-curried-args-hash
          issuer-key-parent-coin
        ) mode-solution
      (list
        ; 0x16 = 010110b - sender: 010 (puzzle) receiver: 110 (puzzle + parent).  Naming
        ; the receiver's parent pins the melt to one coin, so an authorization that is
        ; signed but not submitted cannot be replayed at a later generation whose state
        ; happens to match.
        (list SEND_MESSAGE 0x16
          "JDIDZ"
          issuer-key-parent-coin
          (issuer-key-coin-puzzlehash issuer-key-puzzlehash issuer-key-launcher-id issuer-key-curried-args-hash))
      )
    )
  )

  ;; main
  (assign ; use assign to destructure the curried-args and solution
    ( julia-DID-puzzlehash
      my-launcher-id
      recovery-delay
      multisig-info
      valid-custodian-DIDs
      recovery-info
      DID-doc
    ) curried-args
    mode (f solution)
    (list curried-args
      (if (= mode 3)
        (request-update-revocation-by-DID (r solution))
        (if (= mode 5)
          (request-melt (r solution))
          (x 35)
        )
      )
    )
  )
)