react-native-klarna-inapp-sdk/android/build.gradle at 4735a1ecf1a6c24a6dc892b679321ce5d1890459 · klarna/react-native-klarna-inapp-sdk · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
buildscript {
    ext.getExtOrFallback = { name, fallback ->
        rootProject.ext.has(name) ? rootProject.ext.get(name) : fallback
    }

    ext.getExtOrDefault = { name ->
        getExtOrFallback(name, project.properties["KlarnaMobileSDKRN_" + name])
    }

    repositories {
        google()
        gradlePluginPortal()
        mavenCentral()
    }

    dependencies {
        classpath "com.android.tools.build:gradle:${getExtOrDefault('gradlePluginVersion')}"
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:${getExtOrDefault('kotlinVersion')}"
    }
}

def getExtOrDefault(name) {
  return rootProject.ext.has(name) ? rootProject.ext.get(name) : project.properties["KlarnaMobileSDKRN_" + name]
}

def getExtOrIntegerDefault(name) {
  return rootProject.ext.has(name) ? rootProject.ext.get(name) : (project.properties["KlarnaMobileSDKRN_" + name]).toInteger()
}

def isNewArchitectureEnabled() {
  return rootProject.hasProperty("newArchEnabled") && rootProject.getProperty("newArchEnabled") == "true"
}

def supportsNamespace() {
  def parsed = com.android.Version.ANDROID_GRADLE_PLUGIN_VERSION.tokenize('.')
  def major = parsed[0].toInteger()
  def minor = parsed[1].toInteger()

  // Namespace support was added in 7.3.0
  if (major == 7 && minor >= 3) {
    return true
  }

  return major >= 8
}

plugins {
    id "org.jetbrains.kotlin.plugin.serialization" version "1.9.25"
}
apply plugin: 'com.android.library'
apply plugin: 'kotlin-android'
if (isNewArchitectureEnabled()) {
  apply plugin: "com.facebook.react"
}

android {
    if (supportsNamespace()) {
        namespace "com.klarna.mobile.sdk.reactnative"

        sourceSets {
            main {
              manifest.srcFile "src/main/AndroidManifestNew.xml"
            }
        }
     }
    compileSdkVersion getExtOrIntegerDefault("compileSdkVersion")

    defaultConfig {
        minSdkVersion getExtOrIntegerDefault("minSdkVersion")
        targetSdkVersion getExtOrIntegerDefault("targetSdkVersion")
        buildConfigField "boolean", "IS_NEW_ARCHITECTURE_ENABLED", isNewArchitectureEnabled().toString()
        versionCode 1
        versionName "1.0"
    }
    buildTypes {
        release {
            minifyEnabled false
        }
    }
    lintOptions {
        abortOnError false
        disable "GradleCompatible"
    }
    compileOptions {
        sourceCompatibility JavaVersion.VERSION_1_8
        targetCompatibility JavaVersion.VERSION_1_8
    }
    sourceSets {
        main {
            if (isNewArchitectureEnabled()) {
                java.srcDirs += ["src/newarch/java"]
            } else {
                java.srcDirs += ["src/oldarch/java"]
            }
        }
    }
}

repositories {
    mavenCentral()
    google()
    maven {
        url 'https://x.klarnacdn.net/mobile-sdk/'
    }
}

dependencies {
    // For < 0.71, this will be from the local maven repo
    // For > 0.71, this will be replaced by `com.facebook.react:react-android:$version` by react gradle plugin
    //noinspection GradleDynamicVersion
    implementation "com.facebook.react:react-native:${getExtOrFallback('reactnativeVersion', '+')}"

    implementation "org.jetbrains.kotlin:kotlin-stdlib:${getExtOrDefault('kotlinVersion')}"
    implementation "org.jetbrains.kotlin:kotlin-reflect:${getExtOrDefault('kotlinVersion')}"
    implementation 'org.jetbrains.kotlinx:kotlinx-serialization-json:1.6.3'

    implementation 'com.klarna.mobile:sdk:2.11.0'

    testImplementation "junit:junit:4.13.2"
    testImplementation 'androidx.test:core:1.5.0'
    testImplementation "org.robolectric:robolectric:4.11.1"
    testImplementation "org.mockito:mockito-core:3.12.4"
    testImplementation "org.mockito:mockito-inline:3.12.4"
    testImplementation "org.jetbrains.kotlin:kotlin-test-junit:${getExtOrDefault('kotlinVersion')}"
    testImplementation "io.mockk:mockk:1.14.5"
}

// removed from the docs but we can keep it
// https://reactnative.dev/docs/0.71/new-architecture-library-intro
if (isNewArchitectureEnabled()) {
  react {
    jsRootDir = file("../src/specs")
    libraryName = "RNKlarnaMobileSDK"
    codegenJavaPackageName = "com.klarna.mobile.sdk.reactnative"
  }
}