xenclient-oe/recipes-core/images/xenclient-syncvm-image.bb at e8faa77b9c7a8133f6b765a19ad3b1b76045dc98 · jandryuk/xenclient-oe · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
# XenClient Synchronizer client VM image

LICENSE = "GPLv2 & MIT"
LIC_FILES_CHKSUM = " \
    file://${COMMON_LICENSE_DIR}/GPL-2.0;md5=801f80980d171dd6425610833a22dbe6 \
    file://${COMMON_LICENSE_DIR}/MIT;md5=0835ade698e0bcf8506ecda2f7b4f302 \
"

inherit openxt-image

IMAGE_FEATURES += " \
    package-management \
    read-only-rootfs \
    root-bash-shell \
"

IMAGE_FSTYPES = "ext3.vhd.gz"
export IMAGE_BASENAME = "xenclient-syncvm-image"

COMPATIBLE_MACHINE = "(xenclient-syncvm)"

INITSCRIPT_REMOVE = " \
    finish.sh \
    rmnologin.sh \
    urandom \
"

IMAGE_INSTALL = "\
    ${ROOTFS_PKGMANAGE} \
    packagegroup-core-boot \
    packagegroup-base \
    packagegroup-xenclient-common \
    kernel-modules \
    argo-module \
    libargo \
    libargo-bin \
    rsyslog \
    openssh \
    wget \
    sync-client \
    busybox-ifplugd \
    xenclient-syncvm-tweaks \
    ${@bb.utils.contains('DISTRO_FEATURES', 'blktap2', 'xen-tools-blktap', 'xen-tools-blktap3', d)} \
"

require xenclient-version.inc
inherit xenclient-licences

post_rootfs_shell_commands() {
    # enable ctrlaltdel reboot because PV driver uses ctrl+alt+del to interpret reboot issued via xenstore
    echo 'ca:12345:ctrlaltdel:/sbin/shutdown -t1 -a -r now' >> ${IMAGE_ROOTFS}/etc/inittab;

    # Trick to resolve dom0 name with argo.
    echo '1.0.0.0 dom0' >> ${IMAGE_ROOTFS}/etc/hosts;
}
ROOTFS_POSTPROCESS_COMMAND += "post_rootfs_shell_commands; "