flake.nix

{
  description = "Nix flake for Doplarr (Rust)";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
    crane.url = "github:ipetkov/crane";
    flake-utils.url = "github:numtide/flake-utils";
    rust-overlay = {
      url = "github:oxalica/rust-overlay";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    advisory-db = {
      url = "github:rustsec/advisory-db";
      flake = false;
    };
  };

  outputs = {
    self,
    nixpkgs,
    crane,
    flake-utils,
    rust-overlay,
    advisory-db,
    ...
  }:
    flake-utils.lib.eachDefaultSystem (
      system: let
        pkgs = import nixpkgs {
          inherit system;
          overlays = [(import rust-overlay)];
        };

        inherit (pkgs) lib;

        craneLib = (crane.mkLib pkgs).overrideToolchain (
          p:
            p.rust-bin.fromRustupToolchainFile ./rust-toolchain.toml
        );

        src = craneLib.cleanCargoSource ./.;

        commonArgs = {
          inherit src;
          strictDeps = true;
          nativeBuildInputs = with pkgs;
            [cmake]
            ++ lib.optionals stdenv.isx86_64 [nasm]
            ++ lib.optionals stdenv.isDarwin [libiconv];
          buildInputs = [];
        };

        cargoArtifacts = craneLib.buildDepsOnly commonArgs;

        doplarr = craneLib.buildPackage (
          commonArgs
          // {
            pname = "doplarr";
            cargoExtraArgs = "-p doplarr";
          }
        );

        # Static musl binary (Linux x86_64 only)
        muslPkgs = pkgs.pkgsCross.musl64;
        muslCC = "${muslPkgs.stdenv.cc}/bin/${muslPkgs.stdenv.cc.targetPrefix}cc";
        muslAR = "${muslPkgs.stdenv.cc}/bin/${muslPkgs.stdenv.cc.targetPrefix}ar";

        commonArgsMusl = commonArgs // {
          CARGO_BUILD_TARGET = "x86_64-unknown-linux-musl";
          CARGO_BUILD_RUSTFLAGS = "-C target-feature=+crt-static";
          "CARGO_TARGET_X86_64_UNKNOWN_LINUX_MUSL_LINKER" = muslCC;
          "CC_x86_64_unknown_linux_musl" = muslCC;
          "AR_x86_64_unknown_linux_musl" = muslAR;
          nativeBuildInputs = commonArgs.nativeBuildInputs ++ [muslPkgs.stdenv.cc];
          doCheck = false;
        };

        cargoArtifactsMusl = craneLib.buildDepsOnly commonArgsMusl;

        doplarrStatic = craneLib.buildPackage (commonArgsMusl // {
          cargoArtifacts = cargoArtifactsMusl;
          pname = "doplarr";
          cargoExtraArgs = "-p doplarr";
        });

        # Static musl binary — aarch64
        aarch64MuslPkgs = pkgs.pkgsCross.aarch64-multiplatform-musl;
        aarch64CC = "${aarch64MuslPkgs.stdenv.cc}/bin/${aarch64MuslPkgs.stdenv.cc.targetPrefix}cc";
        aarch64AR = "${aarch64MuslPkgs.stdenv.cc}/bin/${aarch64MuslPkgs.stdenv.cc.targetPrefix}ar";

        commonArgsAarch64Musl = commonArgs // {
          CARGO_BUILD_TARGET = "aarch64-unknown-linux-musl";
          CARGO_BUILD_RUSTFLAGS = "-C target-feature=+crt-static";
          "CARGO_TARGET_AARCH64_UNKNOWN_LINUX_MUSL_LINKER" = aarch64CC;
          "CC_aarch64_unknown_linux_musl" = aarch64CC;
          "AR_aarch64_unknown_linux_musl" = aarch64AR;
          nativeBuildInputs = commonArgs.nativeBuildInputs ++ [aarch64MuslPkgs.stdenv.cc];
          doCheck = false;
        };

        cargoArtifactsAarch64Musl = craneLib.buildDepsOnly commonArgsAarch64Musl;

        doplarrStaticAarch64 = craneLib.buildPackage (commonArgsAarch64Musl // {
          cargoArtifacts = cargoArtifactsAarch64Musl;
          pname = "doplarr";
          cargoExtraArgs = "-p doplarr";
        });

      in {
        checks = {
          # Build the crates as part of `nix flake check` for convenience
          inherit doplarr;

          # Run clippy (and deny all warnings) on the doplarr package only.
          # We skip the api crates as they are autogenerated.
          clippy = craneLib.cargoClippy (
            commonArgs
            // {
              inherit cargoArtifacts;
              cargoClippyExtraArgs = "-p doplarr --all-targets -- --deny warnings --no-deps";
            }
          );

          # Check formatting
          fmt = craneLib.cargoFmt {
            inherit src;
          };

          toml-fmt = craneLib.taploFmt {
            src = pkgs.lib.sources.sourceFilesBySuffices src [".toml"];
            # taplo arguments can be further customized below as needed
            # taploExtraArgs = "--config ./taplo.toml";
          };

          # Audit dependencies
          audit = craneLib.cargoAudit {
            inherit src advisory-db;
          };
        };

        packages =
          {
            default = doplarr;
          }
          // lib.optionalAttrs pkgs.stdenv.isLinux {
            static = doplarrStatic;
            staticAarch64 = doplarrStaticAarch64;

            dockerImage = pkgs.dockerTools.buildLayeredImage {
              name = "ghcr.io/activexray/doplarr_rs";
              tag = "latest";
              contents = [doplarrStatic pkgs.cacert];
              config = {
                Cmd = ["${doplarrStatic}/bin/doplarr"];
                ExposedPorts = {};
                Env = [
                  "SSL_CERT_FILE=${pkgs.cacert}/etc/ssl/certs/ca-bundle.crt"
                ];
              };
            };

            dockerImageAarch64 = pkgs.dockerTools.buildLayeredImage {
              name = "ghcr.io/activexray/doplarr_rs";
              tag = "latest";
              architecture = "arm64";
              contents = [doplarrStaticAarch64 pkgs.cacert];
              config = {
                Cmd = ["${doplarrStaticAarch64}/bin/doplarr"];
                ExposedPorts = {};
                Env = [
                  "SSL_CERT_FILE=${pkgs.cacert}/etc/ssl/certs/ca-bundle.crt"
                ];
              };
            };

          };

        apps.default = flake-utils.lib.mkApp {
          drv = doplarr;
        };

        devShells.default = craneLib.devShell {
          # Inherit inputs from checks.
          checks = self.checks.${system};

          # Additional dev-shell environment variables can be set directly
          # MY_CUSTOM_DEVELOPMENT_VAR = "something else";

          # Extra inputs can be added here; cargo and rustc are provided by default.
          packages = with pkgs; [
            openapi-generator-cli
            cargo-outdated
          ];
        };
      }
    );
}