toubkal_os/linker.ld at master · halimbahae/toubkal_os · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
ENTRY(_start)

SECTIONS {
    . = 0x40080000;

    /* Boot stub must be the very first thing in the binary. */
    .text.boot : {
        KEEP(*(.text.boot))
    }

    .text : {
        *(.text .text.*)
    }

    .rodata : {
        *(.rodata .rodata.*)
    }

    .data : {
        *(.data .data.*)
    }

    . = ALIGN(8);
    __bss_start = .;
    .bss : {
        *(.bss .bss.*)
        *(COMMON)
    }
    . = ALIGN(8);
    __bss_end = .;

    /* 64 KB stack immediately after BSS. Grows downward — SP starts at top. */
    . = ALIGN(16);
    _stack_bottom = .;
    . += 0x10000;
    _stack_top = .;

    /* 256 MB Heap immediately after stack, Page Aligned */
    . = ALIGN(4096);
    __heap_start = .;
    . += 0x10000000;
    __heap_end = .;

    /DISCARD/ : {
        *(.eh_frame)
        *(.note .note.*)
    }
}