csound-live-code/2023-09-09_triangle-bells.csd at main · kunstmusik/csound-live-code · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
<CsoundSynthesizer>
<CsOptions>
-Wdo dac --port=10000
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 64
nchnls = 2
0dbfs = 1

#include "livecode.orc"


;; Author: Steven Yi
;; Date: 2023-09-09
;; Description: Triangle bells with tremolo

start("ReverbMixer")
set_tempo(120)
set_scale("min")

xchnset("Reverb.fb", .85)

instr Bell
  asig = vco2(p5, p4, 12)
  ; asig = zdf_2pole(asig, 100, 0.5, 1)
  asig = zdf_2pole(asig, 12000, 0.5)
  asig *= (1 + linseg(0, .35, 0, .1, 1, p3, 1) * oscili(0.2, 3.7)) ;; tremolo with delay onset
  asig *= transegr:a(0, .002, 0, 1, 3, -4.2, 0, 3, -4.2, 0) ;; bell envelope

  pan_verb_mix(asig, 0.5, 0.2)
endin


eval_at_time({{

;; callback instrument for csound-live-code
instr P1

  hexplay("88888000",
      "Bell", p3,
      in_scale(0, xoscim(4.5, array(0,4,2,3))),
      fade_in(5, 128) * ampdbfs(-12))

   hexplay("80808000",
      "Bell", p3,
      in_scale(1, xoscim(5.5, array(0,4,2,3))),
      fade_in(5, 128) * ampdbfs(-12))

   hexplay("8080",
      "Bell", p3 * 2,
      in_scale(-1, xoscim(3.5, array(0,4))),
      fade_in(5, 128) * ampdbfs(-12))


  ; hexplay("ea81fa80",
  ;     "Bell", p3,
  ;     in_scale(2, cycle(p4, array(0,4,2,3,1,5))),
  ;     fade_in(6, 128) * ampdbfs(-18))

  ; hexplay("f",
  ;     "Bell", p3,
  ;     in_scale(3, cycle(p4, array(0,4,2,3,1,5))),
  ;     fade_in(7, 128) * ampdbfs(-24))


endin

}}, 0)

</CsInstruments>
</CsoundSynthesizer>