ffbtools-flake/flake.nix at master · gmvar/ffbtools-flake · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
{
  description = "ffbtools";

  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
    flake-utils.url = "github:numtide/flake-utils";
  };

  outputs =
    {
      self,
      nixpkgs,
      flake-utils,
    }:
    flake-utils.lib.eachDefaultSystem (
      system:
      let
        pkgs = nixpkgs.legacyPackages.${system};
      in
      {
        packages = rec {
          default = ffbtools;
          ffbtools = pkgs.multiStdenv.mkDerivation {
            pname = "ffbtools";
            version = "0-unstable-2025-05-28";

            src = pkgs.fetchFromGitHub {
              owner = "berarma";
              repo = "ffbtools";
              rev = "5b089d3c59166001f8bbcf4ef4b01c756a1e1ac3";
              sha256 = "fQfVp5VUrpmpUGKLNwYT8QQIk9bu3jl1Ko9jE49r5sc=";
            };

            installPhase = ''
              runHook preInstall
              mkdir -p $out/bin $out/lib
              cp bin/* $out/bin
              install -m755 build/libffbwrapper-i386.so build/libffbwrapper-x86_64.so $out/lib/
              substituteInPlace $out/bin/ffbwrap \
                --replace-fail '/usr/local/lib' "$out/lib"
              runHook postInstall
            '';

            meta = {
              description = "Force feedback tools for Linux, for tuning and debugging FFB wheels/joysticks";
              homepage = "https://github.com/berarma/ffbtools";
              license = pkgs.lib.licenses.gpl3Plus;
              platforms = pkgs.lib.platforms.linux;
              mainProgram = "ffbwrap";
            };
          };
        };
      }
    );
}