-
Notifications
You must be signed in to change notification settings - Fork 1
/
Copy pathconstruct_f.f90
1066 lines (916 loc) · 33.1 KB
/
construct_f.f90
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
!--------------------------------------------------------------------------
! This subroutine constructs the Fock-matrices F^(ia), In case of HF F is
! independent of ia. In case of DFT it constructs the Konh Sham Hamiltonian.
!
! INPUT (through common variables):
! occnum: the occupation numbers
! vecnat: the natural orbitals
! nbasis: nu of basis functions
! nnatorb: nu of natural orbitals
! nintgr: number of non zero two integrals
! hcore: The 1-e integrals (kinetic+external potential)
! twoin: the 2-e integrals
! mu,nu,lambda,sigma: integer matrices for indirect indexing of
! 2-e integrals
! OUTPUT:
! F: The fock matrix
! Coul: The coulomb matrix
! Exch: The exchange matrix
! created by N. N. Lathiotakis and I.Theophilou
!--------------------------------------------------------------------------
subroutine construct_f(iaa)
!..Global
use global; use functional_m; use matrices; use orbocc; use DFT_par; use grid_params
implicit none
!..Arguments
integer, intent(in) :: iaa
!..Local variables
integer :: i, ia, ib, m, n, ig
integer :: k,l,ic
real(dp) :: DXX(lnbasis, lnbasis,3), DM(lnbasis, lnbasis), DMX(3), ss, dd
real(dp) :: occ_pow(lnnatorb,3), X_int, vv(lnbasis)
real(dp) :: fac_cM(lnnatorb,lnnatorb), fac_eM(lnnatorb,lnnatorb)
if(iaa<0.or.iaa>1) stop 'In construct_f: Invalid iaa'
!..iaa: =0 construct the HcoreNO, CoulNO, ExchNO
! =1 Do not construct HcoreNO, CoulNO, ExchNO
!..Sum the 2-integrals
call sum_intg()
if ( functional /= 'DBF' ) then
if ( l_hybc ) then
if ( .not. allocated( VHF ) ) allocate( VHF(nbasis, nbasis))
do m=1,nbasis
do n=1,m
VHF(m,n)=0._dp
do ib=1,maxorb
VHF(m,n)= VHF(m,n) + 2._dp*Coul(m,n,ib) - Exch(m,n,ib)
enddo
VHF(n,m)= VHF(m,n)
enddo
enddo
endif
do ia=1,nnatorb
do ib=1,ia
fac_cM(ia,ib) = (occnum(ia,1)+occnum(ia,2))*(occnum(ib,1)+occnum(ib,2))
fac_eM(ia,ib) = -occnum(ia,1)*occnum(ib,1)-occnum(ia,2)*occnum(ib,2)
!........The double counting 1/2 factor
fac_cM(ia,ib) = 0.5_dp*fac_cM(ia,ib)
fac_eM(ia,ib) = 0.5_dp*fac_eM(ia,ib)
fac_cM(ib,ia) = fac_cM(ia,ib)
fac_eM(ib,ia) = fac_eM(ia,ib)
enddo
enddo
!..The generalized Fock Matrix
!$OMP PARALLEL DEFAULT(SHARED) &
!$OMP PRIVATE(ia,ib,m,n)
!$OMP DO
do ia=1, maxorb
do m=1,nbasis
do n=1,m
F_xc(m,n,ia)=0._dp; F_ha(m,n,ia)=0._dp; F_haM(m,n,ia)=0._dp; F_x(m,n,ia)=0._dp
F(m,n,ia)=Hcore(m,n)*0.5_dp*fac_h(ia)
do ib=1,maxorb
F(m,n,ia)= F(m,n,ia) + fac_c(ia,ib)*Coul(m,n,ib) + fac_e(ia,ib)*Exch(m,n,ib)
F_xc(m,n,ia)= F_xc(m,n,ia) + fac_e(ia,ib)*Exch(m,n,ib)
F_x(m,n,ia)= F_x(m,n,ia) + fac_eM(ia,ib)*Exch(m,n,ib)
F_ha(m,n,ia)= F_ha(m,n,ia) + fac_c(ia,ib)*Coul(m,n,ib)
F_haM(m,n,ia)= F_haM(m,n,ia) + fac_cM(ia,ib)*Coul(m,n,ib)
enddo
F(n,m,ia)=F(m,n,ia)
F_xc(n,m,ia)=F_xc(m,n,ia)
F_x(n,m,ia)=F_x(m,n,ia)
F_ha(n,m,ia)=F_ha(m,n,ia)
F_haM(n,m,ia)=F_haM(m,n,ia)
enddo
enddo
enddo
!$OMP END DO
!$OMP END PARALLEL
else
!..The generalized Fock Matrix
!$OMP PARALLEL DEFAULT(SHARED) &
!$OMP PRIVATE(ia,ib,m,n)
!$OMP DO
do ia=1, maxorb
do m=1,nbasis
do n=1,m
F(m,n,ia)=Hcore(m,n)*0.5_dp*fac_h(ia)
do ib=1,nnatorb
F(m,n,ia)= F(m,n,ia) + fac_c(ia,ib)*Coul(m,n,ib) ! Exc from DFT
enddo
F(n,m,ia)=F(m,n,ia)
enddo
enddo
enddo
!$OMP END DO
!$OMP END PARALLEL
endif !( functional /= 'DBF' )
if(iaa==0) then
!.....Calculate CoulNO, ExchNO, HcoreNO
!$OMP PARALLEL DEFAULT(SHARED) &
!$OMP PRIVATE(ia,ib,m,n,dd)
!$OMP DO
do ia=1,maxorb
HcoreNO(ia,ia) = 0.0_dp
do m =1, nbasis
do n = 1, nbasis
HcoreNO(ia,ia) = HcoreNO(ia,ia) + vecnat(m,ia)*hcore(m,n)*vecnat(n,ia)
enddo
enddo
do ib = 1, ia
CoulNO(ia,ib)=0.0_dp; ExchNO(ia,ib)=0.0_dp
do m =1, nbasis
do n = 1, nbasis
dd=vecnat(m,ia)*vecnat(n,ia)
CoulNO(ia,ib) = CoulNO(ia,ib) + Coul(m,n,ib) * dd
ExchNO(ia,ib) = ExchNO(ia,ib) + Exch(m,n,ib) * dd
enddo ! m
enddo ! n
CoulNO(ib,ia) = CoulNO(ia,ib); ExchNO(ib,ia) = ExchNO(ia,ib)
enddo ! ib
enddo !ia
!$OMP END DO
!$OMP END PARALLEL
endif !(iaa==0)
if (l_non_JK) then
call psi4_int(vecnat(:,1),vecnat(:,2),vecnat(:,2),vecnat(:,3),X_int)
q_non_JK=X_int ! \int\int dr dr\prime \frac{phi_1(r) phi_2(r) phi_2(r\prime) phi_3(r\prime)}{|r-r\prime|}
if ( .not. allocated(XI1) ) allocate ( XI1(lnnatorb), XI2(lnnatorb), XI3(lnnatorb) )
do i=1,nbasis
vv=0._dp; vv(i)=1._dp
call psi4_int(vv,vecnat(:,2),vecnat(:,2),vecnat(:,3),X_int)
XI1(i) = f_non_JK*X_int
call psi4_int(vv,vecnat(:,1),vecnat(:,2),vecnat(:,3),X_int)
XI2(i) = f_non_JK*X_int
call psi4_int(vv,vecnat(:,3),vecnat(:,1),vecnat(:,2),X_int)
XI2(i) = f_non_JK*X_int
call psi4_int(vv,vecnat(:,2),vecnat(:,2),vecnat(:,1),X_int)
XI3(i) = f_non_JK*X_int
enddo
endif !(l_non_JK)
if(Functional == 'SLR') then
call orbs_on_grid(nnatorb)
do ia=1,nnatorb
occ_pow(ia,1) = occnum(ia,1)**alpha
occ_pow(ia,2) = occnum(ia,2)**alpha
enddo
if ( .not.allocated(chdens_gr) ) allocate(chdens_gr(ngrid,3))
!$omp parallel default(shared) &
!$omp private(ig,ia)
!$omp do
do ig=1,ngrid
chdens_gr(ig,1) = 0.0_dp; chdens_gr(ig,2) = 0.0_dp
do ia=1,maxorb
chdens_gr(ig,1) = chdens_gr(ig,1) + occ_pow(ia,1)*vec_nat_grid(ig,ia)**2
chdens_gr(ig,2) = chdens_gr(ig,2) + occ_pow(ia,2)*vec_nat_grid(ig,ia)**2
enddo
chdens_gr(ig,3)=chdens_gr(ig,1)+chdens_gr(ig,2)
enddo
!$omp end do
!$omp end parallel
call DFT_functional_libxc(occnum,orbgridsq)
! call DFT_functional_mine
if(.not.allocated(Vxc_mn_DFT)) allocate (Vxc_mn_DFT(nbasis,nbasis))
!$OMP PARALLEL DEFAULT(SHARED) &
!$OMP PRIVATE(m,n,ig)
!$OMP DO
do m=1,nbasis
do n=1,m
Vxc_mn_DFT(m,n)=0.0_dp
do ig=1,ngrid
Vxc_mn_DFT(m,n) = Vxc_mn_DFT(m,n) + w_grid(ig)*bas_f_grid(ig,m)*Vlxc(1,ig)*bas_f_grid(ig,n)
enddo
Vxc_mn_DFT(n,m)=Vxc_mn_DFT(m,n)
enddo
enddo
!$OMP END DO
!$OMP END PARALLEL
do ia=1,maxorb
do m=1,nbasis
do n=1,m
F(m,n,ia) = F(m,n,ia)+ 0.5_dp*fac_h(ia)*Vxc_mn_DFT(m,n)
enddo
enddo
enddo
endif !(Functional == 'SLR')
if((Functional == 'DFT') .or. (Functional == 'HDR') .or. (Functional == 'DBF') ) then
call orbs_on_grid(maxorb)
call DFT_functional_libxc(occnum,orbgridsq)
if(.not.allocated(Vxc_mn_DFT)) allocate (Vxc_mn_DFT(nbasis,nbasis))
if(.not.allocated(Vc_mn_DFT)) allocate (Vc_mn_DFT(nbasis,nbasis))
!$OMP PARALLEL DEFAULT(SHARED) &
!$OMP PRIVATE(m,n,ig)
!$OMP DO
do m=1,nbasis
do n=1,m
Vxc_mn_DFT(m,n)=0.0_dp; Vc_mn_DFT(m,n)=0.0_dp
do ig=1,ngrid
Vxc_mn_DFT(m,n) = Vxc_mn_DFT(m,n) + w_grid(ig)*bas_f_grid(ig,m)*Vlxc(1,ig)*bas_f_grid(ig,n)
Vc_mn_DFT(m,n) = Vc_mn_DFT(m,n) + w_grid(ig)*bas_f_grid(ig,m)*Vlc(1,ig)*bas_f_grid(ig,n)
enddo
Vxc_mn_DFT(n,m)=Vxc_mn_DFT(m,n); Vc_mn_DFT(n,m)=Vc_mn_DFT(m,n)
enddo
enddo
!$OMP END DO
!$OMP END PARALLEL
if(gga_x .or. gga_c) then
do m=1,nbasis
do n=1,nbasis
DM(m,n)=0.0_dp
do ia=1,nnatorb
DM(m,n)=DM(m,n)+occnum(ia,3)*vecnat(m,ia)*vecnat(n,ia)
enddo
enddo
enddo
do ig=1,ngrid
do m=1,nbasis
do n=1,nbasis
do ic=1,3
DXX(m,n,ic)=grad_bas_f_grid(ig,m,ic)*bas_f_grid(ig,n)
enddo
enddo
enddo
do ic=1,3
DMX(ic) = 0.d0
do m=1,nbasis
do n=1,nbasis
DMX(ic)=DMX(ic) + DM(m,n)*DXX(m,n,ic)
enddo
enddo
DMX(ic) = 4.0_dp*DMX(ic)
enddo
do k=1,nbasis
do l=1,k
ss=0.0_dp
do ic=1,3
ss=ss+DMX(ic)*(DXX(k,l,ic)+DXX(l,k,ic))
enddo
if(gga_x) Vxc_mn_DFT(k,l) = Vxc_mn_DFT(k,l)+w_grid(ig)*Vlxc_sig(1,ig)*ss
if(gga_c) Vc_mn_DFT(k,l) = Vc_mn_DFT(k,l)+w_grid(ig)*Vlc_sig(1,ig)*ss
enddo
enddo
enddo
do k=1,nbasis
do l=1,k
Vxc_mn_DFT(l,k) = Vxc_mn_DFT(k,l); Vc_mn_DFT(l,k) = Vc_mn_DFT(k,l)
enddo
enddo
endif !(gga_x .or. gga_c)
open(unit=121,file='Vxc', status='unknown')
write(121,'(2i4,f20.10)') ((l,k,Vxc_mn_DFT(k,l)+Vc_mn_DFT(k,l),k=1,l),l=1,nbasis)
close(121)
if (Functional/='HDR') then
do ia=1,maxorb
do m=1,nbasis
do n=1,m
F(m,n,ia) = F(m,n,ia)+ 0.5_dp*fac_h(ia)*(Vxc_mn_DFT(m,n)+Vc_mn_DFT(m,n))
F(n,m,ia) = F(m,n,ia)
enddo
enddo
enddo
! if (.not. do_oep) then
! if(Fexist) then
! F=xmix_dft*F+(1.d0-xmix_dft)*F_old !Mixing. For OEP its already done
! else
! if ( .not. allocated(F_old) ) allocate ( F_old(lnbasis,lnbasis,lnnatorb) )
! Fexist=.true.
! endif
! F_old=F
! endif
else
do ia=1,maxorb
do m=1,nbasis
do n=1,m
F(m,n,ia) = F(m,n,ia)+ 0.5_dp*fac_h(ia)*xmix_DF*(Vxc_mn_DFT(m,n) + Vc_mn_DFT(m,n))
enddo
enddo
enddo
endif
endif !((Functional == 'DFT' .or. (Functional == 'HDR'))
end subroutine construct_f
!--------------------------------------------------------------------------
subroutine sum_intg()
!--------------------------------------------------------------------------
! This subroutine does the dirty and time consuming job of suming over
! the 2-e integrals for the calculation of Matrix elements of coulomb
! and exchange kind. Most of the computer time is 'wasted' in this routine.
! Although the best is done to make it optimal there might still be
! space of improvement. BUT DO WITH CARE AND ONLY IF YOU KNOW WHAT YOU
! ARE DOING.
!--------------------------------------------------------------------------
!..Global
use global; use integrals; use matrices
use orbocc, ONLY: vecnat
use functional_m, ONLY: maxorb
implicit none
!..Local variables
integer :: m, n, l, s
integer(8) :: ind_p
integer :: ia, ib, nrec, nchunk, nrec_last, ichunk, irec
logical :: inv_pairs, read_int
real(dp) :: two_int, wmn, wls
real(dp), allocatable :: DM(:,:,:)
if(.not.allocated(DM) ) allocate( DM(lnbasis,lnbasis,lnnatorb) )
do ia=1,maxorb
do m = 1,nbasis
do n =1, m
DM(m,n,ia)=vecnat(m,ia)*vecnat(n,ia)
DM(n,m,ia)=DM(m,n,ia)
enddo
enddo
enddo
nrec=50000000 ! x20 = 1GB
nchunk=nintgr/nrec
nchunk=nchunk+1
nrec_last=mod(nintgr,nrec)
read_int=.true.
if(nchunk==1) then
nrec=nrec_last
read_int=.false.
endif
if(.not.allocated(twoin)) then
allocate( indpacked(nrec), mu(nrec), nu(nrec), lambda(nrec), sigma(nrec), twoin(nrec) )
read_int=.true.
endif
Coul=0.0_dp; Exch=0.0_dp
rewind(42)
!..Do loop over the nonzero and unique orbitals
do ichunk=1,nchunk
if(ichunk==nchunk) nrec=nrec_last
if ( read_int ) then
read(42,err=140) (indpacked(irec), twoin(irec), irec=1,nrec)
endif
!$OMP PARALLEL DEFAULT(SHARED) &
!$OMP PRIVATE(irec,ind_p,m,n,l,s)
!$OMP DO
do irec = 1, nrec
ind_p=indpacked(irec)
call unpack4(m,n,l,s,ind_p)
mu(irec)=m
nu(irec)=n
lambda(irec)=l
sigma(irec)=s
enddo
!$OMP END DO
!$OMP END PARALLEL
!$OMP PARALLEL DEFAULT(SHARED) &
!$OMP PRIVATE(ib,irec,ind_p,m,n,l,s,two_int,wmn,wls,inv_pairs)
!$OMP DO
do ib=1,maxorb
do irec = 1, nrec
m=mu(irec)
n=nu(irec)
l=lambda(irec)
s=sigma(irec)
two_int = twoin(irec)
!.....Create the weights due to symmetry of (mn|ls)
if(m==n) then
wmn = 1.0_dp
else
wmn = 2.0_dp
endif
if(l==s) then
wls = 1.0_dp
else
wls = 2.0_dp
endif
!.....The coulomb and exchange should be added to different F elements:
!.....Coulomb
inv_pairs = (l/=m.or.n/=s)
Coul(m,n,ib) = Coul(m,n,ib) + DM(l,s,ib) * wls * two_int
if(inv_pairs) Coul(l,s,ib) = Coul(l,s,ib) + DM(m,n,ib) * wmn * two_int
!.....Exchange
if(m>=l) Exch(m,l,ib) = Exch(m,l,ib) + two_int * DM(n,s,ib)
if(inv_pairs.and.l>=m) Exch(l,m,ib) = Exch(l,m,ib) + two_int * DM(n,s,ib)
if(m/=n) then
if(n>=l) Exch(n,l,ib) = Exch(n,l,ib) + two_int * DM(m,s,ib)
if(inv_pairs.and.l>=n) Exch(l,n,ib) = Exch(l,n,ib) + two_int * DM(m,s,ib)
if(l/=s) then
if(n>=s) Exch(n,s,ib) = Exch(n,s,ib) + two_int * DM(m,l,ib)
if(inv_pairs.and.s>=n) Exch(s,n,ib)=Exch(s,n,ib) + two_int * DM(m,l,ib)
endif !(l/=s)
endif !(m/=n)
if(l/=s) then
if(m>=s) Exch(m,s,ib) = Exch(m,s,ib) + two_int * DM(n,l,ib)
if(inv_pairs.and.s>=m) Exch(s,m,ib) = Exch(s,m,ib) + two_int * DM(n,l,ib)
endif !l/=s
enddo ! irec
enddo !ib
!$OMP END DO
!$OMP END PARALLEL
enddo ! ichunk
!$OMP PARALLEL DEFAULT(SHARED) &
!$OMP PRIVATE(ia,m,n)
!$OMP DO
do ia=1,maxorb
do m=1,nbasis
do n=1,m
Coul(n,m,ia)=Coul(m,n,ia)
Exch(n,m,ia)=Exch(m,n,ia)
enddo
enddo
enddo
!$OMP END DO
!$OMP END PARALLEL
deallocate( DM )
return
140 stop 'construct_f:sum_intg: error reading 2-e intergral file'
end subroutine sum_intg
!=====================================================================================
subroutine DFT_functional_libxc(occ,orbgridsq)
use global; use grid_params, ONLY: ngrid, chdens_gr
use DFT_par; use functional_m, ONLY:Functional, cl_shell
! use xc_f90_types_m; use xc_f90_lib_m
implicit none
!..Arguments
real(dp) :: occ(lnnatorb,3), orbgridsq(ngrid,lnnatorb)
!..Local
real(dp), allocatable :: rho(:,:), grad_n(:,:)
integer :: ig, ia, i1
if(.not.allocated(chdens_gr)) allocate (chdens_gr(ngrid,3))
if ( cl_shell ) then
i1=1
else
i1=2
endif
allocate ( rho(i1,ngrid), grad_n(i1,ngrid) )
rho=0.0_dp
!$omp parallel default(shared) &
!$omp private(ig,ia)
!$omp do
do ig=1,ngrid
do ia=1,nnatorb
if (cl_shell) then
rho(1,ig) = rho(1,ig) + occ(ia,3)*orbgridsq(ig,ia)
else
rho(1,ig) = rho(1,ig) + occ(ia,1)*orbgridsq(ig,ia)
rho(2,ig) = rho(2,ig) + occ(ia,2)*orbgridsq(ig,ia)
endif
enddo
enddo
!$omp end do
!$omp end parallel
if ( cl_shell ) then
chdens_gr(:,3)=rho(1,:)
chdens_gr(:,1)=0.5_dp*chdens_gr(:,3)
chdens_gr(:,2)=chdens_gr(:,1)
else
chdens_gr(:,1)=rho(1,:)
chdens_gr(:,2)=rho(2,:)
chdens_gr(:,3)=chdens_gr(:,1)+chdens_gr(:,2)
endif
if (.not. allocated(Exc_DFT)) allocate(Exc_DFT(ngrid))
if (.not. allocated(Ec_DFT)) allocate(Ec_DFT(ngrid))
if (.not. allocated(Vlxc)) allocate ( Vlxc(i1,ngrid) )
if (.not. allocated(Vlc)) allocate ( Vlc(i1,ngrid) )
if (.not. allocated(Vlxc_sig)) allocate ( Vlxc_sig(i1,ngrid) )
if (.not. allocated(Vlc_sig)) allocate ( Vlc_sig(i1,ngrid) )
! allocate (Fxc_DFT(ngrid), Fc_DFT(ngrid))
!..Exchange Correlation Functional
select case (xc_f90_info_family(xc_info))
case(XC_FAMILY_LDA)
call xc_f90_lda_exc_vxc(xc_func, ngrid, rho(1,1), Exc_DFT(1), Vlxc(1,1))
case(XC_FAMILY_GGA, XC_FAMILY_HYB_GGA)
call density_gradient( i1, grad_n )
call xc_f90_gga_exc_vxc(xc_func, ngrid, rho(1,1), grad_n(1,1), Exc_DFT(1), Vlxc(1,1), Vlxc_sig(1,1) )
gga_x=.true.
case default
Exc_DFT=0.0_dp; Vlxc=0.0_dp; Vlxc_sig=0.0_dp
end select
!..Correlation Functional for seperate additional correlation functional
if (id_func_c/=0 .and. Functional /= 'SLR') then
select case (xc_f90_info_family(c_info))
case(XC_FAMILY_LDA)
call xc_f90_lda_exc_vxc(c_func, ngrid, rho(1,1), Ec_DFT(1), Vlc(1,1))
case(XC_FAMILY_GGA, XC_FAMILY_HYB_GGA)
if (.not. gga_x) call density_gradient ( i1, grad_n )
call xc_f90_gga_exc_vxc(c_func, ngrid, rho(1,1), grad_n(1,1), Ec_DFT(1), Vlc(1,1), Vlc_sig(1,1) )
gga_c=.true.
case default
Ec_DFT=0.0_dp; Vlc=0.0_dp; Vlc_sig=0.0_dp
end select
else
Ec_DFT=0.0_dp; Vlc=0.0_dp; Vlc_sig=0.0_dp
endif
end subroutine DFT_functional_libxc
!==========================================================================================
!-----------------------------------------------------------------------------------
subroutine density_gradient (i1, top_orb, grad_n)
use global; use orbocc; use grid_params; implicit none
!..Arguments
integer, intent(in) :: i1,top_orb
real(dp),intent(out) :: grad_n(2*i1-1,ngrid)
!..Local
integer :: ibs, ig, k, m, ia, ispin, ic
real(dp) :: gx, gy, gz, DM(lnbasis, lnbasis, 2), g_ig(3,3)
!..Gradient of Basis Functions on grid
if (.not.allocated(grad_bas_f_grid)) then
allocate(grad_bas_f_grid(ngrid,nbasis,3))
endif
if (.not. lgradset) then
do ibs=1,nbasis
do ig=1,ngrid
call gradient_f_bas(ibs, x_grid(ig), y_grid(ig), z_grid(ig), gx, gy, gz)
grad_bas_f_grid(ig,ibs,1)=gx
grad_bas_f_grid(ig,ibs,2)=gy
grad_bas_f_grid(ig,ibs,3)=gz
enddo
enddo
lgradset=.true.
endif
!$OMP PARALLEL DEFAULT(SHARED) &
!$OMP PRIVATE(k,m,ispin,ia)
!$OMP DO
do k=1,nbasis
do m=1,nbasis
do ispin=1,2
DM(k,m,ispin) = 0.0_dp
do ia=1,top_orb
if( occnum(ia,ispin) > small) then
DM(k,m,ispin) = DM(k,m,ispin) + occnum(ia,ispin)*vecnat(k,ia)*vecnat(m,ia)
endif
enddo
enddo
enddo
enddo
!$OMP END DO
!$OMP END PARALLEL
!$OMP PARALLEL DEFAULT(SHARED) &
!$OMP PRIVATE(ig,ic,ispin,g_ig,k,m)
!$OMP DO
do ig=1,ngrid
do ic=1,3
do ispin=1,2
g_ig(ic,ispin) = 0.0_dp
do k=1,nbasis
do m=1,nbasis
g_ig(ic,ispin) = g_ig(ic,ispin) + DM(k,m,ispin)*grad_bas_f_grid(ig,k,ic)*bas_f_grid(ig,m)
enddo
enddo
g_ig(ic,ispin) = 2.0_dp*g_ig(ic,ispin)
enddo
enddo
!Construct the 'contracted gradients' required for libxc input
if (i1==1) then
g_ig(:,3) = g_ig(:,1) + g_ig(:,2)
grad_n(1,ig) = dot_product(g_ig(:,3),g_ig(:,3))
else
grad_n(1,ig) = dot_product(g_ig(:,1),g_ig(:,1))
grad_n(2,ig) = dot_product(g_ig(:,1),g_ig(:,2))
grad_n(3,ig) = dot_product(g_ig(:,2),g_ig(:,2))
endif
enddo
!$OMP END DO
!$OMP END PARALLEL
end subroutine density_gradient
!--------------------------------------------------------------------------------------------------------------
subroutine density_gradient_OLD (i1, grad_n )
use global; use orbocc; use grid_params; use functional_m, ONLY:cl_shell; implicit none
!..Arguments
integer, intent(in) :: i1
real(dp),intent(out) :: grad_n(i1,ngrid)
!..Local
integer :: ibs, ig, k, m, ia, ispin, ic
real(dp) :: gx, gy, gz, DM(lnbasis, lnbasis, 2), g_ig(3,2)
!..Gradient of Basis Functions on grid
if (.not.allocated(grad_bas_f_grid)) then
allocate(grad_bas_f_grid(ngrid,nbasis,3))
endif
if (.not. lgradset) then
do ibs=1,nbasis
do ig=1,ngrid
call gradient_f_bas(ibs, x_grid(ig), y_grid(ig), z_grid(ig), gx, gy, gz)
grad_bas_f_grid(ig,ibs,1)=gx
grad_bas_f_grid(ig,ibs,2)=gy
grad_bas_f_grid(ig,ibs,3)=gz
enddo
enddo
lgradset=.true.
endif
!$OMP PARALLEL DEFAULT(SHARED) &
!$OMP PRIVATE(k,m,ispin,ia)
!$OMP DO
do k=1,nbasis
do m=1,nbasis
do ispin=1,2
DM(k,m,ispin) = 0.0_dp
do ia=1,nnatorb
if( occnum(ia,ispin) > small) then
DM(k,m,ispin) = DM(k,m,ispin) + occnum(ia,ispin)*vecnat(k,ia)*vecnat(m,ia)
endif
enddo
enddo
enddo
enddo
!$OMP END DO
!$OMP END PARALLEL
!$OMP PARALLEL DEFAULT(SHARED) &
!$OMP PRIVATE(ig,ic,ispin,g_ig,k,m)
!$OMP DO
do ig=1,ngrid
do ic=1,3
do ispin=1,2
g_ig(ic,ispin) = 0.0_dp
do k=1,nbasis
do m=1,nbasis
g_ig(ic,ispin) = g_ig(ic,ispin) + DM(k,m,ispin)*grad_bas_f_grid(ig,k,ic)*bas_f_grid(ig,m)
enddo
enddo
g_ig(ic,ispin) = 4.0_dp*g_ig(ic,ispin)
enddo
enddo
if (cl_shell) then
grad_n(1,ig) = g_ig(1,1)*g_ig(1,1)+g_ig(2,1)*g_ig(2,1)+g_ig(3,1)*g_ig(3,1)
else
! To be checked
stop 'construct f: check first'
! grad_n(1,ig) = g_ig(1,1)*g_ig(1,2)+g_ig(2,1)*g_ig(2,2)+g_ig(3,1)*g_ig(3,2)
! grad_n(2,ig) = g_ig(1,2)*g_ig(1,2)+g_ig(2,2)*g_ig(2,2)+g_ig(3,2)*g_ig(3,2)
endif
enddo
!$OMP END DO
!$OMP END PARALLEL
end subroutine density_gradient_OLD
!==========================================================================================
subroutine density_gradient_select(Npoints,Xpoint,Ypoint,Zpoint,Gpoint,G_c)
use global; use orbocc; use grid_params; implicit none
!..Arguments
integer :: Npoints
real(dp) :: Xpoint(Npoints), Ypoint(Npoints), Zpoint(Npoints), Gpoint(Npoints), G_c(Npoints,3)
!..Local
integer :: ibs, ig, k, m, ia, ispin, ic
real(dp) :: gx, gy, gz, DM(lnbasis, lnbasis, 2), g_ig(3,2)
real(dp) :: gbf(nbasis,3), bf(nbasis)
real(dp), external :: f_bas
!..Gradient of Basis Functions
!$OMP PARALLEL DEFAULT(SHARED) &
!$OMP PRIVATE(k,m,ispin,ia)
!$OMP DO
do k=1,nbasis
do m=1,nbasis
do ispin=1,2
DM(k,m,ispin) = 0.0_dp
do ia=1,nnatorb
if( occnum(ia,ispin) > small) then
DM(k,m,ispin) = DM(k,m,ispin) + occnum(ia,ispin)*vecnat(k,ia)*vecnat(m,ia)
endif
enddo
enddo
enddo
enddo
!$OMP END DO
!$OMP END PARALLEL
!$OMP PARALLEL DEFAULT(SHARED) &
!$OMP PRIVATE(ig,ic,ibs,bf,gbf,gx,gy,gz,ispin,g_ig,k,m)
!$OMP DO
do ig=1,Npoints
do ibs=1,nbasis
call gradient_f_bas(ibs, Xpoint(ig), Ypoint(ig), Zpoint(ig), gx, gy, gz)
gbf(ibs,1)=gx
gbf(ibs,2)=gy
gbf(ibs,3)=gz
bf(ibs) = f_bas(ibs, Xpoint(ig), Ypoint(ig), Zpoint(ig))
enddo
grad_bas_f_grid(ig,:,:) = gbf
do ic=1,3
do ispin=1,2
g_ig(ic,ispin) = 0.0_dp
do k=1,nbasis
do m=1,nbasis
g_ig(ic,ispin) = g_ig(ic,ispin) + DM(k,m,ispin)*gbf(k,ic)*bf(m)
enddo
enddo
g_ig(ic,ispin) = 2.0_dp*g_ig(ic,ispin)
enddo
enddo
!....The factors of 2.d0 and 4.0 in the following is because we want total gradient and there is spin degeneracy
G_c(ig,1)=2.0_dp*g_ig(1,1); G_c(ig,2)=2.0_dp*g_ig(2,1); G_c(ig,3)=2.0_dp*g_ig(3,1)
Gpoint(ig) = 4.0_dp*(g_ig(1,1)*g_ig(1,1)+g_ig(2,1)*g_ig(2,1)+g_ig(3,1)*g_ig(3,1))
! grad_n(2,ig) = g_ig(1,1)*g_ig(1,2)+g_ig(2,1)*g_ig(2,2)+g_ig(3,1)*g_ig(3,2)
! grad_n(3,ig) = g_ig(1,2)*g_ig(1,2)+g_ig(2,2)*g_ig(2,2)+g_ig(3,2)*g_ig(3,2)
enddo
!$OMP END DO
!$OMP END PARALLEL
end subroutine density_gradient_select
!=====================================================================================
subroutine DFT_functional_mine(occ,orbgridsq)
!..Made for testing only
use global; use grid_params, ONLY:ngrid; use DFT_par
implicit none
!..Arguments
real(dp) :: occ(lnnatorb), orbgridsq(ngrid,lnnatorb)
integer :: ig, ia
real(dp) :: rho, rho1, rho2, vx_1, vx_2, vc_1, vc_2, ex, ec, zero2
zero2=zero*zero
if (.not. allocated(Exc_DFT)) allocate(Exc_DFT(ngrid))
if (.not. allocated(Ec_DFT)) allocate(Ec_DFT(ngrid))
if (.not. allocated(Vlxc)) allocate(Vlxc(1,ngrid))
if (.not. allocated(Vlc)) allocate(Vlc(1,ngrid))
do ig=1,ngrid
rho = 0.0_dp
do ia=1,nnatorb
rho = rho + occ(ia)*orbgridsq(ig,ia)
enddo
rho1=rho/2.0_dp
rho2=rho1
rho1=max(zero2,rho1)
rho2=max(zero2,rho2)
call lsd_slater(rho1,rho2,vx_1,vx_2, ex)
vc_1=0.0_dp; vc_2=0.0_dp; ec=0.0_dp
call lsd_VWN_cor(rho1,rho2,vc_1,vc_2,ec)
Exc_DFT(ig) = ex/rho; Ec_DFT(ig)=ec/rho
Vlxc(1,ig) = vx_1; Vlc(1,ig)=vc_1 ! For open shell Vx_DFT, Vc_DFT need a second index
enddo
end subroutine DFT_functional_mine
subroutine lsd_slater(rho1, rho2, vx_1, vx_2, ex)
!..Slater Exchange for testing
use global; implicit none
real(dp) :: rho1, rho2, vx_1, vx_2, ex
real(dp) :: rhoth1, rhoth2, fpot, fexc, third, alp
alp=2.0_dp/3.0_dp
third=1.0_dp/3.0_dp
rhoth1=rho1**third; rhoth2=rho2**third
fpot=(3.0_dp/4.0_dp/pi)**third
fexc=-(9.0_dp/4.0_dp)*alp*fpot
fpot=-3.0_dp*alp*fpot
ex=fexc*(rhoth1**4.0_dp + rhoth2**4.0_dp)
vx_1 = fpot*rhoth1
vx_2 = fpot*rhoth2
end subroutine lsd_slater
subroutine lsd_VWN_cor(rho1,rho2,vc_1,vc_2,ec)
!..LDA VWN correlation for testing
!..Global
use global; implicit none
!..Arguments
real(dp), intent(IN) :: rho1, rho2
real(dp), intent(OUT) :: vc_1, vc_2, ec
!..Parameters
real(dp), parameter :: facr = 0.78762331789974325053_dp, &
fach = 1.70992093416136561756_dp,&
facg = 1.125d0, facdg=1.5d0,&
VWNAP= 0.0621814_dp/2.0_dp, VWNBP= 3.7274400_dp, &
VWNCP=12.9352000D+00, VWNX0P=-0.1049800D+00, &
VWNAF= VWNAP/2.0_dp, VWNBF= 7.0604200_dp, &
VWNCF=18.0578000_dp, VWNX0F=-0.3250000_dp, &
VWNAA=-0.03377372_dp/2.0_dp, VWNBA= 1.1310700_dp, &
VWNCA=13.0045000_dp, VWNX0A=-0.0047584_dp
!..Local
real(dp) :: rhoa, rhob, rhot, rho16, qp, qf, qa, xx0p, xx0f, xx0a
real(dp) :: coef1p, coef1f, coef1a, coef2p, coef2f, coef2a
real(dp) :: coef3p, coef3f, coef3a, x, xxp, xxf, xxa, t1p, t1f, t1a
real(dp) :: t2p, t2f, t2a, t3p, t3f, t3a, epscp, epscf, epsca
real(dp) :: xbp, xbf, xba
real(dp) :: xbq2p,xbq2f,xbq2a,brackp,brackf,bracka,curlyp,curlyf,curlya,depscp,depscf,depsca
real(dp) :: hx,dhx, zeta, zeta2, zeta3, zeta4, gzeta, dgzeta, dpot1, dpot2, duma, dumb, pot
rhoa =rho1
rhob =rho2
rhot =rhoa+rhob
rho16 =rhot**(1._dp/6._dp)
qp = sqrt(4._dp*vwncp-vwnbp*vwnbp)
qf = sqrt(4._dp*vwncf-vwnbf*vwnbf)
qa = sqrt(4._dp*vwnca-vwnba*vwnba)
xx0p = VWNX0P*VWNX0P+VWNX0P*VWNBP+VWNCP
xx0f = VWNX0F*VWNX0F+VWNX0F*VWNBF+VWNCF
xx0a = VWNX0A*VWNX0A+VWNX0A*VWNBA+VWNCA
COEF1P= VWNAP
COEF1F= VWNAF
COEF1A= VWNAA
COEF2P=-VWNAP*VWNBP*VWNX0P/XX0P
COEF2F=-VWNAF*VWNBF*VWNX0F/XX0F
COEF2A=-VWNAA*VWNBA*VWNX0A/XX0A
COEF3P= VWNAP*(2._dp*VWNBP/QP)*((VWNCP-VWNX0P*VWNX0P)/XX0P)
COEF3F= VWNAF*(2._dp*VWNBF/QF)*((VWNCF-VWNX0F*VWNX0F)/XX0F)
COEF3A= VWNAA*(2._dp*VWNBA/QA)*((VWNCA-VWNX0A*VWNX0A)/XX0A)
X =FACR/RHO16
XXP =X*X+X*VWNBP+VWNCP
XXF =X*X+X*VWNBF+VWNCF
XXA =X*X+X*VWNBA+VWNCA
T1P =LOG(X*X/XXP)
T1F =LOG(X*X/XXF)
T1A =LOG(X*X/XXA)
T2P =LOG((X-VWNX0P)*(X-VWNX0P)/XXP)
T2F =LOG((X-VWNX0F)*(X-VWNX0F)/XXF)
T2A =LOG((X-VWNX0A)*(X-VWNX0A)/XXA)
T3P =ATAN(QP/(2._dp*X+VWNBP))
T3F =ATAN(QF/(2._dp*X+VWNBF))
T3A =ATAN(QA/(2._dp*X+VWNBA))
EPSCP =COEF1P*T1P+COEF2P*T2P+COEF3P*T3P
EPSCF =COEF1F*T1F+COEF2F*T2F+COEF3F*T3F
EPSCA =COEF1A*T1A+COEF2A*T2A+COEF3A*T3A
XBP = 2._dp*X+VWNBP
XBF = 2._dp*X+VWNBF
XBA = 2._dp*X+VWNBA
XBQ2P = XBP*XBP + QP*QP
XBQ2F = XBF*XBF + QF*QF
XBQ2A = XBA*XBA + QA*QA
BRACKP = 2._dp/(X-VWNX0P) -XBP/XXP -4._dp*(2._dp*VWNX0P+VWNBP)/XBQ2P
BRACKF = 2._dp/(X-VWNX0F) -XBF/XXF -4._dp*(2._dp*VWNX0F+VWNBF)/XBQ2F
BRACKA = 2._dp/(X-VWNX0A) -XBA/XXA -4._dp*(2._dp*VWNX0A+VWNBA)/XBQ2A
CURLYP = 2._dp/X - XBP/XXP - 4._dp*VWNBP/XBQ2P
CURLYF = 2._dp/X - XBF/XXF - 4._dp*VWNBF/XBQ2F
CURLYA = 2._dp/X - XBA/XXA - 4._dp*VWNBA/XBQ2A
DEPSCP = VWNAP*(CURLYP - VWNBP*VWNX0P*BRACKP/XX0P)
DEPSCF = VWNAF*(CURLYF - VWNBF*VWNX0F*BRACKF/XX0F)
DEPSCA = VWNAA*(CURLYA - VWNBA*VWNX0A*BRACKA/XX0A)
HX = FACH*(EPSCF-EPSCP)/EPSCA - 1._dp
DHX = FACH*(DEPSCF-DEPSCP-(EPSCF-EPSCP)*DEPSCA/EPSCA)/EPSCA
ZETA = (RHOA-RHOB)/RHOT
ZETA2 = ZETA *ZETA
ZETA3 = ZETA2*ZETA
ZETA4 = ZETA2*ZETA2
GZETA = ((1._dp+ZETA)**(4._dp/3._dp)+(1._dp-ZETA)**(4._dp/3._dp)-2._dp)*FACG
DGZETA= ((1._dp+ZETA)**(1._dp/3._dp) -(1._dp-ZETA)**(1._dp/3._dp) )*FACDG
! TOTAL POTENTIAL, AND CONTRIBUTION TO ENERGY
POT = EPSCP + EPSCA*GZETA*(1._dp+HX*ZETA4)
ec = POT*RHOT
! CONTRIBUTION TO FUNCTIONAL DERIVATIVE
DPOT1 = -(X/6._dp)*(DEPSCP + DEPSCA*GZETA*(1._dp+HX*ZETA4)&
+ EPSCA*GZETA*DHX*ZETA4)
DPOT2 = EPSCA*(DGZETA*(1._dp+HX*ZETA4) + 4._dp*GZETA*HX*ZETA3)
DUMA = POT + (DPOT1 + DPOT2*(1._dp-ZETA))
DUMB = POT + (DPOT1 - DPOT2*(1._dp+ZETA))
vc_1 = vc_1 + DUMA
vc_2 = vc_2 + DUMB
end subroutine lsd_VWN_cor
!-------------------------------------------------------------------------------------
! Calculates the integral \int d^3x d^3y \frac{\phi_a(x)\phi_b(x)\phi_c(y)\phi_d(y)}
! {|x-y|} where x,y are 3d space vectors and \phi_a, \phi_b ... are molecular orbitals
!
subroutine psi4_int(phi_a,phi_b,phi_c,phi_d,X_int)
!..Global
use global; use integrals
implicit none
!..Arguments
real(dp), intent(in) :: phi_a(lnbasis), phi_b(lnbasis), phi_c(lnbasis), phi_d(lnbasis)
real(dp), intent(out) :: X_int
!..Local
integer :: k,l,m,n, nrec, nchunk, nrec_last, ichunk, irec
integer(8) :: ind_p
logical :: inv_pairs, read_int
real(dp) :: two_int
X_int=0._dp
nrec=50000000 ! x20 = 1GB
nchunk=nintgr/nrec
nchunk=nchunk+1
nrec_last=mod(nintgr,nrec)
read_int=.true.
if(nchunk==1) then
nrec=nrec_last
read_int=.false.
endif
if(.not.allocated(twoin)) then
allocate( indpacked(nrec), mu(nrec), nu(nrec), lambda(nrec), sigma(nrec), twoin(nrec) )
read_int=.true.
endif