Support for Sidecar Pattern on Linux App Service

[marcindulak]

Is there an existing issue for this?

• I have searched the existing issues

Community Note

• Please vote on this issue by adding a 👍 reaction to the original issue to help the community and maintainers prioritize this request
• Please do not leave "+1" or "me too" comments, they generate extra noise for issue followers and do not help prioritize the request
• If you are interested in working on this issue or have submitted a pull request, please leave a comment and review the contribution guide to help.

Support for Sidecar Pattern on Linux App Service

Description

Sidecar Pattern on Linux App Service is a preview feature which is configurable through an ARM template

Implementation may require a reintroduction of linux_fx_version argument, deprecated by azurerm 3 https://registry.terraform.io/providers/hashicorp/azurerm/3.93.0/docs/resources/app_service, or maybe another argument could be introduced to control the internal provider logic to distinguish between the linux_fx_version of "DOCKER" or "SITECONTAINERS" type.

New or Affected Resource(s)/Data Source(s)

azurerm_linux_web_app

Potential Terraform Configuration

resource "azurerm_linux_web_app" "this" { 
  site_config {
    linux_fx_version = "SITECONTAINERS|<user_main/image_main:tag_main>|<user_side1/image_side1:tag_side1>...|user_sideN/image_sideN:tag_sideN>"
 
   sitecontainers {
     image = "user_main/image_main:tag_main"
     target_port = 80
     is_main = true
    }
 
   sitecontainers {
     image = "user_side1/image_side1:tag_side1"
     target_port = 2000
     is_main = false
    }
  }
}

References

https://techcommunity.microsoft.com/t5/apps-on-azure-blog/a-glimpse-into-the-future-the-sidecar-pattern-on-linux-app/ba-p/4045680

The discussions about linux_fx_version in #16290 may be relevant to the implementation of the present feature request.

[josh-yates]

If you're still looking for a way to use the sidecar features via Terraform, there's a workaround similar to this answer in the issue that was previously referenced around Docker Compose. In summary:

• Create an App Service resource for a Linux container as normal
  • Note this approach also works for deployment slots, with changes to resource types for the AzApi steps
• Use the AzApi provider to change the linuxFxVersion to SITECONTAINERS
• Use the AzApi provider again to create resources for the main container and sidecars
  • The main one is still needed as the FX version change above wipes out existing container details

Sample code:

resource "azurerm_linux_web_app" "myapp" {
  ...
}

resource "azapi_update_resource" "enable_sidecar" {
  resource_id = azurerm_linux_web_app.myapp.id
  type        = "Microsoft.Web/sites@2024-04-01"
  body = {
    properties = {
      siteConfig = {
        linuxFxVersion = "SITECONTAINERS"
      }
    }
  }
  lifecycle {
    replace_triggered_by = [azurerm_linux_web_app.myapp]
  }
}

resource "azapi_resource" "main_container" {
  depends_on = [azapi_update_resource.enable_sidecar]
  type       = "Microsoft.Web/sites/sitecontainers@2024-04-01"
  parent_id  = azurerm_linux_web_app.myapp.id
  name       = "main"
  # https://learn.microsoft.com/en-us/rest/api/appservice/web-apps/create-or-update-site-container?view=rest-appservice-2024-04-01#request-body
  body = {
    properties = {
      image          = "registry.domain/main-image:tag"
      isMain         = true
      authType       = "UserCredentials"
      userName       = "username"
      passwordSecret = "password"
      targetPort     = "80"
    }
  }
}

resource "azapi_resource" "sidecar_container" {
  depends_on = [azapi_update_resource.enable_sidecar]
  type       = "Microsoft.Web/sites/sitecontainers@2024-04-01"
  parent_id  = azurerm_linux_web_app.myapp.id
  name       = "sidecar1"
  # https://learn.microsoft.com/en-us/rest/api/appservice/web-apps/create-or-update-site-container?view=rest-appservice-2024-04-01#request-body
  body = {
    properties = {
      image          = "registry.domain/sidecar-image:tag"
      isMain         = false
      authType       = "UserCredentials"
      userName       = "username"
      passwordSecret = "password"
      targetPort     = "80"
      environmentVariables = [
        {
          name  = "AN_ENV_VAR"
          value = "A value"
        }
      ]
    }
  }
}

[elieserr]

this feature might be useful beyond workaround

[DanielHabenicht]

The comment from @josh-yates can also be applied to app service slots (and it would be nice that if this feature request can be expanded to also support slots).
You just need to replace

• "Microsoft.Web/sites@2024-04-01" with "Microsoft.Web/sites/slots@2024-04-01"
• "Microsoft.Web/sites/sitecontainers@2024-04-01" with "Microsoft.Web/sites/slots/sitecontainers@2024-04-01"

and reference the slot azurerm_linux_web_app_slot instead of the app service.

[igorpupkinable]

Can anyone comment on local_mysql_enabled flag and if it relates to this issue? I was hoping that local_mysql_enabled used Sidecar pattern to run MySQL on a side but I could not get it working at all with azurerm_linux_web_app.

[coreyd-valcre]

Has there been any movement on adding something here or do we still need to use the workround?

[dchauran-skillable]

Seems like this is still the case. There is a PR from Microsoft to add this support, however it seems as though it has been waiting for a review for a few months.