Implemented archmagi.

Author: Kodiologist

simalq/color.hy

@@ -45,6 +45,7 @@
 
   flash-label 'white
   flash-player-damaged 'red
+  flash-player-hit-by-special-attack 'orange
   flash-player-shot-mundane 'blue
   flash-player-shot-magic 'purple
 

simalq/tile/monster.hy

@@ -705,3 +705,24 @@
   :damage-shot 10
 
   :flavor "A wretched organic structure, fashioned from fiendish flesh. It twists about to aim its toothy maw, from which it belches flame. It's immobile, but dark magics make it almost invulnerable… almost.")
+
+
+(deftile "W " "an archmage" Approacher
+  :iq-ix 163
+  :destruction-points 75
+
+  :damage-melee 2
+  :damage-shot 12
+  :sees-invisible T
+
+  :act (meth []
+    (doc (.format "Disenchant — If it's not adjacent but has line of effect to you, the monster removes the first beneficial status effect that you have from the following list: {}. Otherwise, it behaves per `Approach`."
+      (.join ", " (gfor  e (StatusEffect.disenchantable)  e.name))))
+    (if (and
+        (not (adjacent? @pos G.player.pos))
+        (@try-to-attack-player :dry-run T)
+        (StatusEffect.disenchant-player))
+      (.animate-hit G.player @ "  " :special-color? T)
+      (@approach)))
+
+  :flavor "A professor emeritus whose killer instincts have been honed by decades of publishing and not perishing. His canny eye can detect the least visible academic politics, and his mastery of grant-review panels has bought him the reagents for powerful spells. But even with the best health insurance in the land, he's found that aging has taken its toll: he can no longer cane the young folk with the vigor of his early years.")

simalq/tile/player.hy

@@ -63,20 +63,8 @@
         (* G.rules.artifact-shield-factor amount)))))
 
     (when animate
-      (flash-map
-        @pos
-        colors.flash-player-damaged
-        (+
-          (if (and attacker attacker.pos)
-            (ray @pos
-              (dir-to @pos attacker.pos)
-              (dist @pos attacker.pos))
-            #())
-          (if (.player-has? StatusEffect.Ivln)
-            #()
-            #(@pos)))
-        {@pos (if (> amount 99) "OW" (format amount "2"))}
-        :flash-time-s .2))
+      (@animate-hit attacker :show-ivln? F
+        :label (if (> amount 99) "OW" (format amount "2"))))
 
     (setv hp-was @hp)
     (unless (.player-has? StatusEffect.Ivln)
@@ -90,6 +78,25 @@
   :destroy (meth []
     (raise (GameOverException 'dead)))
 
+  :!animate-hit (meth [attacker label [special-color? F] [show-ivln? T]]
+    "Use `flash-map` to indicate that the player's been hit."
+    (flash-map
+      @pos
+      (if special-color?
+         colors.flash-player-hit-by-special-attack
+         colors.flash-player-damaged)
+      (+
+        (if (and attacker attacker.pos)
+          (ray @pos
+            (dir-to @pos attacker.pos)
+            (dist @pos attacker.pos))
+          #())
+        (if (and (not show-ivln?) (.player-has? StatusEffect.Ivln))
+          #()
+          #(@pos)))
+      {@pos label}
+      :flash-time-s .2))
+
   :flavor "People who've met Tris and Argonn separately are sometimes surprised to learn that they're siblings. They don't look much alike.")
 
 (setv Player (get Tile.types "Princess Triskaidecagonn XIII"))

simalq/tile/unimplemented.hy

@@ -35,7 +35,6 @@
     [154 "wand_of_flame"]
     [158 "ring_of_protection"]
     [159 "amulet_of_poisonous_touch"]
-    [163 "archmage"]
     [164 "cyclops"]
     [165 "dark_prince"]
     [166 "blind_mage"]

tests/test_monster.hy

@@ -3,6 +3,7 @@
 (import
   fractions [Fraction :as f/]
   tests.lib [init assert-at assert-full-name assert-hp wait set-square wk shoot mv-player use-item top]
+  simalq.util [StatusEffect]
   simalq.geometry [Direction Pos ray at burst]
   simalq.game-state [G])
 (setv  T True  F False)
@@ -721,3 +722,30 @@
   (use-item "wand of death" 0 0)
   (assert-at 'NE 'floor)
   (assert (= G.score 150)))
+
+
+(defn test-archmage []
+  (init [:tiles [
+    "archmage"
+    'floor
+    "cloak of invisibility"
+    "cloak of invisibility"]])
+
+  (mv-player 2 0)
+  (assert (= G.player.hp 100))
+  ; The shot of an archmage can disenchant, in which case it does no
+  ; damage.
+  (wk 'E)
+  (assert (not (.player-has? StatusEffect.Ivis)))
+  (assert (= G.player.hp 100))
+  ; Without disenchantment, it does 12 damage.
+  (wait)
+  (assert (= G.player.hp 88))
+  ; The melee attack of an archmage always does 2 damage and never
+  ; disenchants.
+  (set-square [1 0])
+  (wk 'E)
+  (set-square 'E "archmage")
+  (wait)
+  (assert (.player-has? StatusEffect.Ivis))
+  (assert (= G.player.hp 86)))