Implemented weakness traps.

Author: Kodiologist

simalq/game_state.hy

@@ -160,6 +160,9 @@
       ; How much damage the player does with her sword normally.
     player-melee-damage-artifact 3
       ; How much with the relevant artifact.
+    player-melee-damage-weakness-reduction 1
+      ; How much the player's sword damage is reduced by while she's
+      ; weak.
     player-shot-damage-base 1
       ; How much damage the player does with her bow normally.
     player-shot-damage-artifact 2

simalq/tile/scenery.hy

@@ -764,6 +764,17 @@
 
   :flavor "This spiderweb is the size of a really big spiderweb. Until Idok cleans up the dungeon properly, you'll have to tediously carve your way through the webs with your sword. Got any recommendations for a good smitemaster?")
 
+(deftile "<>" "a weakness trap" Trap
+  :color 'magenta
+  :iq-ix 201
+
+  :!duration 12
+  :hook-player-walked-into (meth []
+    (doc f"Makes you weak for {@duration} more turns, reducing the damage of your sword strikes by {G.rules.player-melee-damage-weakness-reduction}.")
+    (.add StatusEffect.Weak @duration))
+
+  :flavor "This complex gadget swiftly adorns Tris with impractical hyperfeminine attire, including a frilly pink dress and stiletto heels. It will take more than that to extinguish Tris's indomitable tomboyish fighting spirit; still, the new duds make fighting a bit awkward. Fortunately, these are all disposable fast-fashion items made solely for the 'Gram #ootd, and will disintegrate in moments.")
+
 (deftile "<>" "an anti-magic trap" Trap
   :color 'blue
   :iq-ix 169

simalq/tile/unimplemented.hy

@@ -55,7 +55,6 @@
     [196 "wyrm"]
     [197 "dragon"]
     [198 "wand_of_remote_action"]
-    [201 "weakness_trap"]
     [202 "rotation_trap"]
     [203 "krogg"]
     [204 "vampire"]

simalq/util.hy

@@ -93,9 +93,13 @@
 
 (defn player-melee-damage []
   "Return how much damage the player does with her sword."
-  (if (get G.player.artifacts "Holy Sword")
-    G.rules.player-melee-damage-artifact
-    G.rules.player-melee-damage-base))
+  (-
+    (if (get G.player.artifacts "Holy Sword")
+      G.rules.player-melee-damage-artifact
+      G.rules.player-melee-damage-base)
+    (if (.player-has? StatusEffect.Weak)
+      G.rules.player-melee-damage-weakness-reduction
+      0)))
 
 (defn player-shot-damage [magic]
   "Return how much damage the player does with her bow."

tests/test_scenery.hy

@@ -4,7 +4,7 @@
 (import
   fractions [Fraction :as f/]
   pytest
-  tests.lib [init init-boot-camp locate assert-at assert-full-name assert-textmap set-square mv-player assert-player-at wk wait shoot use-item use-cport]
+  tests.lib [init init-boot-camp locate assert-at assert-hp assert-full-name assert-textmap set-square mv-player assert-player-at wk wait shoot use-item use-cport]
   simalq.util [GameOverException StatusEffect]
   simalq.geometry [at Pos]
   simalq.game-state [G]
@@ -657,6 +657,41 @@
   (assert (= (get G.player.status-effects StatusEffect.Para) 2)))
 
 
+(defn test-weakness-trap []
+
+  (init
+    [:tiles ["weakness trap" ["orc" :hp 10]]])
+  ; Get weakened.
+  (wk 'E)
+  ; The weakness trap is still there.
+  (assert-at 'here 'player "weakness trap")
+  ; Hit the orc. While Tris is weak, her sword does only 1 damage.
+  (assert-hp 'E 10)
+  (wk 'E)
+  (assert-hp 'E 9)
+  ; Arrows are unaffected; they still do 1 damage.
+  (shoot 'E)
+  (assert-hp 'E 8)
+  ; Likewise, magic arrows still do 3 damage.
+  (setv G.player.magic-arrows 1)
+  (shoot 'E)
+  (assert-hp 'E 5)
+
+  ; In IQ, the result of being weak while having the Holy Sword
+  ; depends on the order in which you get these effects. This is
+  ; undocumented and probably a bug. In SQ, the two effects cancel out
+  ; (making your sword do 2 damage), regardless of order.
+  (for [reverse? [F T]]
+    (setv ts ["Holy Sword" "weakness trap"])
+    (when reverse?
+      (setv ts (reversed ts)))
+    (init [
+      :height 1
+      :tiles [#* ts ["orc" :hp 10]]])
+    (wk 'E 3)
+    (assert-hp 'E 8)))
+
+
 (defn test-anti-magic-trap []
 
   (init [:tiles [