feat(raycast): add khanelimac script commands

Author: khaneliman

homes/aarch64-darwin/khaneliman@khanelimac/default.nix

@@ -21,6 +21,8 @@ in
     programs = {
       graphical = {
         apps = {
+          raycast = enabled;
+
           thunderbird =
             let
               # Not super secret, just doesn't need to be scraped so easily.

modules/home/programs/graphical/apps/raycast/default.nix

@@ -0,0 +1,140 @@
+{
+  config,
+  lib,
+  pkgs,
+
+  ...
+}:
+let
+  cfg = config.khanelinix.programs.graphical.apps.raycast;
+
+  basePath = lib.concatStringsSep ":" [
+    "/etc/profiles/per-user/${config.home.username}/bin"
+    "/run/current-system/sw/bin"
+    "/nix/var/nix/profiles/default/bin"
+    "/opt/homebrew/bin"
+    "/usr/local/bin"
+    "/usr/bin"
+    "/bin"
+    "/usr/sbin"
+    "/sbin"
+  ];
+
+  mkScript =
+    {
+      title,
+      description,
+      body,
+      icon ? "command-symbol",
+      mode ? "compact",
+      argument1 ? null,
+    }:
+    ''
+      #!${pkgs.runtimeShell}
+      # @raycast.schemaVersion 1
+      # @raycast.title ${title}
+      # @raycast.mode ${mode}
+      # @raycast.icon ${icon}
+      # @raycast.description ${description}
+      ${lib.optionalString (argument1 != null) "# @raycast.argument1 ${builtins.toJSON argument1}"}
+
+      set -euo pipefail
+      export PATH=${lib.escapeShellArg basePath}
+
+      ${body}
+    '';
+in
+{
+  options.khanelinix.programs.graphical.apps.raycast.enable =
+    lib.mkEnableOption "Raycast script commands";
+
+  config = lib.mkIf cfg.enable {
+    # Raycast stores script directory registrations in private app state.
+    # Add ~/.config/raycast/script-commands once from Raycast Settings >
+    # Script Commands > Add Script Directory; scripts below stay declarative.
+    xdg.configFile = {
+      "raycast/script-commands/nix-switch.sh" = {
+        executable = true;
+        text = mkScript {
+          title = "Nix Switch";
+          description = "Switch current nix-darwin configuration.";
+          icon = "hammer";
+          body = "exec nh darwin switch";
+        };
+      };
+
+      "raycast/script-commands/nix-switch-fast.sh" = {
+        executable = true;
+        text = mkScript {
+          title = "Nix Switch Fast";
+          description = "Switch nix-darwin with parallel Nix jobs.";
+          icon = "bolt";
+          body = ''
+            NIX_CONFIG=$'max-jobs = auto\ncores = 0'
+            export NIX_CONFIG
+            exec nh darwin switch
+          '';
+        };
+      };
+
+      "raycast/script-commands/restart-sketchybar.sh" = {
+        executable = true;
+        text = mkScript {
+          title = "Restart Sketchybar";
+          description = "Restart Home Manager Sketchybar launch agent.";
+          icon = "bar-chart";
+          body = ''exec launchctl kickstart -k "gui/$(id -u)/org.nix-community.home.sketchybar"'';
+        };
+      };
+
+      "raycast/script-commands/restart-skhd.sh" = {
+        executable = true;
+        text = mkScript {
+          title = "Restart Skhd";
+          description = "Restart Home Manager skhd launch agent.";
+          icon = "keyboard";
+          body = ''exec launchctl kickstart -k "gui/$(id -u)/org.nix-community.home.skhd"'';
+        };
+      };
+
+      "raycast/script-commands/restart-yabai.sh" = {
+        executable = true;
+        text = mkScript {
+          title = "Restart Yabai";
+          description = "Restart nix-darwin yabai launch agent.";
+          icon = "window";
+          body = ''exec launchctl kickstart -k "gui/$(id -u)/org.nixos.yabai"'';
+        };
+      };
+
+      "raycast/script-commands/open-khanelinix.sh" = {
+        executable = true;
+        text = mkScript {
+          title = "Open Khanelinix";
+          description = "Open khanelinix workspace in Kitty and Zellij.";
+          icon = "terminal";
+          body = ''exec kitty --single-instance -d "$HOME/khanelinix" -- zellij'';
+        };
+      };
+
+      "raycast/script-commands/sesh-connect.sh" = {
+        executable = true;
+        text = mkScript {
+          title = "Sesh Connect";
+          description = "Open named sesh session in Kitty.";
+          icon = "terminal";
+          argument1 = {
+            type = "text";
+            placeholder = "session";
+            optional = true;
+          };
+          body = ''
+            session="''${1:-khanelinix}"
+            export SESSION="$session"
+            exec kitty --single-instance -d "$HOME" -- zsh -lc 'sesh connect "$SESSION"'
+          '';
+        };
+      };
+    };
+  };
+}