WallGen/PKGBUILD at main · hobbypunk90/WallGen · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
# Maintainer: Marcel Hoppe <hoppe.marcel@gmail.com>

pkgname=wallgen-git
pkgver=26.3.1
pkgrel=1
pkgdesc='WallGen is a tool to generate wallpapers matching for your display configuration.'
arch=('any')
source=("git+https://github.com/hobbypunk90/WallGen.git")
sha256sums=(SKIP)
license=('GPL')
depends=('python' 'python-wand' 'python-pydbus' 'python-gobject' 'python-yaml' 'imagemagick')
makedepends=('git' 'python-build' 'python-installer' 'python-wheel')
provides=('wallgen')
conflicts=('wallgen')

pkgver() {
  cd "WallGen"
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
  cd "WallGen"
  /usr/bin/python -m build --wheel --no-isolation
}

package() {
  cd "WallGen"
  /usr/bin/python -m installer --destdir="$pkgdir" dist/*.whl

  DESTSYSTEMD="$pkgdir/usr/lib/systemd/user"
  install -Dm644 "systemd/wallgen.service" "$DESTSYSTEMD/wallgen.service"
  install -Dm644 "systemd/wallgen.timer" "$DESTSYSTEMD/wallgen.timer"
  install -Dm644 "systemd/wallgen-dbus.service" "$DESTSYSTEMD/wallgen-dbus.service"
  install -Dm644 "systemd/wallgen-monitor.service" "$DESTSYSTEMD/wallgen-monitor.service"
}