gtk: implement audio bell

Author: jcollie

include/ghostty.h

@@ -601,6 +601,7 @@ typedef enum {
   GHOSTTY_ACTION_RELOAD_CONFIG,
   GHOSTTY_ACTION_CONFIG_CHANGE,
   GHOSTTY_ACTION_CLOSE_WINDOW,
+  GHOSTTY_ACTION_BELL,
 } ghostty_action_tag_e;
 
 typedef union {

nix/devShell.nix

@@ -33,6 +33,7 @@
   gtk4,
   gtk4-layer-shell,
   gobject-introspection,
+  gst_all_1,
   libadwaita,
   blueprint-compiler,
   gettext,
@@ -179,6 +180,9 @@ in
         wayland
         wayland-scanner
         wayland-protocols
+        gst_all_1.gstreamer
+        gst_all_1.gst-plugins-base
+        gst_all_1.gst-plugins-good
       ];
 
     # This should be set onto the rpath of the ghostty binary if you want

nix/package.nix

@@ -15,6 +15,7 @@
   gtk4,
   gtk4-layer-shell,
   gobject-introspection,
+  gst_all_1,
   libadwaita,
   blueprint-compiler,
   libxml2,
@@ -113,6 +114,9 @@ in
         libadwaita
         gtk4
         glib
+        gst_all_1.gstreamer
+        gst_all_1.gst-plugins-base
+        gst_all_1.gst-plugins-good
         gsettings-desktop-schemas
       ]
       ++ lib.optionals enableX11 [
@@ -165,6 +169,10 @@ in
       mv $out/share/vim/vimfiles "$vim"
       ln -sf "$vim" "$out/share/vim/vimfiles"
       echo "$vim" >> "$out/nix-support/propagated-user-env-packages"
+
+      echo "gst_all_1.gstreamer" >> "$out/nix-support/propagated-user-env-packages"
+      echo "gst_all_1.gst-plugins-base" >> "$out/nix-support/propagated-user-env-packages"
+      echo "gst_all_1.gst-plugins-good" >> "$out/nix-support/propagated-user-env-packages"
     '';
 
     meta = {

src/Surface.zig

@@ -932,6 +932,8 @@ pub fn handleMessage(self: *Surface, msg: Message) !void {
         .present_surface => try self.presentSurface(),
 
         .password_input => |v| try self.passwordInput(v),
+
+        .bell => self.bell(),
     }
 }
 
@@ -4756,3 +4758,15 @@ fn presentSurface(self: *Surface) !void {
         {},
     );
 }
+
+fn bell(self: *Surface) void {
+    _ = self.rt_app.performAction(
+        .{ .surface = self },
+        .bell,
+        {},
+    ) catch |err| {
+        // We ignore this error because we don't want to fail this entire
+        // operation just because the apprt failed to activate the bell.
+        log.warn("apprt failed to activate the bell err={}", .{err});
+    };
+}

src/apprt/action.zig

@@ -244,6 +244,9 @@ pub const Action = union(Key) {
     /// Closes the currently focused window.
     close_window,
 
+    /// The system has received a request to activate the bell.
+    bell,
+
     /// Sync with: ghostty_action_tag_e
     pub const Key = enum(c_int) {
         quit,
@@ -287,6 +290,7 @@ pub const Action = union(Key) {
         reload_config,
         config_change,
         close_window,
+        bell,
     };
 
     /// Sync with: ghostty_action_u

src/apprt/glfw.zig

@@ -242,6 +242,7 @@ pub const App = struct {
             .toggle_maximize,
             .prompt_title,
             .reset_window_size,
+            .bell,
             => {
                 log.info("unimplemented action={}", .{action});
                 return false;

src/apprt/gtk/App.zig

@@ -510,6 +510,7 @@ pub fn performAction(
         .prompt_title => try self.promptTitle(target),
         .toggle_quick_terminal => return try self.toggleQuickTerminal(),
         .secure_input => self.setSecureInput(target, value),
+        .bell => self.bell(target),
 
         // Unimplemented
         .close_all_windows,
@@ -1014,6 +1015,16 @@ pub fn reloadConfig(
     self.config = config;
 }
 
+fn bell(
+    _: *App,
+    target: apprt.Target,
+) void {
+    switch (target) {
+        .app => {},
+        .surface => |surface| surface.rt_surface.bell(),
+    }
+}
+
 /// Call this anytime the configuration changes.
 fn syncConfigChanges(self: *App) !void {
     try self.updateConfigErrors();

src/apprt/gtk/Surface.zig

@@ -9,6 +9,7 @@ const adw = @import("adw");
 const gtk = @import("gtk");
 const gio = @import("gio");
 const gobject = @import("gobject");
+const glib = @import("glib");
 
 const Allocator = std.mem.Allocator;
 const build_config = @import("../../build_config.zig");
@@ -1239,6 +1240,74 @@ pub fn showDesktopNotification(
     c.g_application_send_notification(g_app, body.ptr, notification);
 }
 
+/// Handle bell features.
+pub fn bell(self: *Surface) void {
+    if (self.app.config.@"bell-features".system) system: {
+        // Handle "system" beep by calling the GTK "beep" API.
+
+        // FIXME: when surface is converted to zig-gobject
+        const native = gtk.Widget.getNative(@ptrCast(@alignCast(self.overlay))) orelse break :system;
+        const surface = native.getSurface() orelse break :system;
+        surface.beep();
+    }
+    if (self.app.config.@"bell-features".audio) audio: {
+        // Play a user-specified audio file.
+
+        const pathname, const optional = switch (self.app.config.@"bell-audio" orelse break :audio) {
+            .optional => |path| .{ path, true },
+            .required => |path| .{ path, false },
+        };
+
+        std.debug.assert(std.fs.path.isAbsolute(pathname));
+        const media_file = gtk.MediaFile.newForFilename(pathname);
+
+        if (!optional) {
+            _ = gobject.Object.signals.notify.connect(
+                media_file,
+                ?*anyopaque,
+                gtkStreamError,
+                null,
+                .{ .detail = "error" },
+            );
+        }
+        _ = gobject.Object.signals.notify.connect(
+            media_file,
+            ?*anyopaque,
+            gtkStreamEnded,
+            null,
+            .{ .detail = "ended" },
+        );
+
+        const media_stream = media_file.as(gtk.MediaStream);
+        media_stream.setVolume(1.0);
+        media_stream.play();
+    }
+}
+
+/// Handle a stream that is in an error state.
+fn gtkStreamError(media_file: *gtk.MediaFile, _: *gobject.ParamSpec, _: ?*anyopaque) callconv(.C) void {
+    const path = path: {
+        const file = media_file.getFile() orelse break :path null;
+        break :path file.getPath();
+    };
+    defer if (path) |p| glib.free(p);
+
+    const media_stream = media_file.as(gtk.MediaStream);
+    const err = media_stream.getError() orelse return;
+
+    log.warn("error playing bell from {s}: {s} {d} {s}", .{
+        path orelse "<<unknown>>",
+        glib.quarkToString(err.f_domain),
+        err.f_code,
+        err.f_message orelse "",
+    });
+}
+
+/// Stream is finished, release the memory.
+fn gtkStreamEnded(media_file: *gtk.MediaFile, _: *gobject.ParamSpec, _: ?*anyopaque) callconv(.C) void {
+    media_file.unref();
+}
+
 fn gtkRealize(area: *c.GtkGLArea, ud: ?*anyopaque) callconv(.C) void {
     log.debug("gl surface realized", .{});
 

src/apprt/surface.zig

@@ -81,6 +81,9 @@ pub const Message = union(enum) {
     /// The terminal has reported a change in the working directory.
     pwd_change: WriteReq,
 
+    /// Bell
+    bell: void,
+
     pub const ReportTitleStyle = enum {
         csi_21_t,
 

src/config/Config.zig

@@ -2329,6 +2329,34 @@ term: []const u8 = "xterm-ghostty",
 /// This only works on macOS since only macOS has an auto-update feature.
 @"auto-update-channel": ?build_config.ReleaseChannel = null,
 
+/// Bell features to enable if bell support is available in your runtime. The
+/// format of this is a list of features to enable separated by commas. If you
+/// prefix a feature with `no-` then it is disabled. If you omit a feature, its
+/// default value is used, so you must explicitly disable features you don't
+/// want.
+///
+/// Available features:
+///
+///   * `system` - Use a system function to play an audible sound. This differs
+///     from the `audio` feature in that the sound played is not customizable
+///     from within Ghostty. Your system may allow for the sound to be
+///     customized externally to Ghostty (GTK only).
+///   * `audio` - Play a custom sound. (GTK only).
+///
+/// Example: `audio`, `no-audio`, `system`, `no-system`:
+///
+/// By default, no bell features are enabled.
+@"bell-features": BellFeatures = .{},
+
+/// If `audio` is an enabled bell feature, this is a path to an audio file. If
+/// the path is not absolute, it is considered relative to the directory of the
+/// configuration file that it is referenced from, or from the current working
+/// directory if this is used as a CLI flag. The path may be prefixed with `~/`
+/// to reference the user's home directory.
+///
+/// GTK only.
+@"bell-audio": ?Path = null,
+
 /// This is set by the CLI parser for deinit.
 _arena: ?ArenaAllocator = null,
 
@@ -6786,3 +6814,11 @@ test "theme specifying light/dark sets theme usage in conditional state" {
         try testing.expect(cfg._conditional_set.contains(.theme));
     }
 }
+
+/// Bell features
+pub const BellFeatures = packed struct {
+    system: bool = false,
+    audio: bool = false,
+
+    pub const Features = std.meta.FieldEnum(@This());
+};