backend/build.gradle at main · kgu-basic-capstone/backend · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
plugins {
  id 'java'
  id 'com.diffplug.spotless' version '6.18.0'
  id 'checkstyle'
}

repositories {
  mavenCentral()
}

spotless {
  java {
    googleJavaFormat()
    targetExclude("**/generated/**")
  }

  kotlin {
    ktlint()
    targetExclude("**/generated/**")
  }

  format 'misc', {
    target '**/*.md', '**/*.yml', '**/*.yaml', '**/*.json'
    trimTrailingWhitespace()
    indentWithSpaces(2)
    endWithNewline()
  }
}

tasks.withType(Test) {
  reports {
    html.required = true
    junitXml.required = true
  }

  testLogging {
    events "passed", "skipped", "failed"
    exceptionFormat "full"
  }
}

tasks.withType(JavaCompile) {
  options.encoding = 'UTF-8'
  options.compilerArgs += [
    '-Xlint:unchecked',
    '-Xlint:deprecation',
    '-parameters'
  ]
}

checkstyle {
  toolVersion = '10.3.3'
  configFile = file("${rootDir}/.idea/checkstyleidea/checkstyle-config.xml")
  maxErrors = 0
  maxWarnings = 0
  ignoreFailures = false
}

task installGitHooks(type: Copy) {
  from new File(rootProject.rootDir, '.devcontainer/pre-commit')
  into new File(rootProject.rootDir, '.git/hooks/')
  fileMode 0755
}