|
| 1 | +/- |
| 2 | +Copyright (c) 2025 Joël Riou. All rights reserved. |
| 3 | +Released under Apache 2.0 license as described in the file LICENSE. |
| 4 | +Authors: Joël Riou |
| 5 | +-/ |
| 6 | +module |
| 7 | + |
| 8 | +public import Mathlib.Algebra.Homology.Opposite |
| 9 | +public import Mathlib.Algebra.Homology.Embedding.Restriction |
| 10 | + |
| 11 | +/-! |
| 12 | +# Opposite categories of cochain complexes |
| 13 | +
|
| 14 | +We construct an equivalence of categories `CochainComplex.opEquivalence C` |
| 15 | +between `(CochainComplex C ℤ)ᵒᵖ` and `CochainComplex Cᵒᵖ ℤ`, and we show |
| 16 | +that two morphisms in `CochainComplex C ℤ` are homotopic iff they are |
| 17 | +homotopic as morphisms in `CochainComplex Cᵒᵖ ℤ`. |
| 18 | +
|
| 19 | +-/ |
| 20 | + |
| 21 | +@[expose] public section |
| 22 | + |
| 23 | +noncomputable section |
| 24 | + |
| 25 | +open Opposite CategoryTheory Limits |
| 26 | + |
| 27 | +variable (C : Type*) [Category C] |
| 28 | + |
| 29 | +namespace ComplexShape |
| 30 | + |
| 31 | +/-- The embedding of the complex shape `up ℤ` in `down ℤ` given by `n ↦ -n`. -/ |
| 32 | +@[simps] |
| 33 | +def embeddingUpIntDownInt : (up ℤ).Embedding (down ℤ) where |
| 34 | + f n := -n |
| 35 | + injective_f _ _ := by simp |
| 36 | + rel := by simp |
| 37 | + |
| 38 | +instance : embeddingUpIntDownInt.IsRelIff where |
| 39 | + rel' := by dsimp; lia |
| 40 | + |
| 41 | +/-- The embedding of the complex shape `down ℤ` in `up ℤ` given by `n ↦ -n`. -/ |
| 42 | +@[simps] |
| 43 | +def embeddingDownIntUpInt : (down ℤ).Embedding (up ℤ) where |
| 44 | + f n := -n |
| 45 | + injective_f _ _ := by simp |
| 46 | + rel := by dsimp; lia |
| 47 | + |
| 48 | +instance : embeddingDownIntUpInt.IsRelIff where |
| 49 | + rel' := by dsimp; lia |
| 50 | + |
| 51 | +end ComplexShape |
| 52 | + |
| 53 | +namespace ChainComplex |
| 54 | + |
| 55 | +variable [HasZeroMorphisms C] |
| 56 | + |
| 57 | +attribute [local simp] HomologicalComplex.XIsoOfEq in |
| 58 | +/-- The equivalence of categories `ChainComplex C ℤ ≌ CochainComplex C ℤ`. -/ |
| 59 | +def cochainComplexEquivalence : |
| 60 | + ChainComplex C ℤ ≌ CochainComplex C ℤ where |
| 61 | + functor := ComplexShape.embeddingUpIntDownInt.restrictionFunctor C |
| 62 | + inverse := ComplexShape.embeddingDownIntUpInt.restrictionFunctor C |
| 63 | + unitIso := |
| 64 | + NatIso.ofComponents (fun K ↦ HomologicalComplex.Hom.isoOfComponents |
| 65 | + (fun n ↦ K.XIsoOfEq (by simp))) |
| 66 | + counitIso := |
| 67 | + NatIso.ofComponents (fun K ↦ HomologicalComplex.Hom.isoOfComponents |
| 68 | + (fun n ↦ K.XIsoOfEq (by simp))) |
| 69 | + |
| 70 | +end ChainComplex |
| 71 | + |
| 72 | +namespace CochainComplex |
| 73 | + |
| 74 | +/-- The equivalence of categories `(CochainComplex C ℤ)ᵒᵖ ≌ CochainComplex Cᵒᵖ ℤ`. -/ |
| 75 | +def opEquivalence [HasZeroMorphisms C] : |
| 76 | + (CochainComplex C ℤ)ᵒᵖ ≌ CochainComplex Cᵒᵖ ℤ := |
| 77 | + (HomologicalComplex.opEquivalence C (.up ℤ)).trans |
| 78 | + (ChainComplex.cochainComplexEquivalence _) |
| 79 | + |
| 80 | +variable {C} [Preadditive C] |
| 81 | + |
| 82 | +attribute [local simp] opEquivalence ChainComplex.cochainComplexEquivalence |
| 83 | + |
| 84 | +section |
| 85 | + |
| 86 | +variable {K L : CochainComplex C ℤ} {f g : K ⟶ L} |
| 87 | + |
| 88 | +/-- Given an homotopy between morphisms of cochain complexes indexed by `ℤ`, |
| 89 | +this is the corresponding homotopy between morphisms of cochain complexes |
| 90 | +in the opposite category. -/ |
| 91 | +def homotopyOp (h : Homotopy f g) : |
| 92 | + Homotopy ((opEquivalence C).functor.map f.op) |
| 93 | + ((opEquivalence C).functor.map g.op) where |
| 94 | + hom p q := (h.hom (-q) (-p)).op |
| 95 | + zero p q hpq := by |
| 96 | + rw [h.zero, op_zero] |
| 97 | + dsimp at hpq ⊢ |
| 98 | + lia |
| 99 | + comm n := by |
| 100 | + dsimp |
| 101 | + simp only [h.comm, op_add, add_left_inj] |
| 102 | + rw [add_comm] |
| 103 | + congr 1 |
| 104 | + · rw [prevD_eq _ (j' := - (n + 1)) (by simp)] |
| 105 | + symm |
| 106 | + exact dNext_eq _ (i' := n + 1) (by simp) |
| 107 | + · rw [dNext_eq _ (i' := - (n - 1)) (by dsimp; lia)] |
| 108 | + symm |
| 109 | + exact prevD_eq _ (j' := n - 1) (by simp) |
| 110 | + |
| 111 | +lemma homotopyOp_hom_eq (h : Homotopy f g) |
| 112 | + (p q p' q' : ℤ) (hp : p + p' = 0 := by lia) (hq : q + q' = 0 := by lia) : |
| 113 | + (homotopyOp h).hom p q = |
| 114 | + (L.XIsoOfEq (by dsimp; lia)).hom.op ≫ (h.hom q' p').op ≫ |
| 115 | + (K.XIsoOfEq (by dsimp; lia)).hom.op := by |
| 116 | + obtain rfl : p' = -p := by lia |
| 117 | + obtain rfl : q' = -q := by lia |
| 118 | + simp [homotopyOp] |
| 119 | + |
| 120 | +/-- The homotopy between two morphisms of cochain complexes indexed by `ℤ` |
| 121 | +which correspond to an homotopy between morphisms of cochain complexes |
| 122 | +in the opposite category. -/ |
| 123 | +def homotopyUnop (h : Homotopy ((opEquivalence C).functor.map f.op) |
| 124 | + ((opEquivalence C).functor.map g.op)) : |
| 125 | + Homotopy f g where |
| 126 | + hom p q := (K.XIsoOfEq (by simp)).hom ≫ (h.hom (-q) (-p)).unop ≫ (L.XIsoOfEq (by simp)).hom |
| 127 | + zero p q hpq := by |
| 128 | + rw [h.zero, unop_zero, zero_comp, comp_zero] |
| 129 | + dsimp at hpq ⊢ |
| 130 | + lia |
| 131 | + comm n := Quiver.Hom.op_inj (by |
| 132 | + have H (p q p' q' : ℤ) (hp : p = p') (hq : q = q') : |
| 133 | + h.hom p q = (L.XIsoOfEq (by simpa using hp.symm)).hom.op ≫ h.hom p' q' ≫ |
| 134 | + (K.XIsoOfEq (by simpa)).hom.op := by |
| 135 | + subst hp hq |
| 136 | + simp |
| 137 | + obtain ⟨n, rfl⟩ : ∃ (m : ℤ), n = -m := ⟨-n , by simp⟩ |
| 138 | + have := h.comm n |
| 139 | + dsimp at this |
| 140 | + rw [op_add, op_add, this, add_left_inj, add_comm] |
| 141 | + congr 1 |
| 142 | + · refine (prevD_eq _ (j' := n - 1) (by dsimp; lia)).trans ?_ |
| 143 | + rw [dNext_eq _ (i' := - (n - 1)) (by dsimp; lia)] |
| 144 | + dsimp |
| 145 | + simp [H (- -n) (- -(n - 1)) n (n - 1) (by lia) (by lia), ← op_comp_assoc] |
| 146 | + · refine (dNext_eq _ (i' := n + 1) (by dsimp)).trans ?_ |
| 147 | + rw [prevD_eq _ (j' := - (n + 1)) (by simp)] |
| 148 | + dsimp |
| 149 | + simp [H (- -(n + 1)) (- -n) (n + 1) n (by simp) (by simp), ← op_comp_assoc, ← op_comp]) |
| 150 | + |
| 151 | +lemma homotopyUnop_hom_eq |
| 152 | + (h : Homotopy ((opEquivalence C).functor.map f.op) |
| 153 | + ((opEquivalence C).functor.map g.op)) |
| 154 | + (p q p' q' : ℤ) (hp : p + p' = 0 := by lia) (hq : q + q' = 0 := by lia) : |
| 155 | + (homotopyUnop h).hom p q = |
| 156 | + (K.XIsoOfEq (by dsimp; lia)).hom ≫ (h.hom q' p').unop ≫ |
| 157 | + (L.XIsoOfEq (by dsimp; lia)).hom := by |
| 158 | + obtain rfl : p' = -p := by lia |
| 159 | + obtain rfl : q' = -q := by lia |
| 160 | + simp [homotopyUnop] |
| 161 | + |
| 162 | +end |
| 163 | + |
| 164 | +/-- Two morphisms of cochain complexes indexed by `ℤ` are homotopic iff |
| 165 | +they are homotopic after the application of the functor |
| 166 | +`(opEquivalence C).functor : (CochainComplex C ℤ)ᵒᵖ ⥤ CochainComplex Cᵒᵖ ℤ`. -/ |
| 167 | +def homotopyOpEquiv {K L : CochainComplex C ℤ} {f g : K ⟶ L} : |
| 168 | + Homotopy f g ≃ Homotopy ((opEquivalence C).functor.map f.op) |
| 169 | + ((opEquivalence C).functor.map g.op) where |
| 170 | + toFun h := homotopyOp h |
| 171 | + invFun h := homotopyUnop h |
| 172 | + left_inv h := by |
| 173 | + ext p q |
| 174 | + simp [homotopyUnop_hom_eq _ p q (-p) (-q), |
| 175 | + homotopyOp_hom_eq _ (-q) (-p) q p] |
| 176 | + right_inv h := by |
| 177 | + ext p q |
| 178 | + simp [homotopyOp_hom_eq _ p q (-p) (-q), |
| 179 | + homotopyUnop_hom_eq _ (-q) (-p) q p] |
| 180 | + |
| 181 | +end CochainComplex |
0 commit comments