Various OG image improvements

Some better naming and switching from controller to plug, that just feels a lot better.

Author: joladev

lib/jola_dev/og_image.ex

@@ -1,21 +1,21 @@
 defmodule JolaDev.OGImage do
   @moduledoc """
   Per-page Open Graph image lookup. All images are rendered at compile time
-  via `JolaDev.OGImage.Renderer` and baked into the `@baked` module
-  attribute, then served at runtime from `JolaDevWeb.OGImageController`.
+  via `JolaDev.OGImage.Renderer` and baked into the `@images` module
+  attribute, then served at runtime from `JolaDevWeb.Plugs.OGImage`.
 
   See `JolaDev.OGImage.Renderer` for the rendering primitives.
   """
 
   alias JolaDev.OGImage.Renderer
 
   @dev_mode Application.compile_env!(:jola_dev, :og_image_dev_mode)
-  @baked if not @dev_mode,
-           do:
-             Map.new(Renderer.all_slugs(), fn slug ->
-               {title, description} = Renderer.content_for(slug)
-               {slug, Renderer.generate_bytes(title, description)}
-             end)
+  @images if not @dev_mode,
+            do:
+              Map.new(Renderer.all_slugs(), fn slug ->
+                {title, description} = Renderer.content_for(slug)
+                {slug, Renderer.generate_bytes(title, description)}
+              end)
 
   @doc """
   Returns the public asset path for a slug's OG image. Used by controllers,
@@ -26,9 +26,9 @@ defmodule JolaDev.OGImage do
   @doc """
   Returns `{:ok, png_bytes}` for a known slug, `:error` otherwise.
   """
-  def bytes_for(slug) do
-    if @baked do
-      Map.fetch(@baked, slug)
+  def image_for(slug) do
+    if @images do
+      Map.fetch(@images, slug)
     else
       case Renderer.content_for(slug) do
         {title, description} ->

lib/jola_dev_web/controllers/og_image_controller.ex

@@ -30,6 +30,7 @@ defmodule JolaDevWeb.Endpoint do
     gzip: Mix.env() == :prod,
     only: JolaDevWeb.static_paths()
 
+  plug JolaDevWeb.Plugs.OGImage
   plug JolaDevWeb.Plugs.BlogRedirect
   plug JolaDevWeb.Plugs.StripTrailingSlash
 

lib/jola_dev_web/endpoint.ex

@@ -0,0 +1,38 @@
+defmodule JolaDevWeb.Plugs.OGImage do
+  @moduledoc """
+  Serves Open Graph preview images from `JolaDev.OGImage`. Intercepts any
+  `/images/og/<slug>.png` request, looks up the baked PNG bytes, and sends
+  them with appropriate cache headers. Falls through for unknown slugs so
+  Phoenix's router can render a 404.
+  """
+
+  @behaviour Plug
+
+  import Plug.Conn
+
+  @dev_mode Application.compile_env!(:jola_dev, :og_image_dev_mode)
+  @cache_control if @dev_mode, do: "public, max-age=0", else: "public, max-age=31536000"
+
+  @impl Plug
+  def init(opts), do: opts
+
+  @impl Plug
+  def call(%Plug.Conn{request_path: "/images/og/" <> rest} = conn, _) do
+    slug = String.replace_suffix(rest, ".png", "")
+
+    case JolaDev.OGImage.image_for(slug) do
+      {:ok, bytes} ->
+        conn
+        |> put_resp_content_type("image/png")
+        |> put_resp_header("cache-control", @cache_control)
+        |> send_resp(200, bytes)
+        |> halt()
+
+      :error ->
+        # Let the request fall through so Phoenix handles the 404
+        conn
+    end
+  end
+
+  def call(conn, _), do: conn
+end

lib/jola_dev_web/plugs/og_image.ex

@@ -42,8 +42,6 @@ defmodule JolaDevWeb.Router do
     get "/posts", BlogController, :index
     get "/posts/tag/:tag", BlogController, :tag
     get "/posts/:id", BlogController, :show
-
-    get "/images/og/*slug", OGImageController, :show
   end
 
   scope "/", JolaDevWeb do

lib/jola_dev_web/router.ex

@@ -10,28 +10,28 @@ defmodule JolaDev.OGImageTest do
     end
   end
 
-  describe "bytes_for/1" do
+  describe "image_for/1" do
     test "returns the baked PNG bytes for a known static slug" do
-      assert {:ok, bytes} = OGImage.bytes_for("home")
+      assert {:ok, bytes} = OGImage.image_for("home")
       assert <<137, "PNG\r\n", 26, "\n", _rest::binary>> = bytes
     end
 
     test "returns the baked PNG bytes for a known post slug" do
       post = List.first(JolaDev.Blog.all_posts())
 
-      assert {:ok, bytes} = OGImage.bytes_for("posts/#{post.id}")
+      assert {:ok, bytes} = OGImage.image_for("posts/#{post.id}")
       assert <<137, "PNG\r\n", 26, "\n", _rest::binary>> = bytes
     end
 
     test "returns the baked PNG bytes for a known tag slug" do
       tag = List.first(JolaDev.Blog.all_tags())
 
-      assert {:ok, bytes} = OGImage.bytes_for("posts/tag/#{tag}")
+      assert {:ok, bytes} = OGImage.image_for("posts/tag/#{tag}")
       assert <<137, "PNG\r\n", 26, "\n", _rest::binary>> = bytes
     end
 
     test "returns :error for an unknown slug" do
-      assert OGImage.bytes_for("no-such-page") == :error
+      assert OGImage.image_for("no-such-page") == :error
     end
   end
 end

test/jola_dev/og_image_test.exs

@@ -0,0 +1,60 @@
+defmodule JolaDevWeb.Plugs.OGImageTest do
+  use JolaDevWeb.ConnCase, async: true
+  alias JolaDevWeb.Plugs.OGImage
+
+  describe "call/2" do
+    test "serves a PNG for a static slug", %{conn: conn} do
+      conn =
+        conn
+        |> Map.put(:request_path, "/images/og/home.png")
+        |> OGImage.call([])
+
+      assert conn.status == 200
+      assert get_resp_header(conn, "content-type") == ["image/png; charset=utf-8"]
+      assert <<137, "PNG\r\n", 26, "\n", _rest::binary>> = conn.resp_body
+      assert conn.halted
+    end
+
+    test "serves a PNG for a known post slug", %{conn: conn} do
+      post = List.first(JolaDev.Blog.all_posts())
+
+      conn =
+        conn
+        |> Map.put(:request_path, "/images/og/posts/#{post.id}.png")
+        |> OGImage.call([])
+
+      assert conn.status == 200
+      assert <<137, "PNG\r\n", 26, "\n", _rest::binary>> = conn.resp_body
+    end
+
+    test "serves a PNG for a known tag slug", %{conn: conn} do
+      tag = List.first(JolaDev.Blog.all_tags())
+
+      conn =
+        conn
+        |> Map.put(:request_path, "/images/og/posts/tag/#{tag}.png")
+        |> OGImage.call([])
+
+      assert conn.status == 200
+      assert <<137, "PNG\r\n", 26, "\n", _rest::binary>> = conn.resp_body
+    end
+
+    test "falls through for an unknown OG slug", %{conn: conn} do
+      original = Map.put(conn, :request_path, "/images/og/no-such-page.png")
+
+      result = OGImage.call(original, [])
+
+      assert result == original
+      refute result.halted
+    end
+
+    test "passes through for paths outside /images/og/", %{conn: conn} do
+      original = Map.put(conn, :request_path, "/posts/running-local-models-on-m4")
+
+      result = OGImage.call(original, [])
+
+      assert result == original
+      refute result.halted
+    end
+  end
+end