Add nix development files

When using nix, it allows running `nix-shell dev/nix/shell.nix` to add the required
dependencies to the current environment.

Furthermore, a specific compiler can be requested, e.g.
nix-shell dev/nix/shell.nix -A gcc10 will setup the environment
with cc = gcc10.

The available compilers are for now clang, gcc9 through gcc14.

Author: Tom-Hubrecht

dev/nix/default.nix

@@ -0,0 +1,46 @@
+{
+  sources ? import ./npins,
+  pkgs ? import sources.nixpkgs { },
+}:
+
+let
+  inherit (pkgs.lib) genAttrs;
+
+  packages = with pkgs; [
+    # Dependencies
+    gmp
+    mpfr
+    ntl
+    openblas
+
+    # Build tools
+    autoconf
+    automake
+    gnumake
+    libtool
+  ];
+
+  stdenvs = [
+    "clang"
+    "gcc9"
+    "gcc10"
+    "gcc11"
+    "gcc12"
+    "gcc13"
+    "gcc14"
+  ];
+in
+
+{
+  devShell = pkgs.mkShell {
+    name = "flint.dev";
+    inherit packages;
+    passthru = genAttrs stdenvs (
+      stdenv:
+      (pkgs.mkShell.override { stdenv = pkgs.${stdenv + "Stdenv"}; }) {
+        name = "flint.dev-${stdenv}";
+        inherit packages;
+      }
+    );
+  };
+}

dev/nix/npins/default.nix

@@ -0,0 +1,80 @@
+# Generated by npins. Do not modify; will be overwritten regularly
+let
+  data = builtins.fromJSON (builtins.readFile ./sources.json);
+  version = data.version;
+
+  mkSource =
+    spec:
+    assert spec ? type;
+    let
+      path =
+        if spec.type == "Git" then
+          mkGitSource spec
+        else if spec.type == "GitRelease" then
+          mkGitSource spec
+        else if spec.type == "PyPi" then
+          mkPyPiSource spec
+        else if spec.type == "Channel" then
+          mkChannelSource spec
+        else
+          builtins.throw "Unknown source type ${spec.type}";
+    in
+    spec // { outPath = path; };
+
+  mkGitSource =
+    {
+      repository,
+      revision,
+      url ? null,
+      hash,
+      branch ? null,
+      ...
+    }:
+    assert repository ? type;
+    # At the moment, either it is a plain git repository (which has an url), or it is a GitHub/GitLab repository
+    # In the latter case, there we will always be an url to the tarball
+    if url != null then
+      (builtins.fetchTarball {
+        inherit url;
+        sha256 = hash; # FIXME: check nix version & use SRI hashes
+      })
+    else
+      assert repository.type == "Git";
+      let
+        urlToName =
+          url: rev:
+          let
+            matched = builtins.match "^.*/([^/]*)(\\.git)?$" repository.url;
+
+            short = builtins.substring 0 7 rev;
+
+            appendShort = if (builtins.match "[a-f0-9]*" rev) != null then "-${short}" else "";
+          in
+          "${if matched == null then "source" else builtins.head matched}${appendShort}";
+        name = urlToName repository.url revision;
+      in
+      builtins.fetchGit {
+        url = repository.url;
+        rev = revision;
+        inherit name;
+        # hash = hash;
+      };
+
+  mkPyPiSource =
+    { url, hash, ... }:
+    builtins.fetchurl {
+      inherit url;
+      sha256 = hash;
+    };
+
+  mkChannelSource =
+    { url, hash, ... }:
+    builtins.fetchTarball {
+      inherit url;
+      sha256 = hash;
+    };
+in
+if version == 3 then
+  builtins.mapAttrs (_: mkSource) data.pins
+else
+  throw "Unsupported format version ${toString version} in sources.json. Try running `npins upgrade`"

dev/nix/npins/sources.json

@@ -0,0 +1,11 @@
+{
+  "pins": {
+    "nixpkgs": {
+      "type": "Channel",
+      "name": "nixpkgs-unstable",
+      "url": "https://releases.nixos.org/nixpkgs/nixpkgs-25.05pre744509.88a55dffa4d4/nixexprs.tar.xz",
+      "hash": "031apspqfm8z4yczj8126chfc7mijnmnxzqg0inaz1dwi4pzwlbz"
+    }
+  },
+  "version": 3
+}

dev/nix/shell.nix

@@ -0,0 +1 @@
+(import ./. { }).devShell