gradle-org-conventions-plugin/build.gradle.kts at master · gradle/gradle-org-conventions-plugin · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
plugins {
    `java-gradle-plugin`
    alias(libs.plugins.plugin.publish)
    `maven-publish`
    signing
}

rootProject.group = "io.github.gradle"
rootProject.version = "0.14.1"

java {
    toolchain {
        languageVersion.set(JavaLanguageVersion.of(17))
    }
}

repositories {
    mavenCentral()
    gradlePluginPortal()
}

dependencies {
    compileOnly(libs.develocity.plugin)

    implementation(gradleApi())

    testImplementation(platform(libs.jackson.bom))
    testImplementation("com.fasterxml.jackson.core:jackson-annotations")
    testImplementation("tools.jackson.core:jackson-core")
    testImplementation("tools.jackson.core:jackson-databind")
    testImplementation(libs.develocity.plugin)
    testImplementation(libs.mockitoJunitJupiter)
}

gradlePlugin {
    website = "https://github.com/gradle/gradle-org-conventions-plugin"
    vcsUrl = "https://github.com/gradle/gradle-org-conventions-plugin.git"

    plugins.create("conventionsPlugin") {
        id = "io.github.gradle.develocity-conventions-plugin"
        implementationClass = "io.github.gradle.conventions.DevelocityConventionsPlugin"
        displayName = "Develocity Conventions Plugin"
        description = "Develocity Conventions Plugin for OSS Gradle projects"
        website = "https://github.com/gradle/gradle-org-conventions-plugin"
        vcsUrl = "https://github.com/gradle/gradle-org-conventions-plugin.git"
        tags = listOf("gradle", "develocity")
    }
}

signing {
    useInMemoryPgpKeys(
        project.providers.environmentVariable("PGP_SIGNING_KEY").orNull,
        project.providers.environmentVariable("PGP_SIGNING_KEY_PASSPHRASE").orNull
    )

    setRequired({
        providers.environmentVariable("CI").isPresent
    })
}

tasks.named("publishPlugins", Task::class.java) {
    dependsOn("check")
}

testing {
    suites {
        withType<JvmTestSuite> {
            useJUnitJupiter(libs.versions.junit.get())
        }
    }
}