GNUstep.cmake

[super-betonamu-jin]

# Query gnustep-config
execute_process(
    COMMAND sh gnustep-config --objc-flags
    OUTPUT_VARIABLE GNUSTEP_OBJC_FLAGS
    OUTPUT_STRIP_TRAILING_WHITESPACE
    COMMAND_ERROR_IS_FATAL ANY
)

execute_process(
    COMMAND sh gnustep-config --objc-libs
    OUTPUT_VARIABLE GNUSTEP_OBJC_LIBS
    OUTPUT_STRIP_TRAILING_WHITESPACE
    COMMAND_ERROR_IS_FATAL ANY
)

execute_process(
    COMMAND sh gnustep-config --base-libs
    OUTPUT_VARIABLE GNUSTEP_BASE_LIBS
    OUTPUT_STRIP_TRAILING_WHITESPACE
    COMMAND_ERROR_IS_FATAL ANY
)

# Prepare lists
set(GNUSTEP_DEFINITIONS "")
set(GNUSTEP_INCLUDES "")
set(GNUSTEP_OPTIONS "")

separate_arguments(GNUSTEP_OBJC_FLAGS)

foreach(flag ${GNUSTEP_OBJC_FLAGS})
    if(flag MATCHES "^-D(.+)")
        # Preprocessor definitions
        string(REGEX REPLACE "^-D" "" def ${flag})
        list(APPEND GNUSTEP_DEFINITIONS ${def})
    elseif(flag MATCHES "^-I(.+)")
        # Include directories
        string(REGEX REPLACE "^-I" "" inc ${flag})
        list(APPEND GNUSTEP_INCLUDES ${inc})
    elseif(flag MATCHES "^-M.*")
        # Ignore all -M* flags (dependency generation, etc.)
    else()
        # Other compiler options
        list(APPEND GNUSTEP_OPTIONS ${flag})
    endif()
endforeach()

list(APPEND GNUSTEP_OPTIONS -fobjc-arc -fobjc-arc-exceptions)

Include it in your CMakeLists.txt:

include(${CMAKE_SOURCE_DIR}/cmake/GNUstep.cmake)

Now you can use it:

add_executable(hello hello.m)
target_include_directories(hello PRIVATE ${GNUSTEP_INCLUDES})
target_compile_definitions(hello PRIVATE ${GNUSTEP_DEFINITIONS})
target_compile_options(hello PRIVATE ${GNUSTEP_OPTIONS})
target_link_libraries(hello PRIVATE ${GNUSTEP_OBJC_LIBS} ${GNUSTEP_BASE_LIBS})

You can easily extend it to include GUI.