build.gradle

dependencies {
    api project(':xds')
    api libs.jackson.dataformat.yaml
    api libs.protobuf.java.util
    api(libs.controlplane.server) {
        exclude group: 'io.envoyproxy.controlplane', module: 'api'
    }
    api(libs.controlplane.cache) {
        exclude group: 'io.envoyproxy.controlplane', module: 'api'
    }

    testImplementation project(':athenz')
    testImplementation project(':xds-athenz')
    testImplementation libs.athenz.zms.client
    testImplementation libs.testcontainers.junit.jupiter
}

// Copy the Athenz Docker resources from ':athenz'.
task copyTestResources(type: Copy) {
    from("${rootProject.projectDir}/athenz/src/test") {
        include 'resources/**'
        include '**/AthenzDocker.java'
        include '**/AthenzExtension.java'
    }
    into "${project.ext.genSrcDir}/test"
}

tasks.compileTestJava.dependsOn(tasks.copyTestResources)
tasks.processTestResources.dependsOn(tasks.copyTestResources)
tasks.sourcesJar.dependsOn(tasks.copyTestResources)