SX1276 unable to receive packets

[kuestess]

@jgromes Thanks for the excellent library! I am using a Heltec Lora 32 (v2) in an attempt to receive Insteon packets. As you're probably aware, the Heltec Lora v2 is simply an SX1276 integrated with an ESP32 - pinout for the module is here: pinout. Insteon RF packets are 2-FSK packets of variable length, details of the packet format are here: Insteon packet information.

For now, I'm simply trying to receive packets and will work through the decoding later. I'm using the sketch below based upon the receive_direct example (which I think is the right place to start), but am unable to receive any packets. I've also tried sketches based upon the FSK modem example, but am unable to receive packets there as well. I am using RadioLib 4.5.0. Any help is very much appreciated!

#include <RadioLib.h>

SX1276 radio = new Module(18, 26, 14, 35);

// DIO2 pin: 34
const int pin = 34;

void setup() {
  Serial.begin(9600);

  // initialize SX1278 with FSK modem at 9600 bps
  Serial.print(F("[SX1278] Initializing ... "));
  int state = radio.beginFSK(914.95);
  if (state == ERR_NONE) {
    Serial.println(F("success!"));
  } else {
    Serial.print(F("failed, code "));
    Serial.println(state);
    while (true);
  }

  uint8_t syncWord[] = {0xCE, 0xAA};
  state = radio.setSyncWord(syncWord, 2);
  
  // set function that will be called each time a bit is received
  radio.setDirectAction(readBit);

  // start direct mode reception
  radio.receiveDirect(); 
}

// this function is called when a new bit is received
IRAM_ATTR void readBit(void) {
  // read the data bit
   radio.readBit(pin);
}

void loop() {
  if(radio.available() >= 1) { //shortened to 1 for testing purposes
    Serial.println("[SX1278] Received packet in direct mode!");
    while(radio.available()) {
      // read a byte
      byte b = radio.read();
  
      // print it
      Serial.print(b, HEX);
      Serial.print('\t');
      Serial.write(b);
      Serial.println();
    }
  }
}

[jgromes]

First of all, you're using setSyncWord, which sets sync word for packet operation. If you want to try direct mode, you will have to call setDirectSyncWord.

Also, are you sure you have things like frequency deviation and bit rate configured properly? You don't seem to be doing that in the beginFSK method.

[jgromes]

Also this seems more like a usage question than an actual issue, so until there's some problem in the library I'm converting this to discussion instead.

[kuestess]

Thanks @jgromes - I overlooked that there was a distinct setDirectSyncWord method. I've updated the above code with int state = radio.beginFSK(914.95,48,150,200,0,false); and state = radio.setDirectSyncWord(0x5555CEAA, 16); but am still not able to receive any packets. Settings for frequency deviation, etc. are based upon the Insteon white paper and settings that I have gotten to work using a CC1101 and another library. Is receive direct the best approach, or should I be using the FSK modem as a basis? Thanks again for your help!

[wurst44]

I think it should be:

int16_t PhysicalLayer::setDirectSyncWord(uint32_t syncWord, uint8_t len)
Set sync word to be used to determine start of packet in direct reception mode.

Parameter:
syncWord – Sync word bits.
len – Sync word length in bits.

this should work? state = radio.setDirectSyncWord(10000, 101);
or even this? radio.setDirectSyncWord(1, 1);

[jgromes]

@kuestess are you usre about the FSK paramteres? 48 kbps bit rate with 150 kHz frequency deviation seems highly uncommon. Also the 200 kHz receiver bandwidth is probably too narrow. If you only want to set the sync word without the extra preamble bits (which may or may not be present in your remote - you haven't mentioned them)m then you would use radio.setDirectSyncWord(0xCEAA, 16);

@wurst44 not sure how you arrived at that, but surely you meant something to specify the sync word as bits, i.e. state = radio.setDirectSyncWord(0b10000, 0b101); - but that would give you sync word 0x10 that's 6 bits long ...?

[kuestess]

@jgromes Insteon is a domoticz protocol, so perhaps (?) some of the FSK parameters are different than typical - that said, I'm far from an expert in RF, so appreciate your help. The parameters are from both the Insteon RF spec and a working sketch using a CC1101 and a port of rtl_433 to ESP32. The spec lists frequency deviation as 75kHz, however reading the SX127X spec sheet suggested the register was single-sided, so I doubled it. Neither 75 nor 150 kHz worked. The missing piece from the spec is the receiver bw, however 200 kHz is working on a CC1101 and seems to be the max supported by the library for SX1276. Is there any way to increase receiver bw beyond 200kHz? Alternately, is there a 'raw' mode that would receive any packets broadcast at 915MHz carrier - the thought being to help narrow down specific FSK parameters?

[jgromes]

Ah, forgot SX127x can't do more than 200 kHz channel filter.

Alternately, is there a 'raw' mode that would receive any packets broadcast at 915MHz carrier

Unfortunately not, you need to know these parameters in advance in order to demodulate the signal, since SX127x is not an SDR.

[wurst44]

btw @jgromes, I am still not able to receive anything with the SX1278 in OOK mode.

• Hello World with 2 SX1278 (TX/RX) works.
• A test With CC1101 and promiscuous mode results in receiving stuff but I also get a lot of noise (Hello World works).
• Also no luck with the RadioLib RFM69 OOK (Hello World works).
• Other libs work with OOK CC1101 (EvilCrowRF)
• I am using 3 different rf remotes

Is the lib using the SX127X's continous mode (data sheet 4.2.12.) / package mode (4.2.13.)?

// include the library
#include <RadioLib.h>

// SX1278 radio = new Module(NSS, DIO0, RESET, DIO1);  
// SX1278 radio = new Module(10, 2, 9, 3);  	  // arduino
// SX1278 radio = new Module(15, 4, 16, 5); 	  // nodemcu esp8266 DIO2 11
// SX1278 radio = new Module(18, 26, 14, 4);  // ttgo-lora-esp32 v1
SX1278 radio = new Module(18, 26, 33, 13);    // ttgo-lora-esp32 v2

// nodemcu esp8266
// NSS:   15 D8
// DIO0:  5  D1
// RESET: 16 D0
// DIO1:  4  D2
// const int pin = 9; // DIO2: D11/SD2	GPIO9

// nodemcu ttgo-lora-esp32 v2
// NSS:   18
// DIO0:  26
// RESET: 14
// DIO1:  13
const int pin = 15; // DIO2:  15

// ESP32
void IRAM_ATTR readBit(void) {
// ESP8266
// void ICACHE_RAM_ATTR  readBit(void) {
  radio.readBit(pin);
}

void setup() {
  Serial.begin(9600);

	Serial.print(F("[SX1278] Initializing ... "));
	// int state = radio.begin();
	int state = radio.beginFSK();
	if (state == ERR_NONE) {
		Serial.println(F("success!"));
	} else {
		Serial.print(F("failed, code "));
		Serial.println(state);
		while (true);
	}

	state = radio.setOOK(true);
  	state = radio.setFrequency(433.92);
	state = radio.setBitRate(20);
	// state = radio.setBitRate(8.494);
	// state = radio.setBitRate(9);
	state = radio.setFrequencyDeviation(100); // Though 10 kHz for a 5 kbps seems reasonable enough
	state = radio.setRxBandwidth(200); // 50 kHz
	// state = radio.setRxBandwidth(250); // 50 kHz
	state = radio.setCRC(false); // errorCorrection
	// state = radio.setOutputPower(17.0);
	// state = radio.setCurrentLimit(100);
	// state = radio.setOokThresholdType(SX127X_OOK_THRESH_AVERAGE);
	// state = radio.disableAddressFiltering(); // address filtering is disabled by default - also it has no effect on direct mode
	// state = radio.setPreambleLength(0); // in direct reception, preamble isn't processed

	// state = radio.setDirectSyncWord(1101, 4); // schlafWhite
	// state = radio.setDirectSyncWord(1000, 4); // schlafWhite
	// state = radio.setDirectSyncWord(1001, 4); // interWhite
	// state = radio.setDirectSyncWord(10000, 5); // interGrey
	// state = radio.setDirectSyncWord(10000, 101); // interGrey
	state = radio.setDirectSyncWord(1, 1); // XXX

	// uint8_t syncWord[] = {0x45};
	// state = radio.setSyncWord(syncWord, 1); // interGrey

	if (state != ERR_NONE) {
		Serial.println(F("[SX1278] Unable to start direct reception mode, code "));
		Serial.println(state);
		while (true);
	} else if (state == ERR_NONE) {
		Serial.println(F("[SX1278] Initialized!"));
	}

	radio.setDirectAction(readBit);
  	radio.receiveDirect();

	Serial.println(F("[SX1278] Waiting for incoming transmission ... "));

}

void loop() {

	int state = radio.receiveDirect();
	if (state != ERR_NONE) {
		Serial.println(F("[SX1278] Unable to start direct reception mode, code "));
		Serial.println(state);
	}

	// if(radio.available() >= 15) {
		// Serial.println("[SX1278] Received packet in direct mode!");
		// while(radio.available()) {
		// read a byte
		byte b = radio.read();
	
		// print it
		Serial.print(b, HEX);
		Serial.print('\t');
		Serial.write(b);
		Serial.println();
		// }
	// }

}

[SX1278] Initializing ... success!
[SX1278] Initialized!
[SX1278] Waiting for incoming transmission ...
0       ␀
0       ␀
0       ␀
0       ␀
0       ␀
0       ␀
0       ␀
0       ␀
0       ␀
0       ␀
0       ␀
0       ␀
0       ␀

thank you for your effort and sry for highjacking your post @kuestess 😢

[jgromes]

@wurst44

sry for highjacking your post

I'm glad you're aware you shouldn't be doing this, and disappointed you did it anyway.

The code you have posted seems more than a bit confused. In the loop(), you're spamming the radio with requests to start direct reception, then immediately trying to read the data without checking if there's anything available. Follow the example: enable the direct reception once in setup(), set your sync word correctly (you can't just put in 10001 and hope the compiler understands it as binary number, you have to specify it as such using the 0b prefix), and only call read() once you know there's something available().

EDIT:

Is the lib using the SX127X's continous mode (data sheet 4.2.12.) / package mode (4.2.13.)?

For direct reception, continuous mode is used - the packet engine within SX127x is completely bypassed and can be implemented in software in order to support various non-standard packet types.