nvim/flake.nix at main · hasundue/nvim · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
{
  description = "My Neovim flake";

  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixpkgs-unstable";

    im-switch-nvim = {
      url = "github:drop-stones/im-switch.nvim";
      flake = false;
    };

    opencode-nvim = {
      url = "github:NickvanDyke/opencode.nvim";
      flake = false;
    };

    tree-sitter-lean = {
      url = "github:Julian/tree-sitter-lean";
      flake = false;
    };

    lean-nvim = {
      url = "github:Julian/lean.nvim";
      flake = false;
    };
  };

  outputs =
    { nixpkgs, self, ... }@inputs:
    let
      lib = nixpkgs.lib;

      forSystem =
        op: system:
        op (
          import nixpkgs {
            inherit system;
            overlays = [ self.overlays.default ];
          }
        );

      supportedSystems = [
        "x86_64-linux"
        "aarch64-linux"
      ];

      forEachSystem = op: lib.genAttrs supportedSystems (forSystem op);

      mkOverlay =
        opts:
        lib.composeManyExtensions [
          (import ./overlays/nvim.nix opts)
          (import ./overlays/plugins.nix {
            inherit (inputs)
              im-switch-nvim
              opencode-nvim
              tree-sitter-lean
              lean-nvim
              ;
          })
        ];
    in
    {
      devShells = forEachSystem (
        pkgs:
        lib.mapAttrs (
          name: neovim:
          pkgs.mkShell {
            buildInputs = [ neovim ];
          }
        ) pkgs.nvim.packages
      );

      lib = { inherit supportedSystems; };

      overlays = {
        default = mkOverlay { };
        dev = mkOverlay { dev = true; };
      };

      packages = forEachSystem (pkgs: pkgs.nvim.packages);
    };
}