BiliPai/settings.gradle.kts at main · jay3-yy/BiliPai · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
pluginManagement {
    repositories {
        google {
            content {
                includeGroupByRegex("com\\.android.*")
                includeGroupByRegex("com\\.google.*")
                includeGroupByRegex("androidx.*")
            }
        }
        mavenCentral()
        gradlePluginPortal()
    }
}

// Optional local checkout for deterministic development when GitHub Packages credentials are not
// available. Production/default resolution still uses the exact declared package coordinates.
providers.gradleProperty("bili.miuix.source").orNull?.let { sourcePath ->
    includeBuild(sourcePath) {
        dependencySubstitution {
            substitute(module("top.yukonga.miuix.kmp:miuix-core-android"))
                .using(project(":miuix-core"))
            substitute(module("top.yukonga.miuix.kmp:miuix-ui-android"))
                .using(project(":miuix-ui"))
            substitute(module("top.yukonga.miuix.kmp:miuix-shader-android"))
                .using(project(":miuix-shader"))
            substitute(module("top.yukonga.miuix.kmp:miuix-blur-android"))
                .using(project(":miuix-blur"))
            substitute(module("top.yukonga.miuix.kmp:miuix-preference-android"))
                .using(project(":miuix-preference"))
            substitute(module("top.yukonga.miuix.kmp:miuix-squircle-android"))
                .using(project(":miuix-squircle"))
            substitute(module("top.yukonga.miuix.kmp:miuix-icons-android"))
                .using(project(":miuix-icons"))
            substitute(module("top.yukonga.miuix.kmp:miuix-nav-android"))
                .using(project(":miuix-nav"))
        }
    }
}

dependencyResolutionManagement {
    repositoriesMode.set(RepositoriesMode.FAIL_ON_PROJECT_REPOS)
    repositories {
        google()
        mavenCentral()
        maven { url = uri("https://jitpack.io") }
        // GitHub Packages (compose-miuix-ui/miuix).
        // Authentication is required even for this public package. Keep credentials outside
        // the repository in ~/.gradle/gradle.properties or environment variables.
        val gprUser = providers.gradleProperty("gpr.user")
            .orElse(providers.environmentVariable("GITHUB_ACTOR"))
        val gprKey = providers.gradleProperty("gpr.key")
            .orElse(providers.environmentVariable("GITHUB_TOKEN"))
        maven {
            name = "GitHubPackagesMiuix"
            url = uri("https://maven.pkg.github.com/compose-miuix-ui/miuix")
            if (gprUser.isPresent && gprKey.isPresent) {
                credentials {
                    username = gprUser.get()
                    password = gprKey.get()
                }
            }
        }
        // Cling Repo
        maven {
            url = uri("http://4thline.org/m2")
            isAllowInsecureProtocol = true
        }
    }
}

rootProject.name = "BiliPai"
include(":app")
include(":baselineprofile")
include(":settings-core")
include(":network-core")
include(":plugin-sdk")
include(":design-system")
include(":dolby-ffmpeg-decoder")
include(":danmaku-engine")