feat(hardware): add gamepad controller support module

steam-hardware only covers Steam Input. Add xpadneo (Xbox
wireless-over-Bluetooth), game-devices-udev-rules (DualSense/DualShock
udev permissions), and joycond (Joy-Con/Switch Pro) as independent
toggles under khanelinix.hardware.controllers, enabled game suite.

Author: khaneliman

modules/nixos/hardware/controllers/default.nix

@@ -0,0 +1,30 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}:
+let
+  inherit (lib) mkIf mkEnableOption mkMerge;
+
+  cfg = config.khanelinix.hardware.controllers;
+in
+{
+  options.khanelinix.hardware.controllers = {
+    xpadneo.enable = mkEnableOption "xpadneo driver for Xbox wireless-over-Bluetooth controllers";
+    playstation.enable = mkEnableOption "udev rules for PlayStation DualSense/DualShock controllers";
+    joycon.enable = mkEnableOption "joycond support for Nintendo Joy-Con/Switch Pro controllers";
+  };
+
+  config = mkMerge [
+    (mkIf cfg.xpadneo.enable {
+      hardware.xpadneo.enable = true;
+    })
+    (mkIf cfg.playstation.enable {
+      services.udev.packages = [ pkgs.game-devices-udev-rules ];
+    })
+    (mkIf cfg.joycon.enable {
+      services.joycond.enable = true;
+    })
+  ];
+}

modules/nixos/suites/games/default.nix

@@ -23,6 +23,12 @@ in
 
   config = lib.mkIf cfg.enable {
     khanelinix = {
+      hardware.controllers = lib.mkIf (includes "standard") (mkDefault {
+        xpadneo.enable = true;
+        playstation.enable = true;
+        joycon.enable = true;
+      });
+
       programs = {
         graphical = {
           addons = {