undercarriage/build.gradle at master · joeyb/undercarriage · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
buildscript {
    repositories {
        jcenter()
        mavenLocal()
    }
    dependencies {
        classpath 'com.github.ben-manes:gradle-versions-plugin:0.13.0'
        classpath 'com.google.protobuf:protobuf-gradle-plugin:0.8.0'
    }
}

plugins {
    id 'nebula.project' version '3.3.0'
    id 'nebula.provided-base' version '3.1.0'
}

apply plugin: 'com.github.ben-manes.versions'

subprojects { project ->
    repositories {
        mavenCentral()
    }

    apply plugin: 'java'

    apply plugin: 'checkstyle'
    apply plugin: 'idea'
    apply plugin: 'jacoco'
    apply plugin: 'nebula.contacts'
    apply plugin: 'nebula.info'
    apply plugin: 'nebula.javadoc-jar'
    apply plugin: 'nebula.provided-base'
    apply plugin: 'nebula.source-jar'

    group 'org.joeyb.undercarriage'

    sourceCompatibility = 1.8

    dependencies {
        provided "org.immutables:value:$immutablesVersion"

        compile "javax.inject:javax.inject:$javaxInjectVersion"

        testCompile "junit:junit:$junitVersion"
        testCompile "org.assertj:assertj-core:$assertjVersion"
        testCompile "org.mockito:mockito-core:$mockitoVersion"
    }

    checkstyle {
        configFile = file("$rootDir/gradle/checkstyle/checkstyle.xml")
        toolVersion = '6.18'
    }

    idea {
        module {
            def generatedMainDir = file('src/main/generated')
            def generatedTestDir = file('src/test/generated_tests')

            sourceDirs += generatedMainDir
            testSourceDirs += generatedTestDir

            generatedSourceDirs += generatedMainDir
            generatedSourceDirs += generatedTestDir
        }
    }

    jacoco {
        toolVersion = '0.7.6.201602180812'
    }

    jacocoTestReport {
        reports {
            xml.enabled = true
            html.enabled = true
        }
    }

    check.dependsOn jacocoTestReport

    project.tasks.withType(Javadoc) {
        failOnError = false
    }
    project.tasks.withType(Test) { Test testTask ->
        testTask.testLogging.exceptionFormat = 'full'
    }
}