nixaider/flake.nix at main · jbotwell/nixaider · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
{
  description = "A flake for aider";

  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
    flake-parts.url = "github:hercules-ci/flake-parts";
    aider-input = {
      url = "github:paul-gauthier/aider/v0.48.1";
      flake = false;
    };
  };

  outputs = {
    flake-parts,
    aider-input,
    ...
  } @ inputs:
    flake-parts.lib.mkFlake {inherit inputs;} {
      systems = ["x86_64-linux" "aarch64-linux" "x86_64-darwin" "aarch64-darwin"];

      perSystem = {pkgs, ...}: let
        pyPkgs = pkgs.python312Packages;
        aider = pyPkgs.buildPythonPackage {
          pname = "aider";
          version = "0.48.1";
          src = aider-input;
          doCheck = false;
          propagatedBuildInputs = with pyPkgs; [
            backoff
            beautifulsoup4
            configargparse
            diff-match-patch
            diskcache
            gitpython
            google-generativeai
            importlib-resources
            jsonschema
            litellm
            networkx
            numpy
            openai
            packaging
            pathspec
            pillow
            playwright
            prompt-toolkit
            pypandoc
            pyyaml
            rich
            scipy
            sounddevice
            soundfile
            tiktoken
            # not defined in nixpkgs
            streamlit
            grep-ast
          ];
        };
        grep-ast = pyPkgs.buildPythonPackage rec {
          pname = "grep_ast";
          version = "0.3.3";
          format = "wheel";
          src = pyPkgs.fetchPypi {
            inherit pname version format;
            dist = "py3";
            python = "py3";
            sha256 = "sha256-UVy4ib/+/vomxKsTd7mnWz/GeKpfoCv5qk+PIJmag60=";
          };
          doCheck = false;
          propagatedBuildInputs = with pyPkgs; [
            pathspec
            # not defined in nixpkgs
            tree-sitter-languages
          ];
        };
        streamlit = pyPkgs.buildPythonPackage rec {
          pname = "streamlit";
          version = "1.37.0";
          format = "wheel";
          src = pyPkgs.fetchPypi {
            inherit pname version format;
            sha256 = "sha256-0X4tMrB1onCpfxNKtdIru5i05HT6Jh/0ncSis4A4bIQ=";
          };
          propagatedBuildInputs = with pyPkgs; [blinker tornado];
          doCheck = false;
        };
        tree-sitter-languages = pyPkgs.buildPythonPackage rec {
          pname = "tree_sitter_languages";
          version = "1.10.2";
          format = "wheel";
          src = pkgs.fetchPypi {
            inherit pname version format;
            python = "cp312";
            abi = "cp312";
            platform = "manylinux_2_17_x86_64.manylinux2014_x86_64";
            sha256 = "sha256-bS8c0dG91lMy+cK2fUnc8UjPHe11KFHRWaw+XuT00mA=";
          };
          propagatedBuildInputs = with pyPkgs; [tree-sitter];
          doCheck = false;
        };
      in {
        packages = {default = aider;};
        devShells.default = pkgs.mkShell {
          packages = [
            (pkgs.python312.withPackages (ps: [aider]))
          ];
        };
      };
    };
}