julia_did_chialisp/recovery_prerotation.clsp at main · fizpawiz/julia_did_chialisp · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
;; Copyright 2026 Julia.Social, Inc.
;;
;; Licensed under the Apache License, Version 2.0 (the "License");
;; you may not use this file except in compliance with the License.
;; You may obtain a copy of the License at
;;
;;     http://www.apache.org/licenses/LICENSE-2.0
;;
;; Unless required by applicable law or agreed to in writing, software
;; distributed under the License is distributed on an "AS IS" BASIS,
;; WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
;; See the License for the specific language governing permissions and
;; limitations under the License.

(mod (curried-args solution)

  (include *standard-cl-26*)
  (defun print (l x) (i (all "$print$" l x) x x))

  (include "condition_codes.clib")
  (include "sha256tree.clib")

  (include "parse_merkle_path.clib")
  (include "multiclass.clib")

  ; Switches to a pre-committed set of keys without going through recovery's time lock.
  ; Protects against key compromise: an attacker with current keys cannot set arbitrary new
  ; keys because the next keys were already committed.  Also cancels any active recovery.

  ; For each pubkey given, prepend an AGG_SIG_PUZZLE for that pubkey.
  ; Note that AGG_SIG_PUZZLE is used for fast-forward compatibility
  (defun add-conditions (pubkeys message)
    (if (l pubkeys)
      (c (list AGG_SIG_PUZZLE (f pubkeys) message)
         (add-conditions (r pubkeys) message))
      ()
    )
  )

  (assign
      ( julia-DID-puzzlehash
        my-launcher-id
        recovery-timeout-block
        multisig-info
        valid-custodian-DIDs
        recovery-info
        DID-doc
      ) curried-args
      ( prerotation-multisig-info
        recovery-classes
        recovery-class-depth
        recovery-required-classes
        recovery-required-root
        recovery-delay-setting
      ) recovery-info
      ( classes
        class-depth
        required-classes
        required-root
      ) prerotation-multisig-info
      fee-coin (f solution)
      pubkey-paths (f (r solution))
      new-prerotation-multisig-info (f (r (r solution)))
      conditions (add-conditions (multiclass pubkey-paths class-depth classes required-classes required-root)
                                 (sha256tree solution))
    (list
      (list ; updated curried args
        julia-DID-puzzlehash
        my-launcher-id
        0 ; exercising prerotated keys aborts any active recovery
        prerotation-multisig-info ; updated multisig
        valid-custodian-DIDs
        (list
          new-prerotation-multisig-info
          recovery-classes
          recovery-class-depth
          recovery-required-classes
          recovery-required-root
          recovery-delay-setting
        )
        DID-doc
        0 ; empty pending-recovery slot: the state carries eight slots on every path
      )
      (if fee-coin
        (c (list ASSERT_CONCURRENT_SPEND fee-coin) conditions)
        conditions)
    )
  )
)