Matching a fan curve in Openmodelica

[Modelica1212]

Hi, I'm new to Modelica and trying to simulate a loop consisting of a fan and a resistance. I expect to input my fan curve and resistance characteristics and obtain the intersection between the two plots as the result for pressure and mass flow.

The problem is, I can't seem to visualize the correct fan curve when I try to plot VMachine_flow and dpMachine. Additionally, I'm encountering the same curve for both the resistance and the fan.

Another issue is that I expect to find the equilibrium point in the results instead of just the last point of every plot.

The resistance should exhibit the following behavior:

This is the model I made:

this is the output plots of dp2.Dp vs dp2.m_flow vs and fan.DpMachine vs fan.m_flow:

and this is VMaschine_flow vs DpMachine plot witch look diffrent from my curve values :

And this is the following code:
`model fan

package Medium = Buildings.Media.Air;
Buildings.Fluid.Sources.Boundary_pT sou(
redeclare package Medium = Medium,
use_p_in=false,
p=101325,
T=293.15,
nPorts=2) annotation (Placement(transformation(extent={{-82,10},{-62,30}})));
Buildings.Fluid.FixedResistances.PressureDrop dp2(
redeclare package Medium = Medium,
m_flow_nominal=0.022,
dp_nominal=1) "Pressure drop" annotation (Placement(transformation(extent={{80,40},{100,60}})));

Buildings.Fluid.Movers.SpeedControlled_y fan(
redeclare package Medium = Medium,
per(pressure(V_flow = {0, 3.75, 10.64}, dp = {1525.23, 1394.5, 682.72})), addPowerToMedium = false, use_inputFilter = true)

annotation (Placement(transformation(extent={{40,40},{60,60}})));

Modelica.Blocks.Sources.Constant one(final k = 1) annotation(
Placement(transformation(origin = {30, 76}, extent = {{-40, 20}, {-20, 40}})));
equation
connect(fan.port_b, dp2.port_a) annotation(
Line(points = {{60, 50}, {80, 50}}, color = {0, 127, 255}));
connect(dp2.port_b, sou.ports[1]) annotation(
Line(points = {{100, 50}, {110, 50}, {110, 18}, {-62, 18}}, color = {0, 127, 255}));
connect(one.y, fan.y) annotation(
Line(points = {{12, 106}, {50, 106}, {50, 62}}, color = {0, 0, 127}));
connect(fan.port_a, sou.ports[2]) annotation(
Line(points = {{40, 50}, {-62, 50}, {-62, 20}}, color = {0, 127, 255}));

end fan;`

I would appreciate any guidance on resolving these issues.
thank you in advance

[hcasperfu]

Greetings!

The results from your model are as expected.

• Because your hydraulic loop is closed at the same boundary component sou, the pressure created by fan must balance the pressure drop at dp2, and you will see the characteristic curve of dp2 enforced on fan.
• By default fan.y_start = 0. Therefore the normalised fan speed climbs from 0 to 1, instead of staying at 1 as specified in your input block one. Effectively you are seeing the pressure drop at dp2 plotted against flow rate as the flow rate goes up from zero.

In order to see the fan curve you will have to force a pressure drop or flow rate while ensuring the normalised speed is enforced at 1 so that the fan can "ride the curve" along with the simulation, but it's actually not easy when components are put in a hydraulic loop and are all locked together in an equation system.
If you dig a little deeper into the base classes, Buildings.Fluid.Movers.BaseClasses.Validation.NegativePressureOrFlow is implemented to force the pressure and flow rate. It uses the base component Buildings.Fluid.Movers.BaseClasses.FlowMachineInterface outside of a hydraulic loop. This base component is the one responsible for computing pressure curves and efficiency.
The base validation model can be revised like below to see the pressure curve of the pressure curve implemented in Buildings.Fluid.Movers.Data.Fans.Greenheck.BIDW15. Take note that you need to modify eff.nOri manually to match the array size of your curve.

Cheers,
Casper

model NegativePressureOrFlowDuplicate
  extends Modelica.Icons.Example;

  package Medium = Buildings.Media.Air;

  parameter Buildings.Fluid.Movers.Data.Fans.Greenheck.BIDW15 per;

  parameter Modelica.Units.SI.MassFlowRate m_flow_nominal=0.1
    "Nominal mass flow rate";
  parameter Modelica.Units.SI.PressureDifference dp_nominal=10000
    "Nominal pressure difference";
  parameter Modelica.Units.SI.Density rho_default=1.2
    "Fluid density at medium default state";

  Buildings.Fluid.Movers.BaseClasses.FlowMachineInterface eff(
    per=per,
    preVar=Buildings.Fluid.Movers.BaseClasses.Types.PrescribedVariable.Speed,
    computePowerUsingSimilarityLaws=true,
    rho_default=rho_default,
    nOri=7)
    "FlowMachineInterface model with prescribed pressure"
    annotation (Placement(transformation(extent={{-20,-20},{0,0}})));
  Modelica.Blocks.Sources.Constant rho(k=rho_default) "Density"
    annotation (Placement(transformation(extent={{-80,-60},{-60,-40}})));
  Modelica.Blocks.Sources.Ramp m_flow(height=max(eff.per.pressure.V_flow)*
        rho_default,
    duration=3600)              "Mass flow rate"
    annotation (Placement(transformation(extent={{-80,-20},{-60,0}})));
  Modelica.Blocks.Sources.Constant y(k=1) "Speed"
    annotation (Placement(transformation(extent={{-80,20},{-60,40}})));
  Modelica.Blocks.Sources.Constant m_flow_alt(k=max(eff.per.pressure.V_flow)*
        rho_default) "alternative"
    annotation (Placement(transformation(extent={{-80,62},{-60,82}})));
equation 

  connect(rho.y, eff.rho) annotation (Line(points={{-59,-50},{-28,-50},{-28,-16},
          {-22,-16}}, color={0,0,127}));
  connect(y.y, eff.y_in)
    annotation (Line(points={{-59,30},{-14,30},{-14,2}}, color={0,0,127}));
  connect(m_flow.y, eff.m_flow) annotation (Line(points={{-59,-10},{-32,-10},{-32,
          -6},{-22,-6}}, color={0,0,127}));
annotation(
   experiment(
      StopTime=3600,
      Tolerance=1e-06));
end NegativePressureOrFlowDuplicate;

[Modelica1212]

Hi Casper,

First of all, thank you for your help. It's not a problem if it can work in an open circuit where I can just use the same pressure for both sides. i adjusted my previous model to avoid a closed loop , however, I'm still encountering the same issue as with the previous model.

I also examined Buildings.Fluid.Movers.BaseClasses.FlowMachineInterface and reviewed the code you provided. However, I'm uncertain about how to incorporate it into my model because the ports are not directly compatible. In my model, the objective is to visualize the volumetric flow versus pressure curve of the pump and the resistance, and to be able to identify the intersection point graphically and in the results. Could you please provide guidance on how I can integrate the model you provided with the resistances?

thanks in advance

Regards,
Yassine

`model fan

package Medium = Buildings.Media.Air;
Buildings.Fluid.Sources.Boundary_pT sou(
redeclare package Medium = Medium,
use_p_in=false,
p=101325,
T=293.15,
nPorts=1) annotation (Placement(transformation(origin = {-18, 98}, extent = {{-82, 10}, {-62, 30}}, rotation = 90)));
Buildings.Fluid.FixedResistances.PressureDrop dp2(
redeclare package Medium = Medium,
m_flow_nominal=0.022,
dp_nominal=1) "Pressure drop" annotation (Placement(transformation(origin = {-60, 0}, extent = {{80, 40}, {100, 60}})));

Buildings.Fluid.Movers.SpeedControlled_y fan(
redeclare package Medium = Medium,
per(pressure(V_flow = {0, 3.75, 10.64}, dp = {1525.23, 1394.5, 682.72})), addPowerToMedium = false, use_inputFilter = true)

annotation (Placement(transformation(origin = {-48, 0}, extent = {{40, 40}, {60, 60}})));
Modelica.Blocks.Sources.Constant one(final k = 1) annotation(
Placement(transformation(origin = {2, 50}, extent = {{-40, 20}, {-20, 40}})));
Buildings.Fluid.Sources.Boundary_pT sou1(redeclare package Medium = Medium, T = 293.15, nPorts = 1, p = 101325, use_p_in = false) annotation(
Placement(transformation(origin = {96, 98}, extent = {{-82, 10}, {-62, 30}}, rotation = 90)));
equation
connect(fan.port_b, dp2.port_a) annotation(
Line(points = {{12, 50}, {20, 50}}, color = {0, 127, 255}));
connect(one.y, fan.y) annotation(
Line(points = {{-17, 80}, {2, 80}, {2, 62}}, color = {0, 0, 127}));
connect(fan.port_a, sou.ports[1]) annotation(
Line(points = {{-8, 50}, {-38, 50}, {-38, 36}}, color = {0, 127, 255}));
connect(sou1.ports[1], dp2.port_b) annotation(
Line(points = {{76, 36}, {76, 50}, {40, 50}}, color = {0, 127, 255}));
end fan;`

[hcasperfu]

Greetings!
I think I understand your objective, but I'm not sure that's what Modelica is usually set up to do.
The two curves that you are trying to plot on the same figure (and see them cross) represent two very different scenarios.

1. Given a system curve $Δp = k \dot{V}^2$, the resistance is fixed (i.e. $k$ is constant). The fan curve crosses with the system curve at different points only by varying the speed $y$.
2. Given a fan curve in the form $Δp = y^2 f(\dot{V})$ (translate: $Δp$ is some function of $\dot{V}$ scaled up and down by speed squared $y^2$), the speed is fixed (i.e. $y$ is constant). The system curve crosses with the fan curve at different points only by varying the resistance $k$ (such as operating the dampers).

When you run your model you effectively ran with option 1. As I explained in the previous post, even though you tried to specify $y=1$ with the constant block, the fan model still started from $y=0$ because y.start = 0 by default.
The curve plotting is better achieved by other tools than Modelica, in my opinion. On the other hand, you do get the cross point solved out of these two curves as the end result.

Cheers,
Casper