ZSH Ctrl-R - any way to multi-select and combine lines?

[drelephant]

I think it would be useful to be able to multi-select items in fzf from my Ctrl-R history and combine them with ; characters between them.

In this way I could assemble longer commands from my old history.

I'm using oh-my-zsh with both fzf and fzf-tab added to my plugins.

I tried adding --multi to FZF_CTRL_R_OPTS in my .zshrc but it didn't seem to do anything.

Is there any way to achieve this?

[LangLangBart]

I tried adding --multi to FZF_CTRL_R_OPTS in my .zshrc but it didn't seem to do anything.

The last flag wins; +m (--no-multi) appears after FZF_CTRL_R_OPTS, there is no chance to overwrite it by default.

fzf/shell/key-bindings.zsh

Lines 136 to 141 in 2ab923f

	if zmodload -F zsh/parameter p:{commands,history} 2>/dev/null && (( ${+commands[perl]} )); then
	selected="$(printf '%s\t%s\000' "${(kv)history[@]}" |
	perl -0 -ne 'if (!$seen{(/^\s*[0-9]+\**\t(.*)/s, $1)}++) { s/\n/\n\t/g; print; }' |
	FZF_DEFAULT_OPTS=$(__fzf_defaults "" "-n2..,.. --scheme=history --bind=ctrl-r:toggle-sort,alt-r:toggle-raw --wrap-sign '\t↳ ' --highlight-line ${FZF_CTRL_R_OPTS-} --query=${(qqq)LBUFFER} +m --read0") \
	FZF_DEFAULT_OPTS_FILE='' $(__fzfcmd))"
	else

Even with the -m option enabled, the tricky part is to reliably extract the history event numbers to construct the combined commands.

Below is a modified 'fzf-history-widget' version, add it after your source <(fzf --zsh) line and it should work:

• multi select
• combine multiple commands with '; '

# CTRL-R - Paste the selected command from history into the command line
fzf-history-widget() {
  local selected
  setopt localoptions noglobsubst noposixbuiltins pipefail no_aliases noglob nobash_rematch extendedglob 2> /dev/null
  # Ensure the module is loaded if not already, and the required features, such
  # as the associative 'history' array, which maps event numbers to full history
  # lines, are set. Also, make sure Perl is installed for multi-line output.
  if zmodload -F zsh/parameter p:{commands,history} 2>/dev/null && (( ${+commands[perl]} )); then
    selected="$(printf '%s\t%s\000' "${(kv)history[@]}" |
      perl -0 -ne 'if (!$seen{(/^\s*[0-9]+\**\t(.*)/s, $1)}++) { s/\n/\n\t/g; print; }' |
      FZF_DEFAULT_OPTS=$(__fzf_defaults "" "-n2..,.. --scheme=history --bind=ctrl-r:toggle-sort,alt-r:toggle-raw --wrap-sign '\t↳ ' --highlight-line ${FZF_CTRL_R_OPTS-} --query=${(qqq)LBUFFER} -m --read0") \
      FZF_DEFAULT_OPTS_FILE='' $(__fzfcmd))"
  else
    selected="$(fc -rl 1 | __fzf_exec_awk '{ cmd=$0; sub(/^[ \t]*[0-9]+\**[ \t]+/, "", cmd); if (!seen[cmd]++) print $0 }' |
      FZF_DEFAULT_OPTS=$(__fzf_defaults "" "-n2..,.. --scheme=history --bind=ctrl-r:toggle-sort,alt-r:toggle-raw --wrap-sign '\t↳ ' --highlight-line ${FZF_CTRL_R_OPTS-} --query=${(qqq)LBUFFER} -m") \
      FZF_DEFAULT_OPTS_FILE='' $(__fzfcmd))"
  fi
  local ret=$?
  local -a cmds
  if [ -n "$selected" ]; then
    if [[ $(__fzf_exec_awk '{print $1; exit}' <<< "$selected") =~ ^[1-9][0-9]* ]]; then
      for line in ${(f)selected}; do
        if (( ${+commands[perl]} )); then
          [[ $line == (#b)(<->)$'\t'* ]] && cmds+=("${history[${match[1]}]}")
        elif [[ $(__fzf_exec_awk '{print $1; exit}' <<< "$line") =~ ^[1-9][0-9]* ]]; then
          cmds+=("${history[${MATCH}]}")
        fi
      done
      LBUFFER+="${(j:; :)cmds}"
    else # selected is a custom query, not from history
      LBUFFER="$selected"
    fi
  fi
  zle reset-prompt
  return $ret
}

diff

--- a/shell/key-bindings.zsh
+++ b/shell/key-bindings.zsh
@@ -130,5 +130,5 @@ fi
 fzf-history-widget() {
   local selected
-  setopt localoptions noglobsubst noposixbuiltins pipefail no_aliases noglob nobash_rematch 2> /dev/null
+  setopt localoptions noglobsubst noposixbuiltins pipefail no_aliases noglob nobash_rematch extendedglob 2> /dev/null
   # Ensure the module is loaded if not already, and the required features, such
   # as the associative 'history' array, which maps event numbers to full history
@@ -137,15 +137,23 @@ fzf-history-widget() {
     selected="$(printf '%s\t%s\000' "${(kv)history[@]}" |
       perl -0 -ne 'if (!$seen{(/^\s*[0-9]+\**\t(.*)/s, $1)}++) { s/\n/\n\t/g; print; }' |
-      FZF_DEFAULT_OPTS=$(__fzf_defaults "" "-n2..,.. --scheme=history --bind=ctrl-r:toggle-sort,alt-r:toggle-raw --wrap-sign '\t↳ ' --highlight-line ${FZF_CTRL_R_OPTS-} --query=${(qqq)LBUFFER} +m --read0") \
+      FZF_DEFAULT_OPTS=$(__fzf_defaults "" "-n2..,.. --scheme=history --bind=ctrl-r:toggle-sort,alt-r:toggle-raw --wrap-sign '\t↳ ' --highlight-line ${FZF_CTRL_R_OPTS-} --query=${(qqq)LBUFFER} -m --read0") \
       FZF_DEFAULT_OPTS_FILE='' $(__fzfcmd))"
   else
     selected="$(fc -rl 1 | __fzf_exec_awk '{ cmd=$0; sub(/^[ \t]*[0-9]+\**[ \t]+/, "", cmd); if (!seen[cmd]++) print $0 }' |
-      FZF_DEFAULT_OPTS=$(__fzf_defaults "" "-n2..,.. --scheme=history --bind=ctrl-r:toggle-sort,alt-r:toggle-raw --wrap-sign '\t↳ ' --highlight-line ${FZF_CTRL_R_OPTS-} --query=${(qqq)LBUFFER} +m") \
+      FZF_DEFAULT_OPTS=$(__fzf_defaults "" "-n2..,.. --scheme=history --bind=ctrl-r:toggle-sort,alt-r:toggle-raw --wrap-sign '\t↳ ' --highlight-line ${FZF_CTRL_R_OPTS-} --query=${(qqq)LBUFFER} -m") \
       FZF_DEFAULT_OPTS_FILE='' $(__fzfcmd))"
   fi
   local ret=$?
+  local -a cmds
   if [ -n "$selected" ]; then
     if [[ $(__fzf_exec_awk '{print $1; exit}' <<< "$selected") =~ ^[1-9][0-9]* ]]; then
-      zle vi-fetch-history -n $MATCH
+      for line in ${(f)selected}; do
+        if (( ${+commands[perl]} )); then
+          [[ $line == (#b)(<->)$'\t'* ]] && cmds+=("${history[${match[1]}]}")
+        elif [[ $(__fzf_exec_awk '{print $1; exit}' <<< "$line") =~ ^[1-9][0-9]* ]]; then
+          cmds+=("${history[${MATCH}]}")
+        fi
+      done
+      LBUFFER+="${(j:; :)cmds}"
     else # selected is a custom query, not from history
       LBUFFER="$selected"

EDIT1/2: shorten diff
EDIT3: enable extendedglob

[drelephant]

I really, really appreciate the effort, but unfortunately I couldn't get it to work?

I copied all of that into my .zshrc at the very bottom, it must be running on Ctrl-r because it would let me multi-select using tab, but nothing came onto the command line when I press enter?

I'm not knowledgeable enough about how it all fits together to troubleshoot why it isn't working.

[LangLangBart]

but unfortunately I couldn't get it to work?

thx, I can reproduce. can u try adding extendedglob to setopt localoptions ...?

setopt localoptions noglobsubst noposixbuiltins pipefail no_aliases noglob nobash_rematch extendedglob 2> /dev/null

[drelephant]

Thanks so much, looks to be working now!!

[drelephant]

That's really awesome, definitely should work like that by default!!

[junegunn]

Thanks @LangLangBart for the suggestion. FYI, this behavior is currently supported in the fish version. So I'm open to having it for other shells as well.

#4280

[LangLangBart]

behavior is currently supported in the fish version

was not aware of it

opened a PR with a draft for zsh implementation: #4595