gtk: implement audio bell

Author: jcollie

Diff for: include/ghostty.h

@@ -599,6 +599,7 @@ typedef enum {
   GHOSTTY_ACTION_COLOR_CHANGE,
   GHOSTTY_ACTION_RELOAD_CONFIG,
   GHOSTTY_ACTION_CONFIG_CHANGE,
+  GHOSTTY_ACTION_BELL,
 } ghostty_action_tag_e;
 
 typedef union {

Diff for: nix/devShell.nix

@@ -31,6 +31,7 @@
   glslang,
   gtk4,
   gobject-introspection,
+  gst_all_1,
   libadwaita,
   blueprint-compiler,
   adwaita-icon-theme,
@@ -170,6 +171,9 @@ in
         wayland
         wayland-scanner
         wayland-protocols
+        gst_all_1.gstreamer
+        gst_all_1.gst-plugins-base
+        gst_all_1.gst-plugins-good
       ];
 
     # This should be set onto the rpath of the ghostty binary if you want

Diff for: nix/package.nix

@@ -14,6 +14,7 @@
   glib,
   gtk4,
   gobject-introspection,
+  gst_all_1,
   libadwaita,
   blueprint-compiler,
   wrapGAppsHook4,
@@ -107,6 +108,9 @@ in
         libadwaita
         gtk4
         glib
+        gst_all_1.gstreamer
+        gst_all_1.gst-plugins-base
+        gst_all_1.gst-plugins-good
         gsettings-desktop-schemas
       ]
       ++ lib.optionals enableX11 [
@@ -158,6 +162,10 @@ in
       mv $out/share/vim/vimfiles "$vim"
       ln -sf "$vim" "$out/share/vim/vimfiles"
       echo "$vim" >> "$out/nix-support/propagated-user-env-packages"
+
+      echo "gst_all_1.gstreamer" >> "$out/nix-support/propagated-user-env-packages"
+      echo "gst_all_1.gst-plugins-base" >> "$out/nix-support/propagated-user-env-packages"
+      echo "gst_all_1.gst-plugins-good" >> "$out/nix-support/propagated-user-env-packages"
     '';
 
     meta = {

Diff for: src/Surface.zig

@@ -953,6 +953,8 @@ pub fn handleMessage(self: *Surface, msg: Message) !void {
         .present_surface => try self.presentSurface(),
 
         .password_input => |v| try self.passwordInput(v),
+
+        .bell => self.bell(),
     }
 }
 
@@ -4711,3 +4713,15 @@ fn presentSurface(self: *Surface) !void {
         {},
     );
 }
+
+fn bell(self: *Surface) void {
+    _ = self.rt_app.performAction(
+        .{ .surface = self },
+        .bell,
+        {},
+    ) catch |err| {
+        // We ignore this error because we don't want to fail this entire
+        // operation just because the apprt failed to activate the bell.
+        log.warn("apprt failed to activate the bell err={}", .{err});
+    };
+}

Diff for: src/apprt/action.zig

@@ -230,6 +230,9 @@ pub const Action = union(Key) {
     /// for changes.
     config_change: ConfigChange,
 
+    /// The system has received a request to activate the bell.
+    bell: void,
+
     /// Sync with: ghostty_action_tag_e
     pub const Key = enum(c_int) {
         quit,
@@ -271,6 +274,7 @@ pub const Action = union(Key) {
         color_change,
         reload_config,
         config_change,
+        bell,
     };
 
     /// Sync with: ghostty_action_u

Diff for: src/apprt/glfw.zig

@@ -240,6 +240,7 @@ pub const App = struct {
             .config_change,
             .toggle_maximize,
             .prompt_title,
+            .bell,
             => {
                 log.info("unimplemented action={}", .{action});
                 return false;

Diff for: src/apprt/gtk/App.zig

@@ -482,6 +482,7 @@ pub fn performAction(
         .toggle_split_zoom => self.toggleSplitZoom(target),
         .toggle_window_decorations => self.toggleWindowDecorations(target),
         .quit_timer => self.quitTimer(value),
+        .bell => self.bell(target),
 
         // Unimplemented
         .close_all_windows,
@@ -951,6 +952,16 @@ pub fn reloadConfig(
     self.config = config;
 }
 
+fn bell(
+    _: *App,
+    target: apprt.Target,
+) void {
+    switch (target) {
+        .app => {},
+        .surface => |surface| surface.rt_surface.bell(),
+    }
+}
+
 /// Call this anytime the configuration changes.
 fn syncConfigChanges(self: *App) !void {
     try self.updateConfigErrors();

Diff for: src/apprt/gtk/Surface.zig

@@ -26,6 +26,10 @@ const inspector = @import("inspector.zig");
 const gtk_key = @import("key.zig");
 const c = @import("c.zig").c;
 
+const gtk = @import("gtk");
+const gobject = @import("gobject");
+const glib = @import("glib");
+
 const log = std.log.scoped(.gtk_surface);
 
 /// This is detected by the OpenGL renderer to move to a single-threaded
@@ -1295,6 +1299,81 @@ fn showContextMenu(self: *Surface, x: f32, y: f32) void {
     c.gtk_popover_popup(@ptrCast(@alignCast(window.context_menu)));
 }
 
+pub fn bell(self: *Surface) void {
+    inline for (std.meta.fields(configpkg.Config.BellFeatures.Features)) |field| {
+        const feature = std.meta.stringToEnum(configpkg.Config.BellFeatures.Features, field.name) orelse unreachable;
+        const enabled = @field(self.app.config.@"bell-features", field.name);
+        if (enabled) {
+            switch (feature) {
+                .system => system: {
+                    const native = gtk.Widget.getNative(@ptrCast(@alignCast(self.overlay))) orelse break :system;
+                    const surface = native.getSurface() orelse break :system;
+                    surface.beep();
+                },
+                .audio => audio: {
+                    var arena = std.heap.ArenaAllocator.init(self.app.core_app.alloc);
+                    defer arena.deinit();
+                    const alloc = arena.allocator();
+                    const filename = self.app.config.@"bell-audio" orelse break :audio;
+                    const pathname = pathname: {
+                        if (std.fs.path.isAbsolute(filename))
+                            break :pathname alloc.dupeZ(u8, filename) catch |err| {
+                                log.warn("unable to allocate space for bell audio pathname: {}", .{err});
+                                break :audio;
+                            }
+                        else
+                            break :pathname std.fs.path.joinZ(alloc, &.{
+                                internal_os.xdg.config(alloc, .{ .subdir = "ghostty/media" }) catch |err| {
+                                    log.warn("unable to determine media config subdir: {}", .{err});
+                                    break :audio;
+                                },
+                                filename,
+                            }) catch |err| {
+                                log.warn("unable to allocate space for bell audio pathname: {}", .{err});
+                                break :audio;
+                            };
+                    };
+                    std.fs.accessAbsoluteZ(pathname, .{ .mode = .read_only }) catch {
+                        log.warn("unable to find sound file: {s}", .{filename});
+                        break :audio;
+                    };
+
+                    const file = gtk.MediaFile.newForFilename(pathname);
+                    const stream = file.as(gtk.MediaStream);
+
+                    _ = gobject.Object.signals.notify.connect(
+                        stream,
+                        ?*anyopaque,
+                        gtkStreamError,
+                        null,
+                        .{ .detail = "error" },
+                    );
+                    _ = gobject.Object.signals.notify.connect(
+                        stream,
+                        ?*anyopaque,
+                        gtkStreamEnded,
+                        null,
+                        .{ .detail = "ended" },
+                    );
+
+                    stream.setVolume(1.0);
+                    stream.play();
+                },
+            }
+        }
+    }
+}
+
+fn gtkStreamError(stream: *gtk.MediaStream, _: *gobject.ParamSpec, _: ?*anyopaque) callconv(.C) void {
+    const err = stream.getError();
+    if (err) |e|
+        log.err("error playing bell: {s} {d} {s}", .{ glib.quarkToString(e.f_domain), e.f_code, e.f_message orelse "" });
+}
+
+fn gtkStreamEnded(stream: *gtk.MediaStream, _: *gobject.ParamSpec, _: ?*anyopaque) callconv(.C) void {
+    stream.unref();
+}
+
 fn gtkRealize(area: *c.GtkGLArea, ud: ?*anyopaque) callconv(.C) void {
     log.debug("gl surface realized", .{});
 

Diff for: src/apprt/surface.zig

@@ -81,6 +81,9 @@ pub const Message = union(enum) {
     /// The terminal has reported a change in the working directory.
     pwd_change: WriteReq,
 
+    /// Bell
+    bell: void,
+
     pub const ReportTitleStyle = enum {
         csi_21_t,
 

Diff for: src/config/Config.zig

@@ -2272,6 +2272,30 @@ term: []const u8 = "xterm-ghostty",
 /// This only works on macOS since only macOS has an auto-update feature.
 @"auto-update-channel": ?build_config.ReleaseChannel = null,
 
+/// Bell features to enable if bell support is available in your runtime. The
+/// format of this is a list of features to enable separated by commas. If you
+/// prefix a feature with `no-` then it is disabled. If you omit a feature, its
+/// default value is used, so you must explicitly disable features you don't
+/// want.
+///
+/// Available features:
+///
+///   * `system` - Use a system function to play an audible sound. This differs
+///     from the `audio` feature in that the sound played is not customizable
+///     from within Ghostty. Your system may allow for the sound to be
+///     customized externally to Ghostty.
+///   * `audio` - Play a custom sound. (GTK only).
+///
+/// Example: `audio`, `no-audio`, `system`, `no-system`:
+///
+/// By default, no bell features are enabled.
+@"bell-features": BellFeatures = .{},
+
+/// If `audio` is an enabled bell feature, this is a path to an audio file.
+/// If the path is not absolute, it is considered relative to the `media`
+/// subdirectory of the Ghostty configuration directory.
+@"bell-audio": ?[:0]const u8 = null,
+
 /// This is set by the CLI parser for deinit.
 _arena: ?ArenaAllocator = null,
 
@@ -6913,3 +6937,11 @@ test "theme specifying light/dark sets theme usage in conditional state" {
         try testing.expect(cfg._conditional_set.contains(.theme));
     }
 }
+
+/// Bell features
+pub const BellFeatures = packed struct {
+    system: bool = false,
+    audio: bool = false,
+
+    pub const Features = std.meta.FieldEnum(@This());
+};

Diff for: src/termio/stream_handler.zig

@@ -325,9 +325,8 @@ pub const StreamHandler = struct {
         try self.terminal.printRepeat(count);
     }
 
-    pub fn bell(self: StreamHandler) !void {
-        _ = self;
-        log.info("BELL", .{});
+    pub fn bell(self: *StreamHandler) !void {
+        self.surfaceMessageWriter(.{ .bell = {} });
     }
 
     pub fn backspace(self: *StreamHandler) !void {