feature: amp-126 init project

coling01 · coling01 · commit 55fe2f2ce25a · 2025-12-08T19:07:18.000Z
diff --git a/build.gradle b/build.gradle
@@ -0,0 +1,43 @@
+plugins {
+  id 'application'
+  id 'java'
+  id 'org.springframework.boot' version '4.0.0'
+  id 'io.spring.dependency-management' version '1.1.7'
+  id 'jacoco'
+  id 'maven-publish'
+  id 'com.github.ben-manes.versions' version '0.53.0'
+  id 'org.cyclonedx.bom' version '2.4.1'
+  id 'com.gorylenko.gradle-git-properties' version '2.5.3'
+  id 'com.avast.gradle.docker-compose' version '0.17.12'
+}
+
+group = 'uk.gov.hmcts.cp'
+version = System.getProperty('ARTEFACT_VERSION') ?: '0.0.999'
+
+apply {
+  from("$rootDir/gradle/dependencies/java-core.gradle")
+  from("$rootDir/gradle/dependencies/spring-core.gradle")
+
+  from("$rootDir/gradle/github/repositories.gradle")
+  from("$rootDir/gradle/github/java.gradle")
+  from("$rootDir/gradle/github/dependency.gradle")
+  from("$rootDir/gradle/github/pmd.gradle")
+  from("$rootDir/gradle/github/test.gradle")
+  from("$rootDir/gradle/github/jar.gradle")
+
+  from("$rootDir/gradle/tasks/apitest.gradle")
+  from("$rootDir/gradle/tasks/docker.gradle")
+}
+
+springBoot {
+  buildInfo {
+    properties {
+      name = project.name
+      version = project.version.toString()
+    }
+  }
+}
+
+dependencies {
+  implementation('uk.gov.hmcts.cp:api-cp-crime-courthearing-cases-results:0.0.0-a65d290')
+}
diff --git a/docker/Dockerfile b/docker/Dockerfile
@@ -0,0 +1,10 @@
+# Dockerfile (project root)
+FROM eclipse-temurin:21-jre-alpine
+
+WORKDIR /app
+
+COPY build/libs/*.jar /app/
+
+EXPOSE ${SERVER_PORT:-8082}
+
+ENTRYPOINT ["sh","-c","exec java -jar $(ls /app/*.jar | grep -v 'plain' | head -n1)"]
diff --git a/docker/docker-compose.yml b/docker/docker-compose.yml
@@ -0,0 +1,10 @@
+services:
+  app:
+    container_name: app
+    build:
+      context: ..
+      dockerfile: docker/Dockerfile
+    ports:
+      - "8082:8082"
+    environment:
+      SERVER_PORT: 8082
diff --git a/gradle/dependencies/java-core.gradle b/gradle/dependencies/java-core.gradle
@@ -0,0 +1,21 @@
+ext {
+  log4JVersion = "2.24.3"
+  logbackVersion = "1.5.18"
+  lombokVersion = "1.18.38"
+  mapstructVersion = "1.5.5.Final"
+}
+
+dependencies {
+  implementation 'net.logstash.logback:logstash-logback-encoder:8.1'
+  implementation 'org.apache.logging.log4j:log4j-to-slf4j'
+  implementation 'ch.qos.logback:logback-classic'
+  implementation 'ch.qos.logback:logback-core'
+
+  compileOnly group: 'org.projectlombok', name: 'lombok', version: lombokVersion
+  annotationProcessor group: 'org.projectlombok', name: 'lombok', version: lombokVersion
+  testCompileOnly group: 'org.projectlombok', name: 'lombok', version: lombokVersion
+  testAnnotationProcessor group: 'org.projectlombok', name: 'lombok', version: lombokVersion
+
+  implementation "org.mapstruct:mapstruct:$mapstructVersion"
+  annotationProcessor "org.mapstruct:mapstruct-processor:$mapstructVersion"
+}
diff --git a/gradle/dependencies/spring-core.gradle b/gradle/dependencies/spring-core.gradle
@@ -0,0 +1,11 @@
+dependencies {
+  implementation 'org.springframework.boot:spring-boot-starter-web'
+  implementation 'org.springframework.boot:spring-boot-starter-aspectj'
+
+  testImplementation "org.springframework.boot:spring-boot-starter-webmvc-test"
+
+  testImplementation('org.springframework.boot:spring-boot-starter-test') {
+    exclude group: 'junit', module: 'junit'
+    exclude group: 'org.junit.vintage', module: 'junit-vintage-engine'
+  }
+}
diff --git a/gradle/github/dependency.gradle b/gradle/github/dependency.gradle
@@ -0,0 +1,11 @@
+// check dependencies upon release ONLY
+tasks.named("dependencyUpdates").configure {
+  def isNonStable = { String version ->
+    def stableKeyword = ['RELEASE', 'FINAL', 'GA'].any { qualifier -> version.toUpperCase().contains(qualifier) }
+    def regex = /^[0-9,.v-]+$/
+    return !stableKeyword && !(version ==~ regex)
+  }
+  rejectVersionIf {
+    isNonStable(it.candidate.version) && !isNonStable(it.currentVersion)
+  }
+}
diff --git a/gradle/github/jar.gradle b/gradle/github/jar.gradle
@@ -0,0 +1,34 @@
+jar {
+  enabled = true
+  archiveClassifier.set('plain')
+  manifest {
+    attributes(
+      'Implementation-Title': project.name,
+      'Implementation-Version': project.version.toString()
+    )
+  }
+  if (file("CHANGELOG.md").exists()) {
+    from('CHANGELOG.md') {
+      into 'META-INF'
+    }
+  } else {
+    println "⚠️  CHANGELOG.md not found, skipping inclusion in JAR"
+  }
+}
+
+bootJar {
+  archiveFileName = "${rootProject.name}-${project.version}.jar"
+
+  manifest {
+    attributes('Implementation-Version': project.version.toString())
+  }
+}
+
+tasks.named('composeBuild') {
+  dependsOn tasks.named('bootJar')
+}
+
+tasks.withType(AbstractArchiveTask).configureEach {
+  preserveFileTimestamps = false
+  reproducibleFileOrder = true
+}
diff --git a/gradle/github/java.gradle b/gradle/github/java.gradle
@@ -0,0 +1,12 @@
+java {
+  sourceCompatibility = JavaVersion.VERSION_21
+  targetCompatibility = JavaVersion.VERSION_21
+}
+tasks.withType(JavaCompile).configureEach {
+  options.compilerArgs << "-Xlint:unchecked" << "-Werror"
+}
+
+// https://github.com/gradle/gradle/issues/16791
+tasks.withType(JavaExec).configureEach {
+  javaLauncher.set(javaToolchains.launcherFor(java.toolchain))
+}
diff --git a/gradle/github/pmd.gradle b/gradle/github/pmd.gradle
@@ -0,0 +1,29 @@
+apply plugin: 'pmd'
+
+pmd {
+  ruleSets = []
+  ruleSetFiles = files(".github/pmd-ruleset.xml")
+  ignoreFailures = false
+}
+
+tasks.named("pmdMain").configure {
+  onlyIf { gradle.startParameter.taskNames.contains(name) }
+}
+
+tasks.named("pmdTest").configure {
+  enabled = false
+}
+
+tasks.withType(Pmd) {
+  reports {
+    xml.required.set(true)
+    html.required.set(true)
+  }
+}
+
+tasks.withType(Checkstyle).configureEach {
+  def generatedDir = file("${layout.buildDirectory.get().asFile.absolutePath}/generated/src/main/java").canonicalPath
+  source = source.filter { file ->
+    !file.canonicalPath.startsWith(generatedDir)
+  }
+}
diff --git a/gradle/github/repositories.gradle b/gradle/github/repositories.gradle
@@ -0,0 +1,46 @@
+def githubActor = project.findProperty("github.actor") ?: System.getenv("GITHUB_ACTOR")
+def githubToken = project.findProperty("github.token") ?: System.getenv("GITHUB_TOKEN")
+def githubRepo = System.getenv("GITHUB_REPOSITORY")
+
+def azureADOArtifactRepository = 'https://pkgs.dev.azure.com/hmcts/Artifacts/_packaging/hmcts-lib/maven/v1'
+def azureADOArtifactActor = System.getenv("AZURE_DEVOPS_ARTIFACT_USERNAME")
+def azureADOArtifactToken = System.getenv("AZURE_DEVOPS_ARTIFACT_TOKEN")
+
+repositories {
+  mavenLocal()
+  mavenCentral()
+  maven {
+    url = azureADOArtifactRepository
+  }
+}
+
+publishing {
+  publications {
+    mavenJava(MavenPublication) {
+      artifact(tasks.named('bootJar'))
+      artifact(tasks.named('jar'))
+      pom {
+        name = project.name
+        url = "https://github.com/${githubRepo ?: 'org/repo'}"
+      }
+    }
+  }
+  repositories {
+    maven {
+      name = "GitHubPackages"
+      url = uri("https://maven.pkg.github.com/$githubRepo")
+      credentials {
+        username = githubActor
+        password = githubToken
+      }
+    }
+    maven {
+      name = "AzureArtifacts"
+      url = uri(azureADOArtifactRepository)
+      credentials {
+        username = azureADOArtifactActor
+        password = azureADOArtifactToken
+      }
+    }
+  }
+}
diff --git a/gradle/github/test.gradle b/gradle/github/test.gradle
@@ -0,0 +1,33 @@
+tasks.named('test') {
+  useJUnitPlatform {
+  }
+  systemProperty 'API_SPEC_VERSION', project.version
+  failFast = true
+  // Mockito must be added as an agent, see:
+  // https://javadoc.io/doc/org.mockito/mockito-core/latest/org.mockito/org/mockito/Mockito.html#0.3
+  jvmArgs += [
+    "-javaagent:${configurations.testRuntimeClasspath.find { it.name.contains('mockito-core') }}", '-Xshare:off'
+  ]
+  testLogging {
+    events "passed", "skipped", "failed"
+    exceptionFormat = 'full'
+    showStandardStreams = true
+  }
+  reports {
+    junitXml.required.set(true)
+    html.required.set(true)
+  }
+}
+
+tasks.named('jacocoTestReport') {
+  dependsOn tasks.named('test')
+  executionData fileTree(
+    dir: layout.buildDirectory.dir("jacoco").get().asFile,
+    include: ["*.exec"]
+  )
+  reports {
+    xml.required.set(true)
+    csv.required.set(false)
+    html.required.set(true)
+  }
+}
diff --git a/gradle/tasks/apitest.gradle b/gradle/tasks/apitest.gradle
@@ -0,0 +1,34 @@
+tasks.register('api', Test) {
+  description = "Runs api tests against docker-compose stack"
+  group = "Verification"
+
+  mustRunAfter tasks.named('test')
+
+  testClassesDirs = sourceSets.apiTest.output.classesDirs
+  classpath       = sourceSets.apiTest.runtimeClasspath
+  useJUnitPlatform()
+
+  dependsOn tasks.composeUp
+  finalizedBy tasks.composeDown
+}
+
+tasks.named('check') {
+  dependsOn tasks.named('api')
+}
+
+tasks.named('build') {
+  dependsOn tasks.named('test')
+  dependsOn tasks.named('api')
+}
+
+sourceSets {
+  apiTest {
+    java {
+      compileClasspath += sourceSets.main.output
+      runtimeClasspath += sourceSets.main.output
+    }
+  }
+}
+
+dependencies {
+}
diff --git a/gradle/tasks/docker.gradle b/gradle/tasks/docker.gradle
@@ -0,0 +1,18 @@
+dockerCompose {
+  useComposeFiles = ['docker/docker-compose.yml']
+  startedServices = ['app']
+
+  buildBeforeUp = true
+  waitForTcpPorts = true
+  upAdditionalArgs = ['--wait', '--wait-timeout', '30']
+
+  captureContainersOutput = true
+  removeOrphans = true
+  stopContainers = true
+  removeContainers = true
+
+  projectName = "${rootProject.name}"
+
+  useDockerComposeV2 = true
+  dockerExecutable = 'docker'
+}
diff --git a/src/main/java/uk/gov/hmcts/cp/Application.java b/src/main/java/uk/gov/hmcts/cp/Application.java
@@ -0,0 +1,13 @@
+package uk.gov.hmcts.cp;
+
+import org.springframework.boot.SpringApplication;
+import org.springframework.boot.autoconfigure.SpringBootApplication;
+
+@SpringBootApplication
+
+public class Application {
+
+    public static void main(final String[] args) {
+        SpringApplication.run(Application.class, args);
+    }
+}
diff --git a/src/main/java/uk/gov/hmcts/cp/controllers/RootController.java b/src/main/java/uk/gov/hmcts/cp/controllers/RootController.java
@@ -0,0 +1,19 @@
+package uk.gov.hmcts.cp.controllers;
+
+import lombok.AllArgsConstructor;
+import lombok.extern.slf4j.Slf4j;
+import org.springframework.http.ResponseEntity;
+import org.springframework.web.bind.annotation.GetMapping;
+import org.springframework.web.bind.annotation.RestController;
+
+@RestController
+@AllArgsConstructor
+@Slf4j
+public class RootController {
+
+    @GetMapping("/")
+    public ResponseEntity<String> getRoot() {
+        log.info("START");
+        return ResponseEntity.ok("Hello");
+    }
+}
diff --git a/src/test/java/uk/gov/hmcts/cp/controllers/RootControllerTest.java b/src/test/java/uk/gov/hmcts/cp/controllers/RootControllerTest.java
@@ -0,0 +1,7 @@
+package uk.gov.hmcts.cp.controllers;
+
+import static org.junit.jupiter.api.Assertions.*;
+
+class RootControllerTest {
+
+}
diff --git a/src/test/java/uk/gov/hmcts/cp/controllers/integration/IntegrationTestBase.java b/src/test/java/uk/gov/hmcts/cp/controllers/integration/IntegrationTestBase.java
@@ -0,0 +1,16 @@
+package uk.gov.hmcts.cp.controllers.integration;
+
+import jakarta.annotation.Resource;
+import lombok.extern.slf4j.Slf4j;
+import org.springframework.boot.test.context.SpringBootTest;
+import org.springframework.boot.webmvc.test.autoconfigure.AutoConfigureMockMvc;
+import org.springframework.test.web.servlet.MockMvc;
+
+@SpringBootTest
+@AutoConfigureMockMvc
+@Slf4j
+public abstract class IntegrationTestBase {
+
+    @Resource
+    protected MockMvc mockMvc;
+}
diff --git a/src/test/java/uk/gov/hmcts/cp/controllers/integration/RootControllerIntegrationTest.java b/src/test/java/uk/gov/hmcts/cp/controllers/integration/RootControllerIntegrationTest.java
