Allow flake consumer to specify GHC version (#185)

Closes #178

Adds ability to install via nix flake, passing in GHC version.

Also adds LSP instructions for the helix editor.

Author: jaredramirez

README.md

@@ -25,9 +25,14 @@ If you want to use `static-ls` in your IDE then
 recommended alongside `-fdefer-type-errors flag` for better UX
 and the [ghc hiedb plugin](https://github.com/josephsumabat/hiedb-plugin) for re-indexing. 
 
-Currently only ghc 9.4.4 and 9.6.1 are explicitly supported but I'm happy to add support for other versions of ghc if desired
+Currently only ghc 9.4.4 and 9.6.1 are explicitly supported but I'm happy to add support for other versions of ghc if desired.
+
+To install, it is recommended to build from source. It's important to build
+`static-ls` with the same version of GHC that your project uses.
+
+If you use nix, you can checkout the section below to see how to install
+`static-ls`  via nix flake.
 
-(NOTE: The current version on hackage is out of date. Building from source is currently recommended.)
 
 ## Quick start
 
@@ -154,6 +159,33 @@ static-ls includes a `ghcid` subcommand which passes the appropriate flags to us
 - Must be compiled on the same version of ghc as the project
 - You will need to re-index your hie files once you edit your project
 
+## Install with Nix
+
+**IMPORTANT:** You must build `static-ls` with the same GHC version as your project. Using a different GHC version will result in compatibility issues with HIE files.
+
+Add `static-ls` as an input to your flake:
+
+```nix
+# flake.nix
+{
+  inputs = {
+    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
+    static-ls = {
+      url = "github:josephsumabat/static-ls";
+      inputs.nixpkgs.follows = "nixpkgs";  # Use your nixpkgs version
+    };
+  };
+
+  outputs = { self, nixpkgs, static-ls, ... }: {
+    packages.x86_64-linux.default = static-ls.lib.x86_64-linux.mkPackage {
+      ghcVersion = "ghc963";  # Match your project's GHC version
+    };
+  };
+}
+```
+
+Available GHC versions include: `ghc963`, `ghc981`, `ghc982`, `ghc945`, `ghc946`, etc. Check your nixpkgs for available versions.
+
 ## Editor setup
 Instructions for editor setup
 
@@ -231,6 +263,27 @@ You can technically use any LSP compliant client - for a generic one we generall
   :language-id "haskell"))
 ```
 
+### Helix
+Modify your `languages.toml` config file to add the following:
+
+```toml
+[[language]]
+name = "haskell"
+language-servers = ["haskell-static-ls"]
+
+[language-server.haskell-static-ls]
+command = "static-ls"
+
+```
+
+You can verify that it's configured properly and that `static-ls` is discoverable
+by helix with `hx --health haskell`. You should see something like:
+
+```sh
+Configured language servers:
+  ✓ haskell-static-ls: /path/to/static-ls
+```
+
 ## Troubleshooting
 ### Slowdowns
 Some editors watch all folders in your project directory for changes and report those to the LSP server. This might cause significant slowdown when `.hiefiles` or `.hifiles` are tracked (documented in #175).

flake.nix

@@ -9,46 +9,77 @@
     flake-utils.url = "github:numtide/flake-utils";
   };
 
-  outputs = {
-    self,
-    nixpkgs,
-    flake-utils,
-  }:
-    flake-utils.lib.eachDefaultSystem (system: let
-      # pkgs = nixpkgs.legacyPackages.${system};
-      pkgs = import nixpkgs {
-        inherit system;
-        overlays = [
-          (import ./nix/overlays)
-        ];
-      };
-
-      #haskellPackages = pkgs.haskell.packages.ghc963;
-      haskellPackages = pkgs.haskellPackages;
-
-      jailbreakUnbreak = pkg:
-        pkgs.haskell.lib.doJailbreak (pkg.overrideAttrs (_: {meta = {};}));
+  outputs =
+    {
+      self,
+      nixpkgs,
+      flake-utils,
+    }:
+    let
+      # Default GHC version used for the default package outputs
+      defaultGhcVersion = "ghc963";
 
+      # Name of package
       packageName = "static-ls";
-    in {
-      packages.${packageName} = pkgs.haskell.lib.dontCheck (haskellPackages.callCabal2nix packageName self rec {
-        # Dependency overrides go here
-      });
-
-      packages.default = self.packages.${system}.${packageName};
-
-      devShells.default = pkgs.mkShell {
-        buildInputs = with pkgs; [
-          pkgs.haskell.packages.${pkgs.ghcVersion}.haskell-language-server # you must build it with your ghc to work
-          haskellPackages.fourmolu
-          haskellPackages.hiedb
-          sqlite
-          ghcid
-          cabal-install
-          alejandra
-        ];
-        inputsFrom = [self.packages.${system}.${packageName}.env];
-        shellHook = "PS1=\"[static-ls:\\w]$ \"";
-      };
-    });
+
+      # Function to create packages for a given GHC version
+      mkNixPkgs =
+        {
+          system,
+          ghcVersion,
+        }:
+        import nixpkgs {
+          inherit system;
+          overlays = [
+            (import ./nix/overlays ghcVersion)
+          ];
+        };
+
+      # Given a pkg set, build static-ls
+      mkPackage =
+        pkgs:
+        pkgs.haskell.lib.dontCheck (
+          pkgs.haskellPackages.callCabal2nix packageName self rec {
+            # Dependency overrides go here
+          }
+        );
+
+    in
+    flake-utils.lib.eachDefaultSystem (
+      system:
+      let
+        pkgs = mkNixPkgs {
+          inherit system;
+          ghcVersion = defaultGhcVersion;
+        };
+        package = mkPackage pkgs;
+      in
+      {
+        packages.${packageName} = package;
+        packages.default = package;
+
+        devShells.default = pkgs.mkShell {
+          buildInputs = with pkgs; [
+            pkgs.haskell.packages.${pkgs.ghcVersion}.haskell-language-server # you must build it with your ghc to work
+            haskellPackages.fourmolu
+            haskellPackages.hiedb
+            sqlite
+            ghcid
+            cabal-install
+            alejandra
+          ];
+          inputsFrom = [ package.env ];
+          shellHook = "PS1=\"[static-ls:\\w]$ \"";
+        };
+
+        # Expose a function that consumers can use to build with their desired
+        # GHC version
+        lib.mkPackage =
+          { ghcVersion }:
+          (mkPackage (mkNixPkgs {
+            inherit system ghcVersion;
+          }));
+
+      }
+    );
 }

nix/overlays/default.nix

@@ -8,8 +8,9 @@ let
   };
 
 in
+  ghcVersion:
   self: super: {
-    ghcVersion = "ghc963";
+    ghcVersion = ghcVersion;
 
     all-cabal-hashes =
         # Update revision to match required hackage