build.gradle

plugins {
  id 'com.github.johnrengelman.shadow' version '4.0.3'
}

dependencies {
  compile project(':spectator-api')
  compile project(':spectator-ext-gc')
  compile project(':spectator-ext-jvm')
  compile "com.eclipsesource.minimal-json:minimal-json"
  compile "com.typesafe:config"
  compile 'io.dropwizard.metrics:metrics-core:3.1.2'
  compile 'org.apache.spark:spark-core_2.10:1.6.1'
}

jar {
  manifest {
    attributes(
      "Automatic-Module-Name": "com.netflix.spectator.spark"
    )
  }
}

shadowJar {
  classifier = 'shadow'

  relocate 'com.eclipsesource.json', 'com.netflix.spectator.shadowedjson'

  // The dependencies not listed here should come from the spark distribution
  dependencies {
    include project(':spectator-api')
    include project(':spectator-ext-gc')
    include project(':spectator-ext-jvm')
    include dependency("com.eclipsesource.minimal-json:minimal-json")
    include dependency("com.typesafe:config")
  }
}

publishing {
  publications {
    nebula(MavenPublication) {
      artifact shadowJar
    }
  }
}