LongQt-model/modellib.pro at master · hundlab/LongQt-model · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
#-------------------------------------------------
#
# Project created by QtCreator 2015-10-19T09:57:24
#
#-------------------------------------------------

QT       = core concurrent

TARGET = LongQt-model
TEMPLATE = lib

QMAKE_MAC_SDK = macosx10.12

CONFIG += c++11 staticlib

include(./src/model.pri)

linux {
    debug {
        QMAKE_CXXFLAGS += -g -O0
        QMAKE_CXXFLAGS_RELEASE -= -O2
        TARGET =$$TARGET"-debug"
    }
    release {
        DEFINES += QT_NO_DEBUG_OUTPUT
        TARGET =$$TARGET"-release"
    }
    profile {
        TARGET =$$TARGET"-profile"
    }

    DESTDIR = ./build
    OBJECTS_DIR = ./build/obj
    MOC_DIR = ./build/obj
    RCC_DIR = ./build/obj
    UI_DIR = ./build/obj
}

# Install files
## header files
INSTALL_DIR = "C:/Progra~2/LongQt-model/"
i =0
for(header, HEADERS) {
    tempName = $$dirname(header)
    endDir = $$INSTALL_DIR"include"$$replace(tempName,$$PWD,"")"/"
    eval(HEADER_INSTALLS_$${i}.path = $$endDir)
#message($$eval(HEADER_INSTALLS_$${i}.path))
    eval(HEADER_INSTALLS_$${i}.files = $$header)
    eval(INSTALLS += HEADER_INSTALLS_$$i)
    i = $$str_size($$INSTALLS)
}

## config files (cmake and qmake)
CMAKE_INSTALLS.path = $$INSTALL_DIR"/share/cmake/LongQt-model/"
CMAKE_INSTALLS.files = $$PWD"/LongQt-modelConfig.cmake"
QMAKE_INSTALLS.path = $$INSTALL_DIR"/share/qmake/LongQt-model/"
QMAKE_INSTALLS.files = ""
INSTALLS += CMAKE_INSTALLS

## shared and static lib
target.path = $$INSTALL_DIR
dlltarget.path = $$INSTALL_DIR
#message($$HEADER_INSTALLS.files)
INSTALLS += target