sound-categories/build.gradle at dev · lonefelidae16/sound-categories · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
import com.google.gson.JsonArray
import com.google.gson.JsonParser
import com.google.gson.JsonPrimitive

plugins {
    id 'net.fabricmc.fabric-loom'
    id "maven-publish"
    id 'com.palantir.git-version'
}

var targetJavaLang = Integer.parseInt(rootProject.java_lang_version)

var verStr = (project.findProperty('verStr') ?: versionDetails().gitHash[0..7]).toString()
version = "${project.mod_version}+${verStr}"

allprojects {
    group = project.maven_group

    repositories {
//        maven {
//            name = "stashymane's repo"
//            url = "https://repo.stashy.dev"
//        }
        maven {
            url = "https://artifactory.kow08absty.com/artifactory/fabricmc"
        }
    }
}

base {
    archivesName = project.archives_base_name
}

allprojects {
    apply plugin: 'java'

    java {
        withSourcesJar()
        sourceCompatibility = JavaVersion.toVersion(targetJavaLang)
        targetCompatibility = JavaVersion.toVersion(targetJavaLang)
    }

    tasks.withType(JavaCompile).configureEach {
        it.options.encoding = "UTF-8"
        it.options.release.set(targetJavaLang)
    }

    project.ext['moduleId'] = 'unnamed'
    project.ext['moduleName'] = ''
    project.ext['mod_license'] = project.mod_license
    project.ext['moduleMixins'] = []
    project.ext['moduleAccessWidener'] = ''

    tasks.withType(ProcessResources).configureEach {
        doFirst {
            var props = [
                    "mod_page",
                    "mod_sources",
//                    "mod_issues",
                    "mod_support_lowest_mc"
            ].collectEntries {
                [it, project.properties[it]]
            }

            var mixins = new JsonArray()
            project.ext['moduleMixins'].forEach {
                mixins.add(it)
            }

            props.putAll([
                    'moduleId'    : project.ext['moduleId'],
                    'moduleName'  : project.ext['moduleName'],
                    'mod_license' : project.ext['mod_license'],
                    'moduleMixins': mixins.toString(),
                    'version'     : project.version
            ])

            filesMatching("fabric.mod.json") {
                expand props
            }
        }

        doLast {
            fileTree(dir: outputs.files.asPath, include: "**/fabric.mod.json").each { file ->
                var fabricModJson = JsonParser.parseString(file.text).asJsonObject
                if (!project.ext['moduleAccessWidener'].isEmpty()) {
                    fabricModJson.add("accessWidener", new JsonPrimitive(project.ext['moduleAccessWidener']))
                    file.text = fabricModJson.toString()
                }
            }
        }
    }
}

var devLibsPaths = '**/build/devlibs/*-dev.jar'
var libsPaths = '**/build/libs/*.jar'
var sourcesPaths = '**/*-sources.jar'

dependencies {
    minecraft "com.mojang:minecraft:${rootProject.minecraft_version}"
    implementation "net.fabricmc:fabric-loader:${rootProject.loader_version}"
    implementation "net.fabricmc.fabric-api:fabric-api:${rootProject.fabric_api_version}"

    implementation include("me.lonefelidae16:groominglib:${rootProject.groom_version}")

    compileOnlyApi include(project(path: 'shared'))
    compileOnly include(project(path: 'versioned:sc26.1'))

    // DevLaunch
    runtimeOnly fileTree(dir: 'shared', exclude: [sourcesPaths], include: [devLibsPaths, libsPaths])
    runtimeOnly fileTree(dir: 'versioned', exclude: [sourcesPaths], include: [devLibsPaths, libsPaths])
}

jar {
    from("LICENSE") {
        rename { "${it}_${project.archives_base_name}" }
    }
}

publishing {
    publications {
        mavenJava(MavenPublication) {
            from components.java
        }
    }

    repositories {
        maven {
            url = "https://repo.stashy.dev"
            credentials {
                username = project.hasProperty("publish_username") ? project.publish_username : ""
                password = project.hasProperty("publish_password") ? project.publish_password : ""
            }
        }
    }
}