spring-method-logging/build.gradle at develop · jgremmen/spring-method-logging · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
plugins {
  id 'java-library'
  id 'com.adarshr.test-logger' version '4.0.0'
}


description = 'Method Logging Extension for Spring'
group = 'de.sayayi.lib'
version = libs.versions.spring.method.logging.get()


layout.buildDirectory = '.build'


configurations {
  optionalApi

  compileOnlyApi.extendsFrom(optionalApi)
}


java {
  toolchain {
    languageVersion = JavaLanguageVersion.of(21)
  }

  withSourcesJar()
  withJavadocJar()
}


compileTestJava {
  options.debugOptions.debugLevel = 'lines,vars,source'
  options.compilerArgs = [ '-parameters' ]
}


test {
  useJUnitPlatform()
}


testlogger {
  theme = 'mocha'
  slowThreshold = 2500
}


repositories {
  mavenCentral()
}


dependencies {
  // java
  compileOnlyApi libs.jetbrains.annotations

  optionalApi libs.slf4j.api
  optionalApi libs.log4j.api
  optionalApi libs.logback.classic
  optionalApi libs.tinylog.api
  optionalApi libs.jboss.logging

  implementation libs.spring.context
  implementation libs.message.format


  // test
  testAnnotationProcessor libs.lombok

  testCompileOnly libs.jetbrains.annotations
  testCompileOnly libs.lombok

  testImplementation libs.junit.jupiter.api
  testImplementation libs.spring.test

  testRuntimeOnly libs.junit.jupiter.engine
  testRuntimeOnly libs.junit.platform.launcher
}


tasks.withType(Jar).configureEach {
  reproducibleFileOrder = true

  manifest {
    attributes(
        'Implementation-Vendor': 'Jeroen Gremmen',
        'Implementation-Vendor-Id': 'de.sayayi',
        'Implementation-Title': project.name,
        'Implementation-Version': project.version,
        'Created-By': System.getProperty('java.version'),
        'Built-Date': new Date().format('yyyy-MM-dd HH:mm:ss')
    )
  }

  metaInf {
    from files('LICENSE')
  }

  dependsOn test
}


apply from: file('gradle/javadoc.gradle')
apply from: file('gradle/publish.gradle')


clean {
  delete layout.projectDirectory.dir('build')
}


wrapper {
  distributionType = Wrapper.DistributionType.BIN
}