CompactTM.sysml

package CompactTM {
    private import TM::*; 

    part tankModelcompact :> tankModel {
        part redefines tank {
            attribute redefines tankDiameter = 3.9[m];
            attribute redefines dischargeCoefficient = 3.2;
        }

        flow LH2 from valve.valveBehavior.valveOutput.Qo to tank.tankBehavior.tankInput.Qin;
    }

    requirement smallTMRequirement : TankRequirement {
        subject references tankModelcompact.tank;
        doc /* The diameter of the small tank shall be lower than 4[m] */
        assume constraint { tankModelcompact.tank.tankDiameter < 4[m] }
    }

    analysis smallTMAnalysis : TankAnalysis {
        subject references tankModelcompact;
    }

    requirement maxHeightRequirementSmall :> smallTMRequirement : MaxHeightRequirement {
        subject references tankModelcompact.tank;
        doc /* The maximum height allowable of the small tank is 10 [m]. */
        attribute redefines requiredMaxHeight = 10 [m];
    }

    analysis maxHeightAnalysisSmall : MaxHeightAnalysis {
        subject references tankModelcompact;
        redefines simCond { 
            redefines fromTime = 50[s]; 
            redefines toTime = 400[s]; 
        }
        @MgS::Extension::MATLAB {
            command = (
                "try, set_param('TM','StartTime','50','StopTime','400'); catch, end"
            );
        }
        return simulatedMaxHeight : LengthValue = tankModelcompact.tank.tankBehavior.tankOutput.h{
            @MgS::SimRet {
                ret = Retrieval::MAX; name = "simulatedMaxHeight";
            }
        }
    }

    requirement minVolumeRequirementSmall :> smallTMRequirement : MinVolumeRequirement {
        subject references tankModelcompact.tank;
        doc /* The target minimum volume of small TMs is 100 [L]. */
        attribute redefines requiredMinVolume = 100 [L];
    }

    analysis minVolumeAnalysisSmall : MinVolumeAnalysis {
        subject references tankModelcompact;
        redefines simCond { 
            redefines fromTime = 50[s]; 
            redefines toTime = 400[s]; 
        }
        @MgS::Extension::MATLAB {
            command = (
                "try, set_param('TM','StartTime','50','StopTime','400'); catch, end"
            );
        }
        return simulatedFinalVolume:VolumeFlowRateValue = tankModelcompact.tank.tankBehavior.tankOutput.V{
            @MgS::SimRet {
                ret = Retrieval::FINAL; name = "simulatedFinalVolume";
            }
        }
    }

    satisfy minVolumeRequirementSmall by tankModelcompact.tank;
    satisfy maxHeightRequirementSmall by tankModelcompact.tank;
}