julia_did_chialisp/recovery_cancel.clsp at main · fizpawiz/julia_did_chialisp · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
;; Copyright 2026 Julia.Social, Inc.
;;
;; Licensed under the Apache License, Version 2.0 (the "License");
;; you may not use this file except in compliance with the License.
;; You may obtain a copy of the License at
;;
;;     http://www.apache.org/licenses/LICENSE-2.0
;;
;; Unless required by applicable law or agreed to in writing, software
;; distributed under the License is distributed on an "AS IS" BASIS,
;; WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
;; See the License for the specific language governing permissions and
;; limitations under the License.

(mod (curried-args solution)

  (include *standard-cl-26*)
  (defun print (l x) (i (all "$print$" l x) x x))

  (include "condition_codes.clib")
  (include "curry_and_treehash.clib")
  (include "sha256tree.clib")

  (include "did_puzzles.clib")
  (include "parse_merkle_path.clib")
  (include "multiclass.clib")

  ; Allows recovery-authorized DIDs to abort an in-progress recovery before the time lock
  ; expires, clearing the pending recovery state.

  ; create conditions for the recovery DID participants, step 3: create the message condition
  (defun create-condition (participant participant-curried-arg-hash julia-DID-puzzlehash)
    (list RECEIVE_MESSAGE 22 "JDIDX"  ; 22 = 010110b - sender: 010 (puzzle) receiver: 110 (puzzle + parent)
          (julia-DID-coin-puzzlehash julia-DID-puzzlehash participant participant-curried-arg-hash))
  )

  ; create conditions for the recovery DID participants, step 2: iterate over the need DIDs
  (defun create-conditions-helper (participants participant-curried-arg-hashes julia-DID-puzzlehash)
    (if (l participants)
      (if (l participant-curried-arg-hashes)
        (c (create-condition (f participants) (f participant-curried-arg-hashes) julia-DID-puzzlehash)
           (create-conditions-helper (r participants) (r participant-curried-arg-hashes) julia-DID-puzzlehash))
        (x 23) ; unbalanced lists
      )
      (if (l participant-curried-arg-hashes)
        (x 24) ; unbalanced lists
        ()
      )
    )
  )

  ; create conditions for the recovery DID participants, step 1: get the needed DIDs
  (defun create-conditions (participant-paths participant-curried-arg-hashes julia-DID-puzzlehash recovery-info)
    (assign
      ( prerotation-multisig-info
        classes
        class-depth
        required-classes
        required-root
        recovery-delay
      ) recovery-info
      (create-conditions-helper (multiclass participant-paths class-depth classes required-classes required-root)
                                participant-curried-arg-hashes julia-DID-puzzlehash)
    )
  )

  ; update the curry for the current DID
  (defun update-curry (curried-args)
    (assign ; use assign to destructure the arguments
      ( julia-DID-puzzlehash
        my-launcher-id
        recovery-delay
        multisig-info
        valid-custodian-DIDs
        recovery-info
        DID-doc
      ) curried-args
      ( prerotation-multisig-info
        classes
        class-depth
        required-classes
        required-root
        new-recovery-delay
      ) recovery-info
      (list
        julia-DID-puzzlehash
        my-launcher-id
        0  ; cancel recovery operation by clearing the delay
        multisig-info
        valid-custodian-DIDs
        recovery-info
        DID-doc
        ()
      )
    )
  )

  ;; main
  (assign ; use assign to destructure the curried-args and solution
    ( julia-DID-puzzlehash
      my-launcher-id
      recovery-delay
      multisig-info
      valid-custodian-DIDs
      recovery-info
      DID-doc
    ) curried-args
    ( participant-paths
      participant-curried-arg-hashes
    ) solution
    (if (> recovery-delay 0)
        (assign
            conditions (create-conditions participant-paths participant-curried-arg-hashes
                                          julia-DID-puzzlehash recovery-info)
          (list (update-curry curried-args)
                  conditions
          )
        )
        (x 25) ; recovery not in progress
    )
  )
)